RFLU_InitBcDataHardCode.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Initialize boundary-condition data using hard-coded values.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: 
!   1. This routine assumes a perfect gas.
!
! ******************************************************************************
!
! $Id: RFLU_InitBcDataHardCode.F90,v 1.7 2008/12/06 08:44:56 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_initbcdatahardcode(pRegion)

  USE moddatatypes
  USE moderror
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modparameters
    
  USE rflu_modexactflow, ONLY: rflu_computeexactflowproudman, & 
                               rflu_computeexactflowringleb, & 
                               rflu_computeexactflowssvortex      
  USE rflu_modflowhardcode, ONLY: rflu_getparamshardcodeproudman, & 
                                  rflu_getparamshardcoderingleb, & 
                                  rflu_getparamshardcodessvortex    
    
  USE modinterfaces, ONLY: mixtperf_c_dgp, &
                           mixtperf_p_drt, &
                           mixtperf_r_cpg, &
                           mixtperf_t_dpr 
         
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: errorstring,rcsidentstring
  INTEGER :: ifl,ipatch
  REAL(RFREAL) :: betah,cpgas,d,dinc,ggas,height,mach,mi,minj,p,ptot,rgas, &
                  ri,t,ttot,u,v,vinj,vmag,w,x,y
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_InitBcDataHardCode.F90,v $ $Revision: 1.7 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_InitBcDataHardCode', &
                        'RFLU_InitBcDataHardCode.F90')
 
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
          'Initializing boundary-condition data from hard code...'
                             
    IF ( global%verbLevel > verbose_low ) THEN 
      WRITE(stdout,'(A,3X,A,A)') solver_name,'Case: ',trim(global%casename)
    END IF ! global%verbLevel                         
  END IF ! global%verbLevel

! ==============================================================================
! Set pointers
! ==============================================================================

  pgrid => pregion%grid

! ==============================================================================
! Set constants
! ==============================================================================

  cpgas = global%refCp
  ggas  = global%refGamma  
  rgas  = mixtperf_r_cpg(cpgas,ggas)
  
! ******************************************************************************
! Initialize data fields based on user input
! ******************************************************************************

  SELECT CASE ( global%casename )
  
! ==============================================================================
!   Proudman-Culick flow. NOTE this problem is two-dimensional and assumed to 
!   lie in the x-y plane, and that the injection boundary is located at 
!   y = -height.
! ==============================================================================  
  
    CASE ( "onera_c0", "onera_c0_2d_100x50" )
      CALL rflu_getparamshardcodeproudman(dinc,minj,vinj,ptot)
    
      height = minval(pgrid%xyz(ycoord,1:pgrid%nVertTot))
      
      DO ipatch = 1,pgrid%nPatches
        ppatch => pregion%patches(ipatch)
        
        IF ( ppatch%bcType == bc_injection ) THEN
          IF ( ppatch%mixt%distrib == bcdat_distrib ) THEN  
            DO ifl = 1,ppatch%nBFaces
              x = ppatch%fc(xcoord,ifl)
              y = ppatch%fc(ycoord,ifl)

              CALL rflu_computeexactflowproudman(global,x,y,height,dinc, &
                                                 vinj,ptot,d,u,v,w,p)

              t = mixtperf_t_dpr(d,p,rgas)

              ppatch%mixt%vals(bcdat_inject_mfrate,ifl) = d*v
              ppatch%mixt%vals(bcdat_inject_temp  ,ifl) = t                                  
            END DO ! ifl
          ELSE 
            WRITE(errorstring,'(A,1X,I3)') 'Patch:',ipatch
            CALL errorstop(global,err_distrib_invalid,__line__, &
                           trim(errorstring))
          END IF ! pPatch%mixt%distrib
        ELSE IF ( ppatch%bcType == bc_outflow ) THEN
          IF ( ppatch%mixt%distrib == bcdat_distrib ) THEN  
            DO ifl = 1,ppatch%nBFaces
              x = ppatch%fc(xcoord,ifl)
              y = ppatch%fc(ycoord,ifl)

              CALL rflu_computeexactflowproudman(global,x,y,height,dinc, &
                                                 vinj,ptot,d,u,v,w,p)

              ppatch%mixt%vals(bcdat_outflow_press,ifl) = p
            END DO ! ifl     
          ELSE 
            WRITE(errorstring,'(A,1X,I3)') 'Patch:',ipatch
            CALL errorstop(global,err_distrib_invalid,__line__, &
                           trim(errorstring))          
          END IF ! pPatch%mixt%distrib              
        END IF ! pPatch%bcType      
      END DO ! iPatch  
  
! ==============================================================================
!   Ringleb flow. NOTE this problem is two-dimensional and assumed to lie in 
!   the x-y plane and that the exact solution is restricted to gamma = 1.4.
! ==============================================================================  
  
    CASE ( "ringleb" )
      CALL rflu_getparamshardcoderingleb(ptot,ttot)
          
      DO ipatch = 1,pgrid%nPatches
        ppatch => pregion%patches(ipatch)
        
        IF ( ppatch%bcType == bc_inflow_totang ) THEN
          IF ( ppatch%mixt%distrib == bcdat_distrib ) THEN  
            DO ifl = 1,ppatch%nBFaces
              x = ppatch%fc(xcoord,ifl)
              y = ppatch%fc(ycoord,ifl)

              CALL rflu_computeexactflowringleb(x,y,rgas,ptot,ttot,d,u,v,w,p)

              betah = atan2(v,u) ! w assumed to be zero

              ppatch%mixt%vals(bcdat_inflow_ptot ,ifl) = ptot
              ppatch%mixt%vals(bcdat_inflow_ttot ,ifl) = ttot 
              ppatch%mixt%vals(bcdat_inflow_betah,ifl) = betah
              ppatch%mixt%vals(bcdat_inflow_betav,ifl) = 0.0_rfreal            
            END DO ! ifl
          ELSE 
            WRITE(errorstring,'(A,1X,I3)') 'Patch:',ipatch
            CALL errorstop(global,err_distrib_invalid,__line__, &
                           trim(errorstring))
          END IF ! pPatch%mixt%distrib
        ELSE IF ( ppatch%bcType == bc_outflow ) THEN
          IF ( ppatch%mixt%distrib == bcdat_distrib ) THEN  
            DO ifl = 1,ppatch%nBFaces
              x = ppatch%fc(xcoord,ifl)
              y = ppatch%fc(ycoord,ifl)

              CALL rflu_computeexactflowringleb(x,y,rgas,ptot,ttot,d,u,v,w,p)

              ppatch%mixt%vals(bcdat_outflow_press,ifl) = p
            END DO ! ifl     
          ELSE 
            WRITE(errorstring,'(A,1X,I3)') 'Patch:',ipatch
            CALL errorstop(global,err_distrib_invalid,__line__, &
                           trim(errorstring))          
          END IF ! pPatch%mixt%distrib              
        END IF ! pPatch%bcType      
      END DO ! iPatch
      
! ==============================================================================
!   Supersonic vortex flow. NOTE this problem is two-dimensional and assumed 
!   to lie in the x-y plane. 
! ==============================================================================  
  
    CASE ( "ssvorth20x5l1"   ,"ssvortp20x5l1",    & 
           "ssvorth20x5l3"   ,"ssvortp20x5l3",    &
           "ssvorth40x10l1"  ,"ssvortp40x10l1",   & 
           "ssvorth40x10l3"  ,"ssvortp40x10l3",   & 
           "ssvorth80x20l1"  ,"ssvortp80x20l1",   & 
           "ssvorth80x20l3"  ,"ssvortp80x20l3",   & 
           "ssvorth160x40l1" ,"ssvortp160x40l1",  &
           "ssvorth160x40l3" ,"ssvortp160x40l3",  &
           "ssvorth320x80l1" ,"ssvortp320x80l1",  &
           "ssvorth320x80l3" ,"ssvortp320x80l3",  &
           "ssvorth640x160l1","ssvortp640x160l1", &
           "ssvorth640x160l3","ssvortp640x160l3" )
      CALL rflu_getparamshardcodessvortex(ri,mi,ptot,ttot)
           
      DO ipatch = 1,pgrid%nPatches
        ppatch => pregion%patches(ipatch)
        
        IF ( ppatch%bcType == bc_inflow_totang ) THEN
          IF ( ppatch%mixt%distrib == bcdat_distrib ) THEN 
            DO ifl = 1,ppatch%nBFaces
              x = ppatch%fc(xcoord,ifl)
              y = ppatch%fc(ycoord,ifl)

              CALL rflu_computeexactflowssvortex(x,y,ggas,rgas,ri,mi,ptot, & 
                                                 ttot,d,u,v,w,p)

              vmag  = sqrt(u*u + v*v) ! w assumed to be zero
              betah = asin(v/vmag) 
              mach  = vmag/mixtperf_c_dgp(d,ggas,p)

              ppatch%mixt%vals(bcdat_inflow_ptot ,ifl) = ptot
              ppatch%mixt%vals(bcdat_inflow_ttot ,ifl) = ttot 
              ppatch%mixt%vals(bcdat_inflow_betah,ifl) = betah
              ppatch%mixt%vals(bcdat_inflow_betav,ifl) = 0.0_rfreal
              ppatch%mixt%vals(bcdat_inflow_mach ,ifl) = mach                       
            END DO ! ifl  
          ELSE 
            WRITE(errorstring,'(A,1X,I3)') 'Patch:',ipatch
            CALL errorstop(global,err_distrib_invalid,__line__, &
                           trim(errorstring))            
          END IF ! pPatch%mixt%distrib        
        END IF ! pPatch%bcType      
      END DO ! iPatch     
        
! ==============================================================================
!   Default - must be due to input error
! ==============================================================================  
            
    CASE default 
      CALL errorstop(global,err_reached_default,__line__)  
  END SELECT ! global%casename

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name, &
          'Initializing boundary-condition data from hard code done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_initbcdatahardcode

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_InitBcDataHardCode.F90,v $
! Revision 1.7  2008/12/06 08:44:56  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:18:06  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/08/19 15:41:09  mparmar
! Renamed patch variables
!
! Revision 1.4  2006/03/08 23:39:39  haselbac
! Added 1 layer ssvort cases
!
! Revision 1.3  2005/10/09 15:40:19  haselbac
! Added 2d C0 case
!
! Revision 1.2  2005/04/27 02:14:52  haselbac
! Adapted to changes in inflow treatment
!
! Revision 1.1  2005/04/15 15:08:13  haselbac
! Initial revision
!
! Revision 1.5  2004/10/19 19:30:53  haselbac
! Removed setting of relative velocity on injection boundaries
!
! Revision 1.4  2004/07/06 15:15:53  haselbac
! Adapted to changes in libflu and modflu, cosmetics
!
! Revision 1.3  2004/02/23 23:05:10  haselbac
! Added Proudman solution for ONERA C0 case
!
! Revision 1.2  2004/02/13 03:05:54  haselbac
! Added more casenames
!
! Revision 1.1  2004/01/29 22:58:49  haselbac
! Initial revision
!
! ******************************************************************************