TURB_RansEmsUpdate.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update RaNS/DES solution for steady flow or dual time-stepping
!          using explicit multistage scheme
!
! Description: none.
!
! Input: region = data of current region,
!
! Output: region%levels%turb%cv = new solution after each stage.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_RansEmsUpdate.F90,v 1.6 2008/12/06 08:44:42 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_ransemsupdate( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE turb_modparameters
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset
  USE turb_modinterfaces, ONLY : turb_floextrapintcellvec

#include "Indexing.h"
#endif

  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ic, idx
  
! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: istage, ibc, iec, idxb, idxe
  REAL(RFREAL), POINTER :: tcv(:,:), tcvold(:,:), trhs(:,:), dsterm(:,:)
  REAL(RFREAL), POINTER :: vol(:), dt(:)
  REAL(RFREAL)          :: ark(5), fac, adtv, cfl

#ifdef RFLO
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, icoff, ijcoff
#endif

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'TURB_RansEmsUpdate',&
  'TURB_RansEmsUpdate.F90' )

! get parameters, dimensions and pointers -------------------------------------

  istage = region%irkStep
  ark(:) = region%mixtInput%ark(:)
  cfl    = region%mixtInput%cfl

  IF (region%mixtInput%turbModel == turb_model_sa .OR. &
      region%mixtInput%turbModel == turb_model_dessa .OR. &
      region%mixtInput%turbModel == turb_model_hdessa) THEN
    idxb = cv_sa_nutil
    idxe = cv_sa_nutil
  ENDIF

#ifdef RFLO
  ilev  = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
  iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

  tcv     => region%levels(ilev)%turb%cv
  tcvold  => region%levels(ilev)%turb%cvOld
  trhs    => region%levels(ilev)%turb%rhs
  dsterm  => region%levels(ilev)%turb%dsterm
  vol     => region%levels(ilev)%grid%vol
  dt      => region%levels(ilev)%dt
#endif

#ifdef RFLU
  ibc = 1
  iec = region%grid%nCellsTot        

  tcv     => region%turb%cv
  tcvold  => region%turb%cvOld
  trhs    => region%turb%rhs
  dsterm  => region%turb%dsterm
  vol     => region%grid%vol
  dt      => region%dt
#endif

! update RaNS solution -------------------------------------------------------

  fac = ark(istage)*cfl
  DO ic = ibc,iec
    adtv  = fac*dt(ic)/vol(ic)
    DO idx = idxb,idxe
      trhs(idx,ic) = adtv*trhs(idx,ic)
    ENDDO
  ENDDO

  IF (global%solverType == solv_implicit) THEN
    fac = 1.5_rfreal*ark(istage)*cfl/global%dtMin
    DO ic = ibc,iec
      adtv = 1._rfreal/(1._rfreal+fac*dt(ic))
      DO idx = idxb,idxe
        tcv(idx,ic) = tcvold(idx,ic) - adtv*trhs(idx,ic)
      ENDDO
    ENDDO
  ELSE
    DO ic=ibc,iec
      DO idx = idxb,idxe
        tcv(idx,ic) = tcvold(idx,ic) - trhs(idx,ic)
      ENDDO
    ENDDO
  ENDIF

! clipping for stability

  IF (region%mixtInput%turbModel == turb_model_sa .OR. &
      region%mixtInput%turbModel == turb_model_dessa .OR. &
      region%mixtInput%turbModel == turb_model_hdessa) THEN
    DO ic=ibc,iec
      tcv(cv_sa_nutil,ic) = max( tcv(cv_sa_nutil,ic),real_small )
    ENDDO !ic
  ENDIF

! extrapolate solution to dummy cells

#ifdef RFLO
  CALL turb_floextrapintcellvec( region,idxb,idxe,tcv )
#endif
#ifdef RFLU
!  CALL TURB_FluExtrapIntCellVec( region,idxb,idxe,tcv )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_ransemsupdate

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_RansEmsUpdate.F90,v $
! Revision 1.6  2008/12/06 08:44:42  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2005/03/09 06:35:35  wasistho
! incorporated HDESSA
!
! Revision 1.3  2004/03/20 00:29:17  wasistho
! set turb_rflo_ransNumericalDiss to turb_ransNumerical..
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.4  2004/02/12 03:46:24  wasistho
! filled in RaNS lengthscale in dummy cells
!
! Revision 1.3  2004/01/22 04:00:26  wasistho
! replaced dtMod by dt(ic)
!
! Revision 1.2  2003/10/21 20:32:03  wasistho
! added dt relaxation in steady flow due to RANS source term
!
! Revision 1.1  2003/10/16 20:20:03  wasistho
! installed RaNS in steady state flow (Exp.Mult.Stg)
!
!
!******************************************************************************