TURB_WlmReyAnalogy.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute wall heat flux (heat transfer) assuming Reynolds analogy 
!          between heat and momentum transfer.
!
! Description: Reynolds analogy: 
!              St/(0.5*Cf) = Prt^(-0.66). 
!              With Stanton number, St = qw/(rho*cp*(Tw-Te)*ue), and
!              assuming (Te-Tw)/ue = (T1-Tw)/u1, heat flux (written dotless) 
!              qw = tau_w*cp*(Tw-T1)/u1. 
!              Heat transfer coefficient: cq = qw/(Tw-Te)
!
! Input: region  = data of current region.
!        patch   = current patch.
!
! Output: wall heat flux.
!
! Notes: - Avoiding complication determining BL-edge, heat transfer coefficient
!          if desired should, currently, be computed externally.
!        - Total wall stress already stored in vals(:,WLM_VALS_HFLUX) to use.
!
!******************************************************************************
!
! $Id: TURB_WlmReyAnalogy.F90,v 1.6 2008/12/06 08:44:42 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_wlmreyanalogy( region,patch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset

#include "Indexing.h"
#endif
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: ijbeg, ijend, indcp, bcopt, distrib, ijkval, ijkc, ijkce
  REAL(RFREAL)          :: twall, tauwall, abvel, ratio, prt, cp, utau
  REAL(RFREAL), POINTER :: dv(:,:), gv(:,:), vals(:,:), mvals(:,:)

#ifdef RFLO
  INTEGER :: n1, n2, ioff, icoff, ijcoff
  INTEGER :: ilev, idir, jdir, kdir, iedge, jedge, kedge, nedge, neta
#endif
#ifdef RFLU
  REAL(RFREAL), POINTER :: cv(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_WlmReyAnalogy.F90,v $ $Revision: 1.6 $'

  global => region%global
  CALL registerfunction( global,'TURB_WlmReyAnalogy',&
  'TURB_WlmReyAnalogy.F90' )

! get dimensions, pointers and parameters -------------------------------------

  bcopt =  patch%mixt%switches(bcswi_noslip_adiabat)
  mvals => patch%mixt%vals
  vals  => patch%valBola%vals 

#ifdef RFLO
  n1    = abs(patch%l1end-patch%l1beg)
  n2    = abs(patch%l2end-patch%l2beg)
  ioff  = n1 + 1
  ijbeg = indij( 0, 0,ioff)
  ijend = indij(n1,n2,ioff)
#endif
#ifdef RFLU
  ijbeg = 1
  ijend = patch%nBFaces
#endif

! adiabatic wall : skip heat flux computation and set it to zero

  IF (bcopt == bcopt_adiabat) THEN
    DO ijkval=ijbeg,ijend
      vals(ijkval,wlm_vals_hflux) = 0._rfreal
    ENDDO
    goto 999
  ENDIF

! isothermal wall: proceed with heat flux computation

#ifdef RFLO
  ilev   =  region%currLevel

  dv     => region%levels(ilev)%mixt%dv
  gv     => region%levels(ilev)%mixt%gv
  indcp  =  region%levels(ilev)%mixt%indCp
  prt    =  region%levels(ilev)%mixt%prTurb
#endif
#ifdef RFLU
  cv     => region%mixt%cv
  dv     => region%mixt%dv
  gv     => region%mixt%gv
  indcp  =  region%mixtInput%indCp
  prt    =  region%mixtInput%prTurb
#endif
  ratio   = prt**(-0.66_rfreal)
  distrib = patch%mixt%distrib

#ifdef RFLO
  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  neta  = abs(idir)*region%levels(ilev)%grid%ipc + &
          abs(jdir)*region%levels(ilev)%grid%jpc + &
          abs(kdir)*region%levels(ilev)%grid%kpc
  nedge = min( 8,neta )
  iedge = idir*nedge
  jedge = jdir*nedge
  kedge = kdir*nedge

! Compute wall heat flux. 
! Note that total wall stress has been stored in vals(:,WLM_VALS_HFLUX).

  DO k=kbeg,kend
    DO j=jbeg,jend
      DO i=ibeg,iend
        ijkval = abs(idir)*indij(j-jbeg,k-kbeg,jend-jbeg+1) + &
                 abs(jdir)*indij(k-kbeg,i-ibeg,kend-kbeg+1) + &
                 abs(kdir)*indij(i-ibeg,j-jbeg,iend-ibeg+1)
        ijkc   = indijk(i      ,j      ,k      ,icoff,ijcoff)
        ijkce  = indijk(i+iedge,j+jedge,k+kedge,icoff,ijcoff)

        abvel  = sqrt( dv(dv_mixt_uvel,ijkce)**2+dv(dv_mixt_vvel,ijkce)**2+ &
                       dv(dv_mixt_wvel,ijkce)**2 )
#endif
#ifdef RFLU
! Specific Rocflu, check the state of cv first
  IF (region%mixt%cvState /= cv_mixt_state_cons) &
                            CALL errorstop(global,err_reached_default,__line__)
  ibeg  =  1
  iend  =  patch%nBFaces

  DO i=ibeg,iend
        ijkval = i
        ijkc   = patch%bf2c(i)
        ijkce  = ijkc

        abvel  = sqrt( cv(cv_mixt_xmom,ijkce)**2+cv(cv_mixt_ymom,ijkce)**2+ &
                       cv(cv_mixt_zmom,ijkce)**2 )/cv(cv_mixt_dens,ijkce)
#endif
        twall  = mvals(bcdat_noslip_twall,distrib*ijkval)
        cp     = gv(gv_mixt_cp,ijkc*indcp)
        tauwall= vals(ijkval,wlm_vals_hflux)
        vals(ijkval,wlm_vals_hflux) = ratio*tauwall*cp* &
                                      (twall-dv(dv_mixt_temp,ijkce))/abvel

!wlmCheckprobe-----------------------------------------------------------------
!        utau = SQRT( tauWall/vals(ijkVal,WLM_VALS_DENS) )
!        write(*,*)region%procId,nEta,ijkVal,vals(ijkVal,WLM_VALS_DENS),utau, &
!                  tauWall,vals(ijkVal,WLM_VALS_HFLUX)
!------------------------------------------------------------------------------
#ifdef RFLO
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k
#endif
#ifdef RFLU
  ENDDO       ! i
#endif

999 CONTINUE

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_wlmreyanalogy

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_WlmReyAnalogy.F90,v $
! Revision 1.6  2008/12/06 08:44:42  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/08/19 15:40:42  mparmar
! Renamed patch variables
!
! Revision 1.3  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.2  2004/03/25 04:40:41  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:01  wasistho
! changed nomenclature
!
! Revision 1.2  2004/03/02 03:50:55  wasistho
! forgot colon after Id and Log
!
!
!******************************************************************************