ScaleGridSpeeds.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Scale grid speeds.
!
! Description: None. 
!
! Input: 
!   region     Pointer to region
!
! Output: None.
!
! Notes: 
!   1. Grid speeds need to be scaled because they are derived from an 
!      expression equivalent to a forward Euler discretization, but the actual
!      solution is evolved using the Runge-Kutta scheme. As a result, the 
!      right-hand side differs by a factor involving the Runge-Kutta 
!      coefficients. Its the task of this routine to scale the grid speeds to
!      make up for this discrepancy. 
!   2. Note that at the last Runge-Kutta stage, the coefficient is negative!  
!
!******************************************************************************
!
! $Id: ScaleGridSpeeds.F90,v 1.3 2008/12/06 08:44:10 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE scalegridspeeds( region )

  USE moddatatypes
  USE modgrid,       ONLY: t_grid
  USE moddatastruct, ONLY: t_region
  USE modbndpatch, ONLY  : t_patch
  USE modglobal, ONLY    : t_global
  USE moderror
  USE modparameters
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, rflo_getnodeoffset
#include "Indexing.h"
#endif
#ifdef RFLU
  USE rflu_modgrid
#endif

  IMPLICIT NONE

! *****************************************************************************
! Declarations and definitions
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region) :: region

! =============================================================================
! Locals
! =============================================================================

  INTEGER      :: ifc, ipatch, irk, irkstep
  REAL(RFREAL) :: scalefactor, term
  REAL(RFREAL) :: ark(5), grk(5)
#ifdef RFLO
  INTEGER :: ilev, idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: ibn, ien, inoff, ijnoff, in
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)
#endif
#ifdef RFLU
  REAL(RFREAL), DIMENSION(:), POINTER :: gs
  TYPE(t_patch), POINTER :: ppatch
#endif
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  global => region%global

  CALL registerfunction(global,'ScaleGridSpeeds',&
  'ScaleGridSpeeds.F90')
  
! *****************************************************************************
! Set pointers and variables
! *****************************************************************************

  irkstep = region%irkStep

  ark(:) = region%mixtInput%ark(:)
  grk(:) = region%mixtInput%grk(:)

! *****************************************************************************
! Scale grid speeds
! *****************************************************************************

! =============================================================================
! Determine scaling factor
! ============================================================================= 

  IF ( irkstep > 1 .AND. irkstep < global%nrkSteps ) THEN 
    scalefactor = ark(irkstep-1)/ark(irkstep) 
  ELSE IF ( irkstep == 1 ) THEN
    scalefactor = 1.0_rfreal/ark(irkstep)
  ELSE IF ( irkstep == global%nrkSteps ) THEN
    term = 0.0_rfreal

    DO irk = 1,global%nrkSteps-1
      term = term + grk(irk)/ark(irk)
    END DO ! irk

    scalefactor = (1.0_rfreal/ark(global%nrkSteps) - term)/ark(irkstep-1)    
  ELSE ! Defensive programming
    CALL errorstop(global,err_reached_default,__line__)
  END IF ! irkStep

! =============================================================================
! Interior faces
! ============================================================================= 

#ifdef RFLO
  ilev = region%currLevel
  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

  sivel => region%levels(ilev)%grid%siVel
  sjvel => region%levels(ilev)%grid%sjVel
  skvel => region%levels(ilev)%grid%skVel

  DO in=ibn,ien
    sivel(in) = scalefactor*sivel(in)
    sjvel(in) = scalefactor*sjvel(in)
    skvel(in) = scalefactor*skvel(in)
  ENDDO
#endif

#ifdef RFLU
  gs => region%grid%gs
 
  DO ifc = 1,region%grid%nFaces 
    gs(ifc) = scalefactor*gs(ifc)
  END DO ! ifc

! =============================================================================
! Patch faces
! ============================================================================= 

  DO ipatch = 1,region%grid%nPatches
    ppatch => region%patches(ipatch)
    gs     => ppatch%gs

    DO ifc = 1,ppatch%nBFaces
      gs(ifc) = scalefactor*gs(ifc)
    END DO ! ifc
  END DO ! iPatch
#endif

! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE scalegridspeeds

!******************************************************************************
!
! RCS Revision history:
!
! $Log: ScaleGridSpeeds.F90,v $
! Revision 1.3  2008/12/06 08:44:10  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:23  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 16:51:17  haselbac
! Initial revision after changing case
!
! Revision 1.8  2003/11/20 16:40:35  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.5  2003/10/01 23:52:09  jblazek
! Corrected bug in moving noslip wall BC and grid speeds.
!
! Revision 1.4  2003/05/15 02:57:02  jblazek
! Inlined index function.
!
! Revision 1.3  2003/03/15 16:35:29  haselbac
! Changed loop limit
!
! Revision 1.2  2002/12/02 20:10:41  jblazek
! Moved RFLU_ModGrid inside ifdef RFLU in ScaleGridSpeeds.
!
! Revision 1.1  2002/11/08 21:55:48  haselbac
! Initial revision
!
!******************************************************************************