SPEC_EqEulCorrPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute Equilibrium Eulerian correction to species mass fluxes and 
!   overall mass flux for boundary faces.
!
! Description: None.
!
! Input:
!   pRegion        Pointer to data of current region
!   pPatch         Pointer to data of current patch
!   iSpec          Index of species
!
! Output: None.
!
! Notes:
!   1. Outflow boundary conditions have a modified flux due to the Equilibrium
!      Eulerian velocity correction
!   2. Inflow  boundary conditions have unmodified fluxes: the total mass flux 
!      is specified, and has already been accounted for
!
! ******************************************************************************
!
! $Id: SPEC_EqEulCorrPatch.F90,v 1.6 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_eqeulcorrpatch(pRegion,pPatch,iSpec)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE modbndpatch, ONLY: t_bcvalues,t_patch
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE moderror
  USE modparameters

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: ispec
  TYPE(t_region), POINTER :: pregion
  TYPE(t_patch), POINTER :: ppatch

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: bctype,c1,ifl
  REAL(RFREAL) :: flx,gx,gy,gz,nx,ny,nz,nm,sd1x,sd1y,sd1z,sdf,taucoef
  REAL(RFREAL), DIMENSION(:), POINTER :: pmfmixt
  REAL(RFREAL), DIMENSION(:,:), POINTER :: psd,pcvspec,ptvmixt,rhsmixt,rhsspec
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: SPEC_EqEulCorrPatch.F90,v $ $Revision: 1.6 $'

  global => pregion%global

  CALL registerfunction(global,'SPEC_EqEulCorrPatch',&
  'SPEC_EqEulCorrPatch.F90')

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pgrid   => pregion%grid
  pmfmixt => ppatch%mfMixt

  psd     => pregion%mixt%sd
  pcvspec => pregion%spec%cv
  ptvmixt => pregion%mixt%tv  
  rhsmixt => pregion%mixt%rhs  
  rhsspec => pregion%spec%rhs

  bctype  =  ppatch%bcType

  taucoef =  pregion%specInput%specType(ispec)%tauCoefficient

! ******************************************************************************
! Checks: Defensive coding, should never occur
! ******************************************************************************

  IF ( pregion%specInput%specType(ispec)%discreteFlag .EQV. .false. ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pRegion%specInput

  IF ( pregion%specInput%specType(ispec)%velocityMethod /= &
       spec_methv_eqeul ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pRegion%specInput

  IF ( taucoef <= 0.0_rfreal ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! tauCoef

  IF ( pregion%mixtInput%indSd /= 1 ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pRegion%mixtInput%indSd

  IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN
    CALL errorstop(global,err_cv_state_invalid,__line__)
  END IF ! pRegion%mixt%cvState

! ******************************************************************************
! Set gravity vector for settling velocity
! ******************************************************************************

  IF ( (global%accelOn .EQV. .true.) .AND. &  
       (pregion%specInput%specType(ispec)%settlingFlag .EQV. .true.) ) THEN 
    gx = global%accelX
    gy = global%accelY
    gz = global%accelZ
  ELSE 
    gx = 0.0_rfreal
    gy = 0.0_rfreal
    gz = 0.0_rfreal            
  END IF ! global%accelOn
  
! ******************************************************************************
! Select boundary type
! ******************************************************************************

  SELECT CASE ( bctype )

! ==============================================================================
!   Inflow: No additional terms
! ==============================================================================

    CASE ( bc_inflow_totang,bc_inflow_veltemp )

! ==============================================================================
!   Outflow: No test on pMfMixt: for consistency with RFLU_ScalarFirstPatch
! ==============================================================================

    CASE ( bc_outflow )   
      DO ifl = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifl)

        nx = ppatch%fn(xcoord,ifl)
        ny = ppatch%fn(ycoord,ifl)
        nz = ppatch%fn(zcoord,ifl)
        nm = ppatch%fn(xyzmag,ifl)

        sd1x = psd(sd_xmom,c1)
        sd1y = psd(sd_ymom,c1)
        sd1z = psd(sd_zmom,c1)

        sdf = ((sd1x-gx)*nx + (sd1y-gy)*ny + (sd1z-gz)*nz)/ptvmixt(tv_mixt_muel,c1)
        
        flx = -taucoef*sdf*pcvspec(ispec,c1)*nm

        rhsspec(ispec,c1) = rhsspec(ispec,c1) + flx
        
        rhsmixt(cv_mixt_dens,c1) = rhsmixt(cv_mixt_dens,c1) + flx          
      END DO ! ifl

! ==============================================================================
!   Slip wall: No additional terms
! ==============================================================================

    CASE ( bc_slipwall )

! ==============================================================================
!   No-slip wall: No additional terms
! ==============================================================================

    CASE ( bc_noslipwall_hflux,bc_noslipwall_temp )

! ==============================================================================
!   Farfield
! ==============================================================================

    CASE ( bc_farfield )
      DO ifl = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifl)

        IF ( pmfmixt(ifl) > 0.0_rfreal ) THEN ! Outflow
          nx = ppatch%fn(xcoord,ifl)
          ny = ppatch%fn(ycoord,ifl)
          nz = ppatch%fn(zcoord,ifl)
          nm = ppatch%fn(xyzmag,ifl)

          sd1x = psd(sd_xmom,c1)
          sd1y = psd(sd_ymom,c1)
          sd1z = psd(sd_zmom,c1)

          sdf = ((sd1x-gx)*nx + (sd1y-gy)*ny + (sd1z-gz)*nz)/ptvmixt(tv_mixt_muel,c1)

          flx = -taucoef*sdf*pcvspec(ispec,c1)*nm

          rhsspec(ispec,c1) = rhsspec(ispec,c1) + flx
          
          rhsmixt(cv_mixt_dens,c1) = rhsmixt(cv_mixt_dens,c1) + flx            
        END IF ! pMfMixt
      END DO ! ifl

! ==============================================================================
!   Injection: No additional terms
! ==============================================================================

    CASE ( bc_injection )
    
! ==============================================================================
!   Virtual 
! ==============================================================================

    CASE ( bc_virtual )    

! ==============================================================================
!   Default
! ==============================================================================

    CASE default
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! bcType

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_eqeulcorrpatch

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_EqEulCorrPatch.F90,v $
! Revision 1.6  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2005/11/10 02:34:41  haselbac
! Added support for gravity, cleaned up patch CASE statement
!
! Revision 1.3  2005/10/05 14:24:10  haselbac
! Bug fix: Missing definition of pTvMixt
!
! Revision 1.2  2005/03/31 17:17:41  haselbac
! Changed computation of correction, cosmetics
!
! Revision 1.1  2004/07/30 22:47:37  jferry
! Implemented Equilibrium Eulerian method for Rocflu
!
! ******************************************************************************