SPEC_RFLU_ReadBcInputFile.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Read in user input related to boundary conditions for species 
!   (done on all processors).
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: SPEC_RFLU_ReadBcInputFile.F90,v 1.7 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2003-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_rflu_readbcinputfile(pRegion)

  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moderror
  USE modparameters
  USE modmpi
  
  USE modbuildfilenames, ONLY: buildfilenameplain
  
  USE modinterfacesspecies, ONLY: spec_rflu_readbcfarfsection, & 
                                  spec_rflu_readbcinflowsection, & 
                                  spec_rflu_readbcinjectsection, & 
                                  spec_rflu_readbcsectiondummy
  
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: ifilename,rcsidentstring
  CHARACTER(256) :: line
  INTEGER :: errorflag,ipatch,loopcounter
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_grid) :: grid
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: SPEC_RFLU_ReadBcInputFile.F90,v $ $Revision: 1.7 $'

  global => pregion%global

  CALL registerfunction(global,'SPEC_RFLU_ReadBcInputFile',&
  'SPEC_RFLU_ReadBcInputFile.F90')

! ******************************************************************************
! Open file
! ******************************************************************************

  CALL buildfilenameplain(global,filedest_indir,'.bc',ifilename)
  
  OPEN(if_input,file=ifilename,form='FORMATTED',status='OLD',iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) THEN 
    CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! Read file looking for keywords
! ******************************************************************************

  loopcounter = 0

  keywordloop: DO
    READ(if_input,'(A256)',iostat=errorflag) line
    
    IF ( errorflag > 0 ) THEN ! Error occurred
      CALL errorstop(global,err_file_read,__line__,'File: '//trim(ifilename))
    ELSE IF ( errorflag < 0 ) THEN ! Encountered end of file
      EXIT keywordloop
    END IF ! errorFlag    
    
    SELECT CASE( trim(line) )
      CASE ('# BC_SLIPW')
        CALL spec_rflu_readbcsectiondummy(pregion)
      CASE ('# BC_NOSLIP')
        CALL spec_rflu_readbcsectiondummy(pregion)      
! TEMPORARY - Keep this for backward compatibility
      CASE ('# BC_INFLOW')
        CALL spec_rflu_readbcinflowsection(pregion)
! END TEMPORARY    
      CASE ('# BC_INFLOW_TOTANG')
        CALL spec_rflu_readbcinflowsection(pregion)
      CASE ('# BC_INFLOW_VELTEMP')
        CALL spec_rflu_readbcinflowsection(pregion)             
      CASE ('# BC_OUTFLOW')
        CALL spec_rflu_readbcsectiondummy(pregion)      
      CASE ('# BC_FARF')
        CALL spec_rflu_readbcfarfsection(pregion)
      CASE ('# BC_INJECT')
        CALL spec_rflu_readbcinjectsection(pregion)
      CASE ('# END')
        EXIT
    END SELECT ! TRIM(line)

    loopcounter = loopcounter + 1 ! Prevent infinite loop
    IF ( loopcounter >= limit_infinite_loop ) THEN 
      CALL errorstop(global,err_infinite_loop ,__line__)
    END IF ! loopCounter
  END DO keywordloop

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(if_input,iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) THEN 
    CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_rflu_readbcinputfile

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_RFLU_ReadBcInputFile.F90,v $
! Revision 1.7  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:25  haselbac
! Removed tabs
!
! Revision 1.4  2005/04/27 02:13:37  haselbac
! Added routine to read INFLOW_VELTEMP
!
! Revision 1.3  2005/03/31 17:20:03  haselbac
! Fixed problem with crashes by reading with dummy routine
!
! Revision 1.2  2004/06/16 20:01:23  haselbac
! Added use of ModBuildFileNames, cosmetics
!
! Revision 1.1  2003/11/25 21:08:37  haselbac
! Initial revision
!
! ******************************************************************************