TURB_WlmFluxPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute total viscous and heat fluxes through current patch using 
!          wall stress and heat transfer from wall layer model selected.
!
! Description: This routine works in the same way as TURB_VisFluxEddyPatch
!              or TURB_VFluxHybridPatch but using wall stress from wall layer 
!              model instead of mu*Sij or SGS-tau_ij, respectively.
!
! Input: region  = data of current region.
!        patch   = current patch.
!
! Output: mixt%diss = total viscous fluxes added to dissipation
!
! Notes: Unlike the general viscous flux patch routines (TURB_visFluxEdduPatch
!        and TURB_vFluxHybridPatch), this wlm flux routine coverts both eddy
!        viscosity model (EVM, fixed and dynamic Smagorinsky) as well as
!        turbulent stress models (TSM, scale similarity and dynamic mixed).
!
!******************************************************************************
!
! $Id: TURB_WlmFluxPatch.F90,v 1.4 2008/12/06 08:44:42 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_wlmfluxpatch( region,patch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getpatchindices,rflo_getpatchdirection, &
                            rflo_getcelloffset,rflo_getnodeoffset
#endif
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: i, j, k, ic

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: bctype, ijkcb0, ijknb, ijkval
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  REAL(RFREAL)          :: beta, heatflux
  REAL(RFREAL)          :: fd(4),sf(3),twij(3,3)
  REAL(RFREAL), POINTER :: diss(:,:),vals(:,:)

#ifdef RFLO
  INTEGER :: inode, jnode, knode, idir, jdir, kdir
  INTEGER :: ilev, lbound, icoff, ijcoff, inoff, ijnoff
  REAL(RFREAL)          :: sgn
  REAL(RFREAL), POINTER :: sface(:,:)
#endif
#ifdef RFLU
  REAL(RFREAL), POINTER :: fn(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_WlmFluxPatch.F90,v $ $Revision: 1.4 $'

  global => region%global
  CALL registerfunction( global,'TURB_WlmFluxPatch',&
  'TURB_WlmFluxPatch.F90' )

! get dimensions and pointers -------------------------------------------------

  vals   => patch%valBola%vals

#ifdef RFLO
  ilev   =  region%currLevel
  lbound =  patch%lbound
  diss   => region%levels(ilev)%mixt%diss  
#endif  
#ifdef RFLU
  diss   => region%mixt%diss  
#endif  

! get coefficients -----------------------------------------------------------

  bctype = patch%bcType
  beta   = region%mixtInput%betrk(region%irkStep)

#ifdef RFLO

! take the right face vector and make it point outwards ----------------------

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  sgn   = +1._rfreal
  inode = 0
  jnode = 0
  knode = 0
  IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
    sgn   = -1._rfreal
    inode = -idir
    jnode = -jdir
    knode = -kdir
  ENDIF

! get the appropriate face vector --------------------------------------------

  IF (lbound==1 .OR. lbound==2) THEN
    sface => region%levels(ilev)%grid%si
  ELSE IF (lbound==3 .OR. lbound==4) THEN
    sface => region%levels(ilev)%grid%sj
  ELSE
    sface => region%levels(ilev)%grid%sk
  ENDIF

! non-conforming region interface --------------------------------------------

  IF (bctype>=bc_regionint .AND. bctype<=bc_regionint+bc_range) THEN

  ELSE IF (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) THEN

! everything else

  ELSE

! flux in the direction normal to the patch ----------------------------------

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          ijkcb0 = indijk(i      ,j      ,k      ,icoff,ijcoff)  ! bnd cells
          ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)  ! bnd nodes
          ijkval = abs(idir)*indij(j-jbeg,k-kbeg,jend-jbeg+1) + &
                   abs(jdir)*indij(k-kbeg,i-ibeg,kend-kbeg+1) + &
                   abs(kdir)*indij(i-ibeg,j-jbeg,iend-ibeg+1)

          sf(1)  = sgn*sface(xcoord,ijknb)
          sf(2)  = sgn*sface(ycoord,ijknb)
          sf(3)  = sgn*sface(zcoord,ijknb)
#endif
#ifdef RFLU
    ibeg  =  1
    iend  =  patch%nBFaces
    fn    => patch%fn

    DO ic=ibeg,iend
          ijkcb0 = patch%bf2c(ic)
          ijknb  = ic
          ijkval = ic

          sf(1)  = fn(xcoord,ijknb)*fn(xyzmag,ijknb)
          sf(2)  = fn(ycoord,ijknb)*fn(xyzmag,ijknb)
          sf(3)  = fn(zcoord,ijknb)*fn(xyzmag,ijknb)           
#endif

          twij(1,1) = vals(ijkval,wlm_vals_tauux)
          twij(1,2) = vals(ijkval,wlm_vals_tauuy)
          twij(1,3) = vals(ijkval,wlm_vals_tauuz)

          twij(2,1) = vals(ijkval,wlm_vals_tauvx)
          twij(2,2) = vals(ijkval,wlm_vals_tauvy)
          twij(2,3) = vals(ijkval,wlm_vals_tauvz)

          twij(3,1) = vals(ijkval,wlm_vals_tauwx)
          twij(3,2) = vals(ijkval,wlm_vals_tauwy)
          twij(3,3) = vals(ijkval,wlm_vals_tauwz)

          heatflux  = sqrt(sf(1)*sf(1)+sf(2)*sf(2)+sf(3)*sf(3))* &
                      vals(ijkval,wlm_vals_hflux) 

          fd(1) = twij(1,1)*sf(1)+twij(1,2)*sf(2)+twij(1,3)*sf(3)
          fd(2) = twij(2,1)*sf(1)+twij(2,2)*sf(2)+twij(2,3)*sf(3)
          fd(3) = twij(3,1)*sf(1)+twij(3,2)*sf(2)+twij(3,3)*sf(3)
          fd(4) = heatflux

!wlmCheckprobe---------------------------------------------------------------
!    write(*,*)region%procId,i,j,k,twij(1,2),twij(3,2),twij(2,1),twij(2,3), &
!              heatFlux
!----------------------------------------------------------------------------

          diss(cv_mixt_xmom,ijkcb0) = diss(cv_mixt_xmom,ijkcb0)+fd(1)*beta
          diss(cv_mixt_ymom,ijkcb0) = diss(cv_mixt_ymom,ijkcb0)+fd(2)*beta
          diss(cv_mixt_zmom,ijkcb0) = diss(cv_mixt_zmom,ijkcb0)+fd(3)*beta
          diss(cv_mixt_ener,ijkcb0) = diss(cv_mixt_ener,ijkcb0)+fd(4)*beta

#ifdef RFLO
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k
  ENDIF         ! bcType
#endif
#ifdef RFLU
  ENDDO         ! iC
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_wlmfluxpatch

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_WlmFluxPatch.F90,v $
! Revision 1.4  2008/12/06 08:44:42  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/24 03:37:03  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.2  2004/03/02 03:49:30  wasistho
! forgot colon after Id and Log
!
!
!******************************************************************************