TO3D_Main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: convert a 2-D grid into ROCFLO`s 3-D format.
!
! Description: none.
!
! Input: none.
!
! Output: none.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TO3D_Main.F90,v 1.4 2008/12/06 08:44:52 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

PROGRAM rocflo_2dto3d

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE to3d_modinterfaces, ONLY : rflo_getdimensphysnodes, &
                                 rflo_getnodeoffset, rflo_writegridregion
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... loop variables
  INTEGER :: i, j, k, ijk, ijkm1

! ... local variables
  CHARACTER(CHRLEN)   :: versionstring, headerstring
  CHARACTER(3*CHRLEN) :: fname2d
 
  INTEGER :: inoff, ijnoff, ijkbeg, ijkend
  INTEGER :: idnbeg, jdnbeg, kdnbeg, idnend, jdnend, kdnend
  INTEGER :: ipnbeg, jpnbeg, kpnbeg, ipnend, jpnend, kpnend
  INTEGER :: margin, versionwidth, errorflag
  INTEGER, PARAMETER :: headerwidth = 53
 
  REAL(RFREAL)          :: depth, dz
  REAL(RFREAL), POINTER :: xyz(:,:)
 
  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: regions(:)

!******************************************************************************

  ALLOCATE( global )

  global%nFunTree = 0
  CALL registerfunction( global,'ROCFLO_2Dto3D',&
  'TO3D_Main.F90' )

! initialize ------------------------------------------------------------------
! global parameters

  global%verbLevel = verbose_high

  global%flowType    = flow_steady  ! stationary flow
  global%currentTime = 0._rfreal    ! no physical time set
  global%currentIter = 0            ! no iteration

  global%inDir  = './'              ! directory path
  global%outDir = './'

  global%nProcAlloc = 1
  global%myProcid   = masterproc    ! default process number (if not MPI)
  global%mpierr     = err_none
  global%error      = err_none

  global%pi  = 4._rfreal*atan(1._rfreal)
  global%rad = global%pi/180._rfreal

! print header ----------------------------------------------------------------

#ifdef MPI
  CALL mpi_init( global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *       ROCFLO-MP: 2-D to 3-D Grid Convertor        *'
  WRITE(stdout,  '(A)') solver_name//'  *       ====================================        *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! region data

  global%nRegions = 1

  ALLOCATE( regions(global%nRegions),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  regions(1)%global            => global
  regions(1)%active             = active
  regions(1)%procid             = global%myProcid
  regions(1)%nPatches           = 1
  regions(1)%nGridLevels        = 1
  regions(1)%nDumCells          = 0
  regions(1)%mixtInput%moveGrid = .false.  ! fixed grid

  ALLOCATE( regions(1)%levels(regions(1)%nGridLevels),stat=errorflag )
  global%error = errorflag
  IF (global%error /=0 ) CALL errorstop( global,err_allocate,__line__ )

! read user input -------------------------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Name of file with 2-D grid:'
  READ(stdin,'(A)') fname2d

  WRITE(stdout,'(A)') solver_name//' Case name:'
  READ(stdin,'(A)') global%casename

  WRITE(stdout,'(A)') solver_name//' Number of cells in the 3rd direction (>1):'
  READ(stdin,*) regions(1)%levels(1)%grid%kpc
  regions(1)%levels(1)%grid%kpc = max(2,regions(1)%levels(1)%grid%kpc)

  WRITE(stdout,'(A)') solver_name//' Depth of the 3-D grid (>0.):'
  READ(stdin,*) depth

  WRITE(stdout,'(A)') solver_name//' Format of 3-D grid (0=ASCII, 1=binary):'
  READ(stdin,*) global%gridFormat

! read the 2-D grid -----------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading 2-D grid ...'

  OPEN(if_grid,file=fname2d,status='old',form='formatted',iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
    CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname2d) )

! dimensions

  READ(if_grid,*) regions(1)%levels(1)%grid%ipc, &
                  regions(1)%levels(1)%grid%jpc

  WRITE(stdout,'(A,I4,A,I4)') solver_name//'   dimensions= ', &
                              regions(1)%levels(1)%grid%ipc, &
                              ' x ',regions(1)%levels(1)%grid%jpc

  CALL rflo_getdimensdummynodes( regions(1),1,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getdimensphysnodes( regions(1),1,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )
  CALL rflo_getnodeoffset( regions(1),1,inoff,ijnoff )

  ijkbeg = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ijkend = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

! allocate memory for coordinates

  ALLOCATE( regions(1)%levels(1)%grid%xyz(3,ijkbeg:ijkend),stat=errorflag )
  global%error = errorflag
  IF (global%error /=0 ) CALL errorstop( global,err_allocate,__line__ )

! coordinates (store as k=kpnbeg plane at z=depth)

  xyz => regions(1)%levels(1)%grid%xyz

  k = kpnbeg
  DO j=jpnbeg,jpnend
    DO i=ipnbeg,ipnend
      ijk = indijk(i,j,k,inoff,ijnoff)
      READ(if_grid,*) xyz(xcoord,ijk), &
                      xyz(ycoord,ijk)
                      xyz(zcoord,ijk) = 0._rfreal
    ENDDO
  ENDDO

! close file

  CLOSE(if_grid,iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
    CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname2d) )

! translate the x-y-plane -----------------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Generating 3-D grid ...'

  dz = depth/REAL(regions(1)%levels(1)%grid%kpc)

  DO k=kpnbeg+1,kpnend
    DO j=jpnbeg,jpnend
      DO i=ipnbeg,ipnend
        ijk   = indijk(i,j,k  ,inoff,ijnoff)
        ijkm1 = indijk(i,j,k-1,inoff,ijnoff)
        xyz(xcoord,ijk) = xyz(xcoord,ijkm1)
        xyz(ycoord,ijk) = xyz(ycoord,ijkm1)
        xyz(zcoord,ijk) = xyz(zcoord,ijkm1) + dz
      ENDDO
    ENDDO
  ENDDO

! store 3-D grid --------------------------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Storing 3-D grid ...'

  CALL rflo_writegridregion( 1,regions )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

  WRITE(stdout,'(/,A)') solver_name//' Finished.'

#ifdef MPI
  CALL mpi_finalize( global%mpierr )
#endif

END PROGRAM rocflo_2dto3d

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TO3D_Main.F90,v $
! Revision 1.4  2008/12/06 08:44:52  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:18:03  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/12/03 03:37:55  wasistho
! rflo_modinterfacesto3d to to3d_modinterfaces
!
! Revision 1.1  2004/12/03 02:50:44  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:52:40  wasistho
! lower to upper case
!
! Revision 1.15  2003/05/15 02:57:07  jblazek
! Inlined index function.
!
! Revision 1.14  2003/03/20 22:37:45  haselbac
! Renamed ModInterfaces
!
! Revision 1.13  2003/03/20 19:49:34  haselbac
! Corrected mistake in phased check-in
!
! Revision 1.12  2002/10/12 03:20:51  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.11  2002/09/20 22:22:37  jblazek
! Finalized integration into GenX.
!
! Revision 1.10  2002/09/05 17:40:23  jblazek
! Variable global moved into regions().
!
! Revision 1.9  2002/07/16 21:34:37  jblazek
! Prefixed screen output with SOLVER_NAME.
!
! Revision 1.8  2002/06/14 17:48:36  jblazek
! Added call to MPI_Finalize.
!
! Revision 1.7  2002/06/14 17:46:51  jblazek
! Added version string.
!
! Revision 1.6  2002/06/07 16:40:37  jblazek
! Grid & solution for all regions in one file.
!
! Revision 1.5  2002/03/18 21:31:55  jblazek
! Made codes compatible with MPI.
!
! Revision 1.4  2002/02/21 23:25:07  jblazek
! Blocks renamed as regions.
!
! Revision 1.3  2002/01/11 17:20:19  jblazek
! Added time stamp or iteration number to file names.
!
! Revision 1.2  2002/01/08 22:09:17  jblazek
! Added calculation of face vectors and volumes.
!
! Revision 1.1  2001/12/21 23:56:52  jblazek
! Added utility to convert 2D grids to 3D.
!
!******************************************************************************