SPEC_EqEulCorr.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute Equilibrium Eulerian correction to species mass fluxes and 
!   overall mass flux for interior faces.
!
! Description: None.
!
! Input:
!   pRegion        Pointer to data of current region
!   iSpec          Index of species
!
! Output: None.
!
! Notes:
!  1. By passing iSpec, rather than looping over all iSpec inside the face
!     loop, this routine is optimized for the case of a few Eq Eul species 
!     among many non Eq Eul (e.g., gas species).
!
! ******************************************************************************
!
! $Id: SPEC_EqEulCorr.F90,v 1.8 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_eqeulcorr(pRegion,iSpec)

  USE moddatatypes
  USE moderror
  USE modparameters
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid  
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE modspecies, ONLY: t_spec_type  

  USE spec_modparameters

  USE spec_modinterfaces, ONLY: spec_eqeulcorrpatch

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: ispec
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: c1,c2,ifl,ipatch,ispeceev
  REAL(RFREAL) :: eo1,eo2,flx,idens,ir1,ir2,nx,ny,nz,nm,phi1,phi2,p1,p2,ry, &
                  ry1,ry2,r1,r2,taucoef,term,ts1,ts2,ug,ug1,ug2,us,us1,us2, &
                  vg,vg1,vg2,vs,vs1,vs2,wg,wg1,wg2,ws,ws1,ws2             
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvmixt,pcvspec,pdvmixt,psd, &
                                           rhsmixt,rhsspec
  REAL(RFREAL), DIMENSION(:,:,:), POINTER :: peev
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_spec_type), POINTER :: pspectype  

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: SPEC_EqEulCorr.F90,v $ $Revision: 1.8 $'

  global => pregion%global

  CALL registerfunction(global,'SPEC_EqEulCorr',&
  'SPEC_EqEulCorr.F90')

! ******************************************************************************
! Set dimensions and pointers
! ******************************************************************************

  pgrid   => pregion%grid
  psd     => pregion%mixt%sd
  pcvmixt => pregion%mixt%cv
  pcvspec => pregion%spec%cv
  pdvmixt => pregion%mixt%cv  
  rhsmixt => pregion%mixt%rhs
  rhsspec => pregion%spec%rhs
  peev    => pregion%spec%eev  

  pspectype => pregion%specInput%specType(ispec)  

  taucoef  = pspectype%tauCoefficient
  ispeceev = pspectype%iSpec2iSpecEEv
  idens    = 1.0_rfreal/pspectype%pMaterial%dens

! ******************************************************************************
! Checks: Defensive coding, should never occur
! ******************************************************************************

  IF ( pspectype%discreteFlag .EQV. .false. ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pSpecType%discreteFlag

  IF ( pspectype%velocityMethod /= spec_methv_eqeul ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pSpecType%velocityMethod

  IF ( taucoef <= 0.0_rfreal ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! tauCoef

  IF ( pregion%mixtInput%indSd /= 1 ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pRegion%mixtInput%indSd

  IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN
    CALL errorstop(global,err_cv_state_invalid,__line__)
  END IF ! pRegion%mixt%cvState
  
  IF ( pregion%spec%cvState /= cv_mixt_state_cons ) THEN
    CALL errorstop(global,err_cv_state_invalid,__line__)
  END IF ! pRegion%spec%cvState  

! ******************************************************************************
! Compute fluxes
! ******************************************************************************

  DO ifl = 1,pgrid%nFaces
    c1 = pgrid%f2c(1,ifl)
    c2 = pgrid%f2c(2,ifl)

    nx = pgrid%fn(xcoord,ifl)
    ny = pgrid%fn(ycoord,ifl)
    nz = pgrid%fn(zcoord,ifl)
    nm = pgrid%fn(xyzmag,ifl)

! ==============================================================================
!   Get data
! ==============================================================================

    ir1 = 1.0_rfreal/pcvmixt(cv_mixt_dens,c1)
    ug1 = ir1*pcvmixt(cv_mixt_xmom,c1)
    vg1 = ir1*pcvmixt(cv_mixt_ymom,c1)
    wg1 = ir1*pcvmixt(cv_mixt_zmom,c1)
    eo1 = ir1*pcvmixt(cv_mixt_ener,c1)
    p1  =     pdvmixt(dv_mixt_pres,c1)
    
    ir2 = 1.0_rfreal/pcvmixt(cv_mixt_dens,c2)
    ug2 = ir2*pcvmixt(cv_mixt_xmom,c2)
    vg2 = ir2*pcvmixt(cv_mixt_ymom,c2)
    wg2 = ir2*pcvmixt(cv_mixt_zmom,c2) 
    eo2 = ir2*pcvmixt(cv_mixt_ener,c2) 
    p2  =     pdvmixt(dv_mixt_pres,c2)                   

    ry1 = pcvspec(ispec,c1)
    ry2 = pcvspec(ispec,c2)
    
    phi1 = ry1*idens
    phi2 = ry2*idens

    us1 = peev(eev_spec_xvel,ispeceev,c1)
    vs1 = peev(eev_spec_yvel,ispeceev,c1)
    ws1 = peev(eev_spec_zvel,ispeceev,c1) 
    ts1 = peev(eev_spec_temp,ispeceev,c1) 
    
    us2 = peev(eev_spec_xvel,ispeceev,c2)
    vs2 = peev(eev_spec_yvel,ispeceev,c2)
    ws2 = peev(eev_spec_zvel,ispeceev,c2)
    ts2 = peev(eev_spec_temp,ispeceev,c2)    

! ==============================================================================
!   Compute fluxes
! ==============================================================================

    ry = 0.5_rfreal*(ry1 + ry2)

    ug = 0.5_rfreal*(ug1 + ug2)
    vg = 0.5_rfreal*(vg1 + vg2)
    wg = 0.5_rfreal*(wg1 + wg2)

    us = 0.5_rfreal*(us1 + us2)
    vs = 0.5_rfreal*(vs1 + vs2)
    ws = 0.5_rfreal*(ws1 + ws2)
            
! TEMPORARY
    flx = ((us-ug)*nx + (vs-vg)*ny + (ws-wg)*nz)*nm    
!    flx = 0.0_RFREAL
! END TEMPORARY

    term = ry*flx

! ==============================================================================
!   Accumulate into residuals
! ==============================================================================

    rhsspec(ispec       ,c1) = rhsspec(ispec       ,c1) + term
    rhsspec(ispec       ,c2) = rhsspec(ispec       ,c2) - term

    rhsmixt(cv_mixt_dens,c1) = rhsmixt(cv_mixt_dens,c1) + term
    rhsmixt(cv_mixt_dens,c2) = rhsmixt(cv_mixt_dens,c2) - term    
    
    rhsmixt(cv_mixt_xmom,c1) = rhsmixt(cv_mixt_xmom,c1) + term*ug1
    rhsmixt(cv_mixt_xmom,c2) = rhsmixt(cv_mixt_xmom,c2) - term*ug2  
    
    rhsmixt(cv_mixt_ymom,c1) = rhsmixt(cv_mixt_ymom,c1) + term*vg1
    rhsmixt(cv_mixt_ymom,c2) = rhsmixt(cv_mixt_ymom,c2) - term*vg2  
    
    rhsmixt(cv_mixt_zmom,c1) = rhsmixt(cv_mixt_zmom,c1) + term*wg1
    rhsmixt(cv_mixt_zmom,c2) = rhsmixt(cv_mixt_zmom,c2) - term*wg2
    
    rhsmixt(cv_mixt_ener,c1) = rhsmixt(cv_mixt_ener,c1) + term*eo1 + flx*p1*phi1
    rhsmixt(cv_mixt_ener,c2) = rhsmixt(cv_mixt_ener,c2) - term*eo2 - flx*p2*phi2                
  END DO ! ifl

! ******************************************************************************
! Compute fluxes through boundary faces
! ******************************************************************************

  DO ipatch=1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)
    
    CALL spec_eqeulcorrpatch(pregion,ppatch,ispec)
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_eqeulcorr

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_EqEulCorr.F90,v $
! Revision 1.8  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.7  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.6  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.5  2005/11/27 02:08:47  haselbac
! Rewrote to take advantage of EEv
!
! Revision 1.4  2005/11/17 14:40:39  haselbac
! Added corrections to momentum and energy equations
!
! Revision 1.3  2005/11/10 02:34:15  haselbac
! Added support for gravity
!
! Revision 1.2  2005/03/31 17:17:15  haselbac
! Changed computation of correction, cosmetics
!
! Revision 1.1  2004/07/30 22:47:37  jferry
! Implemented Equilibrium Eulerian method for Rocflu
!
! ******************************************************************************