SPEC_RFLU_ReadBcInjectSection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Read in user input related to injection boundary condition for 
!   species.
!
! Description: None.
!
! Input: 
!   pRegion     Region pointer
!
! Output: None.
!
! Notes: 
!   1. Define additional keyword, SPEC_, which can be used to set a default 
!      for all species. Individual species can be overridden by specifying
!      the appropriate keyword SPECn. 
!
!******************************************************************************
!
! $Id: SPEC_RFLU_ReadBcInjectSection.F90,v 1.5 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE spec_rflu_readbcinjectsection(pRegion)

  USE moddatatypes
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE moderror
  USE modparameters
  
  USE modinterfaces, ONLY: makenumberedkeys,readpatchsection 

  IMPLICIT NONE

! *****************************************************************************
! Definitions and declarations
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region), POINTER :: pregion

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: bcname,rcsidentstring
  CHARACTER(10), DIMENSION(:), ALLOCATABLE :: keys
  CHARACTER(256) :: filename
  LOGICAL, DIMENSION(:), ALLOCATABLE :: defined
  INTEGER :: checksum,distrib,errorflag,ifc,ikey,ipatch,ipatchbeg,ipatchend, &
             ireg,ival,nbfacestot,nkeys
  REAL(RFREAL), DIMENSION(:), ALLOCATABLE :: vals
  TYPE(t_grid) :: grid
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: SPEC_RFLU_ReadBcInjectSection.F90,v $ $Revision: 1.5 $'

  global => pregion%global

  CALL registerfunction(global,'SPEC_RFLU_ReadBcInjectSection',&
  'SPEC_RFLU_ReadBcInjectSection.F90')

! *****************************************************************************
! Allocate memory 
! *****************************************************************************

  nkeys = pregion%specInput%nSpecies + 1 ! Add one because of default key

  ALLOCATE(keys(nkeys),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'keys')
  END IF ! global%error

  ALLOCATE(vals(nkeys),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'vals')
  END IF ! global%error  

  ALLOCATE(defined(nkeys),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'defined')
  END IF ! global%error 

! *****************************************************************************
! Generate keys. NOTE first key is default key.
! *****************************************************************************

  keys(1) = 'SPEC_'
  
  CALL makenumberedkeys(keys,2,'SPEC',1,nkeys,1)

! *****************************************************************************
! Read section
! *****************************************************************************

  CALL readpatchsection(global,if_input,nkeys,keys,vals,ipatchbeg,ipatchend, &
                        distrib,filename,bcname,defined)

! *****************************************************************************
! Check if specified number of patches exceeds available ones
! *****************************************************************************

  IF ( ipatchend > global%nPatches ) THEN 
    CALL errorstop(global,err_patch_range,__line__)
  END IF ! iPatchEnd

! *****************************************************************************
! Set options and check if all necessary values defined
! *****************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

! =============================================================================
!   Check whether this global patch exists in this region
! =============================================================================

    IF ( ppatch%iPatchGlobal >= ipatchbeg .AND. & 
         ppatch%iPatchGlobal <= ipatchend ) THEN

! -----------------------------------------------------------------------------
!     Set options. NOTE at this stage, have already read information for 
!     mixture, so for GENx runs, pPatch%bcCoupled has been set and checked. 
!     Hence can use it directly to determine whether need distribution.
! -----------------------------------------------------------------------------

      ppatch%spec%nData     = pregion%specInput%nSpecies
      ppatch%spec%nSwitches = 0
      
      IF ( ppatch%bcCoupled == bc_burning ) THEN 
        ppatch%spec%distrib = bcdat_distrib ! MUST have distribution
      ELSE 
        ppatch%spec%distrib = distrib 
      END IF ! pPatch%bcCoupled

! -----------------------------------------------------------------------------
!     Check whether all values defined (if no default defined)
! -----------------------------------------------------------------------------

      IF ( defined(1) .EQV. .false. ) THEN ! No default defined
        checksum = 0
      
        DO ikey = 2,nkeys
          IF ( defined(ikey) .EQV. .true. ) THEN 
            checksum = checksum + 1
          END IF ! defined
        END DO ! iKey
        
        IF ( checksum /= pregion%specInput%nSpecies ) THEN 
          CALL errorstop(global,err_bcval_missing,__line__)
        END IF ! checkSum 
      END IF ! defined(1)

    END IF ! pPatch%iPatchGlobal
  END DO ! iPatch

! *****************************************************************************
! Copy values/distribution to variables
! *****************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

! =============================================================================
!   Check whether this global patch exists in this region
! =============================================================================

    IF ( ppatch%iPatchGlobal >= ipatchbeg .AND. & 
         ppatch%iPatchGlobal <= ipatchend ) THEN

! -----------------------------------------------------------------------------
!     Distribution 
! -----------------------------------------------------------------------------

      IF ( ppatch%spec%distrib == bcdat_distrib ) THEN
        nbfacestot = ppatch%nBTrisTot + ppatch%nBQuadsTot
        
        ALLOCATE(ppatch%spec%vals(ppatch%spec%nData,nbfacestot), & 
                 stat=errorflag)                              
        global%error = errorflag         
        IF ( global%error /= 0 ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%spec%vals')
        END IF ! global        

! ----- If not coupled, get boundary data from file ---------------------------

        IF ( ppatch%bcCoupled == bc_not_coupled ) THEN          
          CALL errorstop(global,err_reached_default,__line__)
        ELSE ! initialize - important for GENX runs from scratch
          DO ifc = 1,nbfacestot
            DO ival = 1,ppatch%spec%nData
              ppatch%spec%vals(ival,ifc) = 0.0_rfreal
            END DO ! iVal
          END DO ! ifc
        END IF ! pPatch%bcCoupled

! -----------------------------------------------------------------------------
!     Constant value
! -----------------------------------------------------------------------------

      ELSE
        ALLOCATE(ppatch%spec%vals(ppatch%spec%nData,0:1), & 
                 stat=errorflag)
        global%error = errorflag         
        IF ( global%error /= 0 ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%spec%vals')
        END IF ! global%error

        DO ival = 1,ppatch%spec%nData
          IF ( defined(1+ival) .EQV. .true. ) THEN ! Set to input
            ppatch%spec%vals(ival,0:1) = vals(1+ival)                      
          ELSE ! Set to default
            ppatch%spec%vals(ival,0:1) = vals(1)
          END IF ! defined          
        END DO ! iVal
      END IF  ! pPatch%spec%distrib
    END IF ! pPatch%iPatchGlobal
  END DO ! iPatch

! *****************************************************************************
! Deallocate memory 
! *****************************************************************************

  DEALLOCATE(keys,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'keys')
  END IF ! global%error

  DEALLOCATE(vals,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'vals')
  END IF ! global%error  

  DEALLOCATE(defined,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'defined')
  END IF ! global%error 
  
! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_rflu_readbcinjectsection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_RFLU_ReadBcInjectSection.F90,v $
! Revision 1.5  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/08/19 15:40:32  mparmar
! Renamed patch variables
!
! Revision 1.2  2006/04/07 15:19:25  haselbac
! Removed tabs
!
! Revision 1.1  2003/11/25 21:08:37  haselbac
! Initial revision
!
!******************************************************************************