RVAV_ExtractVariables.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: extract that primitive and derived variables for a thermally and 
!          calorically perfect gas mixture. the extracted variables (ev) are
!          stored in 3D arrays ev(ibeg:iend,jbeg:jend,kbeg:kend). for the 
!          moment we have not incorporated the ijump, jjunp and kjump options
!
! Description: this subroutine work with Stream1 & Stream2
!
! Input: region            ! the region from which we are extracting
!        ibeg, iend, ijump ! the dimensions of the subregion of the region
!        jbeg, jend, jjump !                       
!        kbeg, kend, kjump !                       
!
! Output: ev = extracted variables (e.g.: rho, u, v, w, p, T, s, omega )
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RVAV_ExtractVariables.F90,v 1.3 2008/12/06 08:45:08 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rvav_extractvariables( global, region,            &
                                          ibeg, iend, ijump, &
                                          jbeg, jend, jjump, &
                                          kbeg, kend, kjump, &
                                          icoff, ijcoff, &
                                          variableindex,     &
                                          filetype,          &
                                          indcp, indmol, ev )

  USE modmpi
  USE modparameters
  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modgrid, ONLY       : t_grid
  USE modmixture, ONLY    : t_mixt
  USE moderror
  USE modinterfaces, ONLY : rflo_getcelloffset 
  USE rvav_modparameters
  USE rvav_modglobal
  IMPLICIT NONE

#include "Indexing.h"

! ... variables in the parameter list of the subroutine
  TYPE(t_region) :: region
  TYPE(t_global), POINTER :: global
  INTEGER :: ibeg, iend, ijump, jbeg, jend, jjump, kbeg, kend, kjump
  INTEGER :: icoff, ijcoff
  INTEGER :: indcp, indmol
  INTEGER :: variableindex
  INTEGER :: filetype
  REAL(RFREAL), POINTER :: ev(:,:,:) ! this is an array for a single extracted
                                     ! variable with i,j,k dimensions

! ... local variables
  CHARACTER(CHRLEN) :: msg

  INTEGER :: ipc, jpc, kpc ! the indices of the physical cells
  INTEGER :: ic            ! the cell index which is obtained from (ipc,jpc,kpc)
                           ! by using the IndIJK function in Indexing.h
  INTEGER :: is, js, ks    ! the indices of the shifted cells
  INTEGER :: ilev, ioffset, ijoffset
  TYPE(t_grid),   POINTER :: grid
  TYPE(t_mixt),   POINTER :: mixt
  REAL(RFREAL), POINTER :: cv(:,:), gv(:,:)

  REAL(RFREAL) :: rgas, gamma, rhoq, pressure, temperature, sound_speed, &
                  mach_number

!******************************************************************************

  CALL registerfunction( global, 'RVAV_ExtractVariables',&
  'RVAV_ExtractVariables.F90' )

! ... set local pointers to the global pointers

  ilev = global%startLevel
  grid => region%levels(ilev)%grid
  mixt => region%levels(ilev)%mixt
  cv   => mixt%cv
  gv   => mixt%gv

! ... get the offsets for the region
  
  IF ( global%verbLevel/=verbose_none ) THEN
    WRITE(stdout,'(/,A)')        'RVAV Extract'
    WRITE(stdout,'(A,3(I5,3X))') '  ibeg,iend,ijump',ibeg,iend,ijump
    WRITE(stdout,'(A,3(I5,3X))') '  jbeg,jend,jjump',jbeg,jend,jjump
    WRITE(stdout,'(A,3(I5,3X))') '  kbeg,kend,kjump',kbeg,kend,kjump
    WRITE(stdout,'(A,3(I5,3X))') '  iLev,iCOff,ijCOff',ilev,icoff,ijcoff
  END IF !verbLevel
  
  SELECT CASE ( filetype )

    CASE (file_computed)
        ioffset  = icoff
        ijoffset = ijcoff

    CASE (file_analytical)
        ioffset  = iend-ibeg+1
        ijoffset = ioffset* (jend-jbeg+1)
        IF (globalrvav%SimilarityTypeS2==rvav_blasius) THEN
          ioffset = icoff
          ijoffset = icoff*(jend-jbeg+1) 
        ENDIF
    CASE (file_experimental)
        ioffset  = iend-ibeg+1
        ijoffset = ioffset* (jend-jbeg+1)

  END SELECT

  IF ( global%verbLevel/=verbose_none ) THEN
    WRITE(stdout,'(A,3(I5,3X))') '  iLev,iOffset,ijOffset',ilev,ioffset,ijoffset
  END IF !verbLevel
  
! ... loop over the ipc,jpc,kpc indices to get the extracted variable (ev)

  DO kpc = kbeg, kend, kjump
    DO jpc = jbeg, jend, jjump
      DO ipc = ibeg, iend, ijump

! ... convert the ipc, jpc, kpc indices to the cell index ic
        ic = indijk( ipc, jpc, kpc, ioffset, ijoffset )

        is = int(REAL(ipc-ibeg,kind=rfreal)/REAL(ijump,kind=rfreal))+1
        js = int(REAL(jpc-jbeg,kind=rfreal)/REAL(jjump,kind=rfreal))+1
        ks = int(REAL(kpc-kbeg,kind=rfreal)/REAL(kjump,kind=rfreal))+1

! ... calculate some of the gas constants needed for variable extraction

        IF ( filetype == file_computed  ) THEN

          rgas = 8314.3_rfreal/gv(gv_mixt_mol, ic*indmol)
          gamma = gv(gv_mixt_cp,ic*indcp)/( gv(gv_mixt_cp,ic*indcp)-rgas )
  
! ... select appropriate cases 

        SELECT CASE( variableindex )
          CASE( rvav_rho )
            ev( is, js, ks ) =  cv(cv_mixt_dens, ic)

          CASE( rvav_rhou )
            ev( is, js, ks ) =  cv(cv_mixt_xmom, ic)

          CASE( rvav_rhov )
            ev( is, js, ks ) =  cv(cv_mixt_ymom, ic)

          CASE( rvav_rhow )
            ev( is, js, ks ) =  cv(cv_mixt_zmom, ic)

          CASE( rvav_rhoet )
            ev( is, js, ks ) =  cv(cv_mixt_ener, ic)

          CASE( rvav_u )
            ev( is, js, ks ) =  cv(cv_mixt_xmom, ic)/cv(cv_mixt_dens, ic)

          CASE( rvav_v )
            ev( is, js, ks ) =  cv(cv_mixt_ymom, ic)/cv(cv_mixt_dens, ic)

          CASE( rvav_w )
            ev( is, js, ks ) =  cv(cv_mixt_zmom, ic)/cv(cv_mixt_dens, ic)

          CASE( rvav_p )
            rhoq = 0.5_rfreal* &
                   ( 1.0_rfreal/cv(cv_mixt_dens,ic) )* &
                   ( cv(cv_mixt_xmom,ic)*cv(cv_mixt_xmom,ic) + &
                     cv(cv_mixt_ymom,ic)*cv(cv_mixt_ymom,ic) + &
                     cv(cv_mixt_zmom,ic)*cv(cv_mixt_zmom,ic) )
            ev( is, js, ks ) =  ( gamma-1._rfreal )* &
                                   ( cv(cv_mixt_ener, ic) - rhoq )

          CASE( rvav_t )
            rhoq = 0.5_rfreal* &
                   ( 1.0_rfreal/cv(cv_mixt_dens,ic) )* &
                   ( cv(cv_mixt_xmom,ic)*cv(cv_mixt_xmom,ic) + &
                     cv(cv_mixt_ymom,ic)*cv(cv_mixt_ymom,ic) + &
                     cv(cv_mixt_zmom,ic)*cv(cv_mixt_zmom,ic) )
            pressure =  ( gamma-1._rfreal )* &
                        ( cv(cv_mixt_ener, ic) - rhoq )
            ev( is, js, ks ) = pressure/( cv(cv_mixt_dens, ic)*rgas )

          CASE( rvav_tstag )
            rhoq = 0.5_rfreal* &
                   ( 1.0_rfreal/cv(cv_mixt_dens,ic) )* &
                   ( cv(cv_mixt_xmom,ic)*cv(cv_mixt_xmom,ic) + &
                     cv(cv_mixt_ymom,ic)*cv(cv_mixt_ymom,ic) + &
                     cv(cv_mixt_zmom,ic)*cv(cv_mixt_zmom,ic) )
            pressure =  ( gamma-1._rfreal )* &
                        ( cv(cv_mixt_ener, ic) - rhoq )
            temperature = pressure/( cv(cv_mixt_dens, ic)*rgas )
            sound_speed = sqrt(gamma*rgas*temperature)
            mach_number = sqrt(2.0_rfreal*rhoq/cv(cv_mixt_dens,ic))/sound_speed
            ev( is, js, ks ) = (1.0_rfreal + &
                                  0.5_rfreal*(gamma-1.0_rfreal)* &
                                  mach_number*mach_number)*&
                                  temperature

          CASE( rvav_pstag )
            rhoq = 0.5_rfreal* &
                   ( 1.0_rfreal/cv(cv_mixt_dens,ic) )* &
                   ( cv(cv_mixt_xmom,ic)*cv(cv_mixt_xmom,ic) + &
                     cv(cv_mixt_ymom,ic)*cv(cv_mixt_ymom,ic) + &
                     cv(cv_mixt_zmom,ic)*cv(cv_mixt_zmom,ic) )
            pressure =  ( gamma-1._rfreal )* &
                        ( cv(cv_mixt_ener, ic) - rhoq )
            temperature = pressure/( cv(cv_mixt_dens, ic)*rgas )
            sound_speed = sqrt(gamma*rgas*temperature)
            mach_number = sqrt(2.0_rfreal*rhoq/cv(cv_mixt_dens,ic))/sound_speed
            ev( is, js, ks ) = 1.0_rfreal + &
                                  0.5_rfreal*(gamma-1.0_rfreal)* &
                                  mach_number*mach_number
            ev( is, js, ks ) = (ev( is, js, ks)**(gamma/(gamma-1.0_rfreal)))*&
                                  pressure
        END SELECT
        END IF ! fileType

! - For Analytical and Experimental Extract as is while shifting cv by 3.

        IF ( filetype == file_analytical .OR. &
             filetype == file_experimental     ) THEN

          ev( is, js, ks ) = cv(variableindex-zcoord,ic)

       END IF ! fileType


! ... DO NOT DEALLOCATE ev. It is a pointer that is required outside this code
! ... No derived variables  such as entropy and vorticity.

      ENDDO
    ENDDO
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rvav_extractvariables

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RVAV_ExtractVariables.F90,v $
! Revision 1.3  2008/12/06 08:45:08  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:18:18  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 22:43:21  fnajjar
! Initial revision after changing case
!
! Revision 1.11  2003/11/21 23:40:45  fnajjar
! Remove quotes from comment lines as it confuses the compiler
!
! Revision 1.10  2003/11/20 16:40:41  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.6  2003/05/15 02:57:08  jblazek
! Inlined index function.
!
! Revision 1.5  2002/09/10 00:01:45  f-najjar
! Variable global moved into regions()
!
! Revision 1.4  2002/06/24 15:50:10  f-najjar
! Fixed Offset for Blasius
!
! Revision 1.3  2002/06/19 20:22:40  f-najjar
! Cleaned unnecessary PRINT statement
!
! Revision 1.2  2002/06/15 17:28:52  f-najjar
! Bug Fix of iOffSet and ijOffset
!
! Revision 1.1.1.1  2002/06/03 21:41:29  f-najjar
! Initial Import of RocVaV
!