Rocstar-legacy/RFLU__ModExactFlow_8F90_source.html

 ! *********************************************************************

 ! * Rocstar Simulation Suite                                          *

 ! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *

 ! *                                                                   *

 ! * Illinois Rocstar LLC                                              *

 ! * Champaign, IL                                                     *

 ! * www.illinoisrocstar.com                                           *

 ! * sales@illinoisrocstar.com                                         *

 ! *                                                                   *

 ! * License: See LICENSE file in top level of distribution package or *

 ! * http://opensource.org/licenses/NCSA                               *

 ! *********************************************************************

 ! *********************************************************************

 ! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *

 ! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *

 ! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *

 ! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *

 ! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *

 ! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *

 ! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *

 ! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *

 ! *********************************************************************

 ! ******************************************************************************

 !

 ! Purpose: Suite of routines to compute exact flow solutions.

 !

 ! Description: None.

 !

 ! Notes:

 !   1. Collected routines in single module because computation of exact

 !      solutions is needed in at least three places: initialization of

 !      solution, setting of boundary profiles, and computation of errors.

 !

 ! ******************************************************************************

 !

 ! $Id: RFLU_ModExactFlow.F90,v 1.10 2008/12/06 08:44:21 mtcampbe Exp $

 !

 ! Copyright: (c) 2004-2006 by the University of Illinois

 !

 ! ******************************************************************************


 MODULE rflu_modexactflow


   USE modparameters

   USE moddatatypes

   USE modglobal, ONLY: t_global


   IMPLICIT NONE


   PRIVATE

   PUBLIC :: rflu_computeexactflowculick, &

             rflu_computeexactflowpacoust, &

             rflu_computeexactflowproudman, &

             rflu_computeexactflowringleb, &

             rflu_computeexactflowssvortex, &

             rflu_setexactflowlinear, &

             rflu_setexactflowtrig


 ! ******************************************************************************

 ! Declarations and definitions

 ! ******************************************************************************


   CHARACTER(CHRLEN) :: RCSIdentString = &

     '$RCSfile: RFLU_ModExactFlow.F90,v $ $Revision: 1.10 $'


 ! ******************************************************************************

 ! Routines

 ! ******************************************************************************


   CONTAINS


 ! ******************************************************************************

 !

 ! Purpose: Compute exact solution for Culick flow.

 !

 ! Description: None.

 !

 ! Input:

 !   global      Pointer to global data

 !   x           x-coordinate

 !   y           y-coordinate

 !   z           z-coordinate

 !

 ! Output:

 !   d           Density

 !   u           x-velocity component

 !   v           y-velocity component

 !   w           z-velocity component

 !   p           Static pressure

 !

 ! Notes:

 !   1. Assume cylindrical domain with axis along x-coordinate direction.

 !   2. Assume radius equal to 0.01.

 !   3. Assume injection velocity equal to unity.

 !   4. Total pressure is not uniform but assumed so for now.

 !

 ! ******************************************************************************


   SUBROUTINE rflu_computeexactflowculick(global,x,y,z,d,u,v,w,p)


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     REAL(RFREAL), INTENT(IN) :: x,y,z

     REAL(RFREAL), INTENT(OUT) :: d,p,u,v,w

     TYPE(t_global), POINTER :: global


 ! ==============================================================================

 !   Locals

 ! ==============================================================================


     REAL(RFREAL) :: r,ro,theta,vr


 ! ******************************************************************************

 !   Start, compute exact solution

 ! ******************************************************************************


     r     = sqrt(y*y + z*z)

     ro    = 0.01_rfreal

     theta = atan2(z,y)


     d  = 1.0_rfreal


     vr = -sin(0.5_rfreal*global%pi*(r/ro)**2)/(r/ro)

     u  = global%pi*x/ro*cos(0.5_rfreal*global%pi*(r/ro)**2)

     v  = vr*cos(theta)

     w  = vr*sin(theta)


     p = 1.0e+5 ! TEMPORARY


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_computeexactflowculick


 ! ******************************************************************************

 !

 ! Purpose: Compute exact solution for pipe acoustics.

 !

 ! Description: None.

 !

 ! Input:

 !   global      Pointer to global data

 !   x           x-coordinate

 !   y           y-coordinate

 !   z           z-coordinate

 !   t           time

 !   L           Length of pipe

 !   ro          Outer radius of pipe

 !   iBc         Type of boundary condition in axial direction (0 = zero

 !               pressure disturbance, 1 = zero pressure disturbance gradient)

 !   im          Index of mode in circumferential direction

 !   in          Index of mode in axial direction

 !   iq          Index of mode in radial direction

 !   etaqm       q-th root of m-th order Bessel function of first kind

 !   omega       Frequency

 !   dTot        Total density

 !   pTot        Total pressure

 !   aTot        Total speed of sound

 !   const       Constant (appears in theoretical solution, but is not equal

 !               to amplitude)

 !

 ! Output:

 !   d           Density

 !   u           x-velocity component

 !   v           y-velocity component

 !   w           z-velocity component

 !   p           Static pressure

 !

 ! Notes:

 !   1. Exact solution assumes that z-axis corresponds to axis of symmetry of

 !      pipe.

 !

 ! ******************************************************************************


   SUBROUTINE rflu_computeexactflowpacoust(global,x,y,z,t,L,ro,iBc,im,in,iq, &

                                           etaqm,omega,dtot,ptot,atot,const, &

                                           d,u,v,w,p)


     USE rflu_modbessel


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     INTEGER, INTENT(IN) :: ibc,im,in,iq

     REAL(RFREAL), INTENT(IN) :: atot,const,dtot,etaqm,l,omega,ptot,ro,t,x,y,z

     REAL(RFREAL), INTENT(OUT) :: d,p,u,v,w

     TYPE(t_global), POINTER :: global


 ! ==============================================================================

 !   Locals

 ! ==============================================================================


     REAL(RFREAL) :: cimt,cinz,cot,dummyreal,jm,jmd,r,simt,sinz,sot,term, &

                     theta,ur,ut,uz


 ! ******************************************************************************

 !   Start, compute exact solution

 ! ******************************************************************************


     r = sqrt(x*x + y*y)

     theta = atan2(y,x)


     CALL rflu_jyndd(im,etaqm*r/ro,jm,jmd,dummyreal,dummyreal,dummyreal, &

                     dummyreal)


     cimt = cos(im*theta)

     simt = sin(im*theta)


     cinz = cos(in*global%pi*z/l)

     sinz = sin(in*global%pi*z/l)


     cot  = cos(omega*t)

     sot  = sin(omega*t)


     term = const/(dtot*omega)


     IF ( ibc == 0 ) THEN

       p = const*jm*cimt*sinz*cot

     ELSE IF ( ibc == 1 ) THEN

       p = const*jm*cimt*cinz*cot

     ELSE

       p = 0.0_rfreal

     END IF ! iBc


     d = dtot + p/atot*atot

     p = ptot + p


     IF ( ibc == 0 ) THEN

       ur = -   term  *jmd*(etaqm/ro)*cimt*sinz                 *sot

       ut =  im*term/r*jm            *simt*sinz                 *sot

       uz = -   term  *jm            *cimt*cinz*(in*global%pi/l)*sot

     ELSE IF ( ibc == 1 ) THEN

       ur = -   term  *jmd*(etaqm/ro)*cimt*cinz                 *sot

       ut =  im*term/r*jm            *simt*cinz                 *sot

       uz =     term  *jm            *cimt*sinz*(in*global%pi/l)*sot

     ELSE

       ur = 0.0_rfreal

       ut = 0.0_rfreal

       uz = 0.0_rfreal

     END IF ! iBc


     u = ur*cos(theta) - ut*sin(theta)

     v = ur*sin(theta) + ut*cos(theta)

     w = uz


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_computeexactflowpacoust


 ! ******************************************************************************

 !

 ! Purpose: Compute exact solution for Proudman-Culick flow.

 !

 ! Description: None.

 !

 ! Input:

 !   global      Pointer to global data

 !   x           x-coordinate

 !   y           y-coordinate

 !   height      Height of domain

 !   dInc        Density

 !   vInj        Injection velocity

 !   pTot        Total pressure at (x,y) = (0,0)

 !

 ! Output:

 !   d           Density

 !   u           x-velocity component

 !   v           y-velocity component

 !   w           z-velocity component

 !   p           Static pressure

 !

 ! Notes:

 !   1. Total pressure is not uniform!

 !

 ! ******************************************************************************


   SUBROUTINE rflu_computeexactflowproudman(global,x,y,height,dInc,vInj,pTot, &

                                            d,u,v,w,p)


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     REAL(RFREAL), INTENT(IN) :: dinc,height,ptot,vinj,x,y

     REAL(RFREAL), INTENT(OUT) :: d,p,u,v,w

     TYPE(t_global), POINTER :: global


 ! ******************************************************************************

 !   Start, compute exact solution

 ! ******************************************************************************


     u = -0.5_rfreal*global%pi*x/height*vinj*cos(0.5_rfreal*global%pi*y/height)

     v =                                vinj*sin(0.5_rfreal*global%pi*y/height)


     w = 0.0_rfreal


     d = dinc

     p = ptot - 0.25_rfreal*vinj**2*(1.0_rfreal &

                                   + 0.5_rfreal*(global%pi*x/height)**2 &

                                   -         cos(global%pi*y/height))


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_computeexactflowproudman


 ! ******************************************************************************

 !

 ! Purpose: Compute exact solution for Ringleb flow.

 !

 ! Description: The solution to the Ringleb flow is given in terms of qBar

 !   (normalized velocity magnitude) and the k (streamline constant). It is

 !   not possible to determine these as an explicit function of x and y.

 !   Instead, given x and y, qBar and k are determined iteratively. Once

 !   qBar and k are known, the solution can be computed in terms of the

 !   primitive variables.

 !

 ! Input:

 !   x           x-coordinate

 !   y           y-coordinate

 !   rGas        Gas constant

 !   pTot        Total pressure

 !   tTot        Total temperature

 !

 ! Output:

 !   d           Density

 !   u           x-velocity component

 !   v           y-velocity component

 !   w           z-velocity component

 !   p           Static pressure

 !

 ! Notes:

 !   1. This routine assumes a perfect gas and that the ratio of specific heats

 !      is equal to 1.4.

 !   2. Depending on how the geometry is defined (which values of qBar and k

 !      were chosen), it may become necessary to alter the initial guess for

 !      qBar.

 !

 ! ******************************************************************************


   SUBROUTINE rflu_computeexactflowringleb(x,y,rGas,pTot,tTot,d,u,v,w,p)


     USE modinterfaces, ONLY: mixtperf_c_grt,mixtperf_d_prt


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     REAL(RFREAL), INTENT(IN) :: ptot,rgas,ttot,x,y

     REAL(RFREAL), INTENT(OUT) :: d,p,u,v,w


 ! ==============================================================================

 ! Locals

 ! ==============================================================================


     CHARACTER(CHRLEN) :: rcsidentstring

     INTEGER :: cntr,cntrmax

     REAL(RFREAL) :: a,abar,atot,alpha,dabardqbar,dfdqbar,djdabar,djdqbar, &

                     dqbar,drhobardqbar,f,j,k,qbar,qbarmax,rhobar,t,tol


 ! ******************************************************************************

 !   Start, compute exact solution

 ! ******************************************************************************


 ! ==============================================================================

 !   Determine solution in terms of qBar and k with Newton-Raphson method

 ! ==============================================================================


     cntr    = 0

     cntrmax = 100 ! Maximum number of Newton-Raphson steps


     qbar    = 0.3_rfreal       ! Initial guess for qBar

     qbarmax = sqrt(5.0_rfreal) ! Physically possible maximum value for qBar


     tol = 1.0e-16_rfreal ! Convergence tolerance


 ! -------------------------------------------------------------------------------

 !   Loop over iterations

 ! -------------------------------------------------------------------------------


     DO

       cntr = cntr + 1


       abar   = sqrt(1.0_rfreal - 0.2_rfreal*qbar**2)

       rhobar = abar**5.0_rfreal


       j      = 1.0_rfreal/abar                 &

              + 1.0_rfreal/(3.0_rfreal*abar**3) &

              + 1.0_rfreal/(5.0_rfreal*abar**5) &

              - 0.5_rfreal*log((1.0_rfreal+abar)/(1.0_rfreal-abar))


 ! --- Compute function value ---------------------------------------------------


       f = (x - 0.5_rfreal*j)**2 + y**2 - 1.0_rfreal/(4.0_rfreal*rhobar**2*qbar**4)


 ! --- Compute derivative -------------------------------------------------------


       drhobardqbar = -qbar*abar**3

       djdabar = -1.0_rfreal/abar**2 &

                 -1.0_rfreal/abar**4 &

                 -1.0_rfreal/abar**6 &

                 -1.0_rfreal/((1.0_rfreal+abar)*(1.0_rfreal-abar))

       dabardqbar = -0.2_rfreal*qbar/abar

       djdqbar = djdabar*dabardqbar

       dfdqbar = -(x - 0.5_rfreal*j)*djdqbar &

               + 0.5_rfreal/(rhobar**3*qbar**4)*drhobardqbar &

               + 1.0_rfreal/(rhobar**2*qbar**5)


 ! --- Update -------------------------------------------------------------------


       dqbar = -f/dfdqbar


       qbar = qbar + dqbar


 ! --- Limit to physically possible maximum -------------------------------------


       qbar = min(qbar,qbarmax)


 ! --- Convergence check and update k -------------------------------------------


       IF ( (abs(dqbar) < tol ) .OR. (cntr == cntrmax) ) THEN

         k = sqrt(2.0_rfreal/(1.0_rfreal/qbar**2 &

                            - 2.0_rfreal*rhobar*(x - 0.5_rfreal*j)))


         EXIT

       END IF ! ABS(dqBar)

     END DO ! <empty>


 ! ==============================================================================

 !   Determine solution in terms of primitive variables

 ! ==============================================================================


     p    = ptot*rhobar**1.4_rfreal

     t    = ttot*rhobar**0.4_rfreal

     d    = mixtperf_d_prt(p,rgas,t)

     atot = mixtperf_c_grt(1.4_rfreal,rgas,ttot)

     a    = atot*abar


     alpha = asin(min(1.0_rfreal,qbar/k))

     u     = atot*qbar*cos(alpha)*sign(1.0_rfreal,y)

     v     = atot*qbar*sin(alpha)

     w     = 0.0_rfreal


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_computeexactflowringleb


 ! ******************************************************************************

 !

 ! Purpose: Compute exact solution for supersonic vortex.

 !

 ! Description: None.

 !

 ! Input:

 !   x           x-coordinate

 !   y           y-coordinate

 !   gGas        ratio of specific heats

 !   rGas        Gas constant

 !   ri          Inner radius

 !   Mi          Mach number at inner radius

 !   pTot        Total pressure

 !   tTot        Total temperature

 !

 ! Output:

 !   d           Density

 !   u           x-velocity component

 !   v           y-velocity component

 !   w           z-velocity component

 !   p           Static pressure

 !

 ! Notes:

 !   1. This routine assumes a perfect gas.

 !

 ! ******************************************************************************


   SUBROUTINE rflu_computeexactflowssvortex(x,y,gGas,rGas,ri,Mi,pTot,tTot, &

                                            d,u,v,w,p)


     USE modinterfaces, ONLY: mixtperf_c_grt, &

                              mixtperf_d_dogma, &

                              mixtperf_d_prt, &

                              mixtperf_p_gmapo, &

                              mixtperf_p_ddogpo, &

                              mixtperf_t_dpr


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     REAL(RFREAL), INTENT(IN) :: ggas,mi,ptot,rgas,ri,ttot,x,y

     REAL(RFREAL), INTENT(OUT) :: d,p,u,v,w


 ! ==============================================================================

 !   Locals

 ! ==============================================================================


     REAL(RFREAL) :: ai,alpha,di,dtot,pi,r,term,ti,vi


 ! ******************************************************************************

 !   Start, compute exact solution

 ! ******************************************************************************


     dtot = mixtperf_d_prt(ptot,rgas,ttot)


     di = mixtperf_d_dogma(dtot,ggas,mi)

     pi = mixtperf_p_gmapo(ggas,mi,ptot)

     ti = mixtperf_t_dpr(di,pi,rgas)

     ai = mixtperf_c_grt(ggas,rgas,ti)

     vi = mi*ai


     r     = sqrt(x*x + y*y)

     alpha = atan(y/x)


     term = 1.0_rfreal - (ri/r)**2

     term = 1.0_rfreal + 0.5_rfreal*(ggas - 1.0_rfreal)*mi*mi*term

     d    = di*term**(1.0_rfreal/(ggas - 1.0_rfreal))

     p    = mixtperf_p_ddogpo(d,dtot,ggas,ptot)


     u =  vi*ri/r*sin(alpha)

     v = -vi*ri/r*cos(alpha)

     w =  0.0_rfreal


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_computeexactflowssvortex


 ! ******************************************************************************

 !

 ! Purpose: Set linear variable behavior.

 !

 ! Description: None.

 !

 ! Input:

 !   x           x-coordinate

 !   y           y-coordinate

 !   z           z-coordinate

 !   iVar        Variable index

 !

 ! Output:

 !   var         Variable

 !   gx          x-component of gradient

 !   gy          y-component of gradient

 !   gz          z-component of gradient

 !

 ! Notes: None.

 !

 ! ******************************************************************************


   SUBROUTINE rflu_setexactflowlinear(x,y,z,iVar,var,gx,gy,gz)


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     INTEGER, INTENT(IN) :: ivar

     REAL(RFREAL), INTENT(IN) :: x,y,z

     REAL(RFREAL), INTENT(OUT) :: gx,gy,gz,var


 ! ==============================================================================

 !   Locals

 ! ==============================================================================


     REAL(RFREAL) :: a,b,c


 ! ******************************************************************************

 !   Start, set exact solution

 ! ******************************************************************************


     a = 1 + (ivar-1)*(zcoord-xcoord)

     b = a + 1

     c = a + 2


     var = a*x + b*y + c*z


     gx = a

     gy = b

     gz = c


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_setexactflowlinear


 ! ******************************************************************************

 !

 ! Purpose: Set trigonometric variable behavior.

 !

 ! Description: None.

 !

 ! Input:

 !   global      Pointer to globa data

 !   nx          Wave number for x-direction

 !   ny          Wave number for y-direction

 !   nz          Wave number for z-direction

 !   x           x-coordinate

 !   y           y-coordinate

 !   z           z-coordinate

 !   iVar        Variable index

 !

 ! Output:

 !   var         Variable

 !   gx          x-component of gradient

 !   gy          y-component of gradient

 !   gz          z-component of gradient

 !

 ! Notes:

 !   1. At present, do not make use of iVar.

 !

 ! ******************************************************************************


   SUBROUTINE rflu_setexactflowtrig(global,nx,ny,nz,x,y,z,iVar,var,gx,gy,gz)


     IMPLICIT NONE


 ! ******************************************************************************

 !   Declarations and definitions

 ! ******************************************************************************


 ! ==============================================================================

 !   Arguments

 ! ==============================================================================


     INTEGER, INTENT(IN) :: ivar

     REAL(RFREAL), INTENT(IN) :: nx,ny,nz,x,y,z

     REAL(RFREAL), INTENT(OUT) :: gx,gy,gz,var

     TYPE(t_global), POINTER :: global


 ! ==============================================================================

 !   Locals

 ! ==============================================================================


     REAL(RFREAL) :: a,b,c


 ! ******************************************************************************

 !   Start, set exact solution

 ! ******************************************************************************


     a = nx*global%pi

     b = ny*global%pi

     c = nz*global%pi


     var = cos(a*x)*sin(b*y)*cos(c*z)


     gx = -a*sin(a*x)*sin(b*y)*cos(c*z)

     gy =  b*cos(a*x)*cos(b*y)*cos(c*z)

     gz = -c*cos(a*x)*sin(b*y)*sin(c*z)


 ! ******************************************************************************

 !   End

 ! ******************************************************************************


   END SUBROUTINE rflu_setexactflowtrig


 ! ******************************************************************************

 ! End

 ! ******************************************************************************


 END MODULE rflu_modexactflow


 ! ******************************************************************************

 !

 ! RCS Revision history:

 !

 ! $Log: RFLU_ModExactFlow.F90,v $

 ! Revision 1.10  2008/12/06 08:44:21  mtcampbe

 ! Updated license.

 !

 ! Revision 1.9  2008/11/19 22:17:32  mtcampbe

 ! Added Illinois Open Source License/Copyright

 !

 ! Revision 1.8  2006/04/13 18:07:34  haselbac

 ! Added routine for Culick flow

 !

 ! Revision 1.7  2006/04/07 15:19:19  haselbac

 ! Removed tabs

 !

 ! Revision 1.6  2006/01/06 22:10:26  haselbac

 ! Added routines for linear and trig solution for grad testing

 !

 ! Revision 1.5  2005/04/29 12:54:36  haselbac

 ! Adapted routine for exact pipe acoust solution to accept time argument

 !

 ! Revision 1.4  2005/04/20 14:41:53  haselbac

 ! Bug fix and extensions for pipe acoustics case

 !

 ! Revision 1.3  2005/03/31 17:02:44  haselbac

 ! Fixed bug in initialization of pressure for ONERA C0 case

 !

 ! Revision 1.2  2005/03/15 20:44:44  haselbac

 ! Added routine to compute exact solution for pipe acoustics

 !

 ! Revision 1.1  2004/07/06 15:14:27  haselbac

 ! Initial revision

 !

 ! ******************************************************************************


rflu_modexactflow::rflu_computeexactflowculick
subroutine, public rflu_computeexactflowculick(global, x, y, z, d, u, v, w, p)
Definition: RFLU_ModExactFlow.F90:103

Color::r
unsigned char r() const
Definition: Color.h:68

modglobal
Definition: ModGlobal.F90:39

rflu_modbessel::rflu_jyndd
subroutine, public rflu_jyndd(N, X, BJN, DJN, FJN, BYN, DYN, FYN)
Definition: RFLU_ModBessel.F90:94

modparameters
Definition: ModParameters.F90:42

sign
static SURF_BEGIN_NAMESPACE double sign(double x)
Definition: compute_curvature.C:31

d
const NT & d
Definition: rational_rotation.h:73

k
j indices k indices k
Definition: Indexing.h:6

y
void int int REAL REAL * y
Definition: read.cpp:74

rflu_modexactflow::rflu_computeexactflowpacoust
subroutine, public rflu_computeexactflowpacoust(global, x, y, z, t, L, ro, iBc, im, in, iq, etaqm, omega, dTot, pTot, aTot, const, d, u, v, w, p)
Definition: RFLU_ModExactFlow.F90:193

Kdtree_d::ExtPoint::term
void term()
Definition: kdtree_d.h:237

Color::b
unsigned char b() const
Definition: Color.h:70

mixtperf_p_ddogpo
real(rfreal) function mixtperf_p_ddogpo(D, Do, G, Po)
Definition: MixtPerf_P.F90:85

mixtperf_d_prt
real(rfreal) function mixtperf_d_prt(P, R, T)
Definition: MixtPerf_D.F90:71

sqrt
double sqrt(double d)
Definition: double.h:73

rflu_modexactflow
Definition: RFLU_ModExactFlow.F90:42

rflu_modbessel
Definition: RFLU_ModBessel.F90:42

Line_2::c
RT c() const
Definition: Line_2.h:150

v
*********************************************************************Illinois Open Source License ****University of Illinois NCSA **Open Source License University of Illinois All rights reserved ****Developed free of to any person **obtaining a copy of this software and associated documentation to deal with the Software without including without limitation the rights to and or **sell copies of the and to permit persons to whom the **Software is furnished to do subject to the following this list of conditions and the following disclaimers ****Redistributions in binary form must reproduce the above **copyright this list of conditions and the following **disclaimers in the documentation and or other materials **provided with the distribution ****Neither the names of the Center for Simulation of Advanced the University of nor the names of its **contributors may be used to endorse or promote products derived **from this Software without specific prior written permission ****THE SOFTWARE IS PROVIDED AS WITHOUT WARRANTY OF ANY **EXPRESS OR INCLUDING BUT NOT LIMITED TO THE WARRANTIES **OF FITNESS FOR A PARTICULAR PURPOSE AND **NONINFRINGEMENT IN NO EVENT SHALL THE CONTRIBUTORS OR **COPYRIGHT HOLDERS BE LIABLE FOR ANY DAMAGES OR OTHER WHETHER IN AN ACTION OF TORT OR **ARISING OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE **USE OR OTHER DEALINGS WITH THE SOFTWARE v
Definition: roccomf90.h:20

pi
static const double pi
Definition: smooth_medial.C:43

z
void int int int REAL REAL REAL * z
Definition: write.cpp:76

sin
NT & sin
Definition: rational_rotation.h:78

x
void int int REAL * x
Definition: read.cpp:74

mixtperf_t_dpr
real(rfreal) function mixtperf_t_dpr(D, P, R)
Definition: MixtPerf_T.F90:85

mixtperf_d_dogma
real(rfreal) function mixtperf_d_dogma(Do, G, Ma)
Definition: MixtPerf_D.F90:55

rflu_modexactflow::rflu_computeexactflowringleb
subroutine, public rflu_computeexactflowringleb(x, y, rGas, pTot, tTot, d, u, v, w, p)
Definition: RFLU_ModExactFlow.F90:385

rflu_modexactflow::rflu_computeexactflowssvortex
subroutine, public rflu_computeexactflowssvortex(x, y, gGas, rGas, ri, Mi, pTot, tTot, d, u, v, w, p)
Definition: RFLU_ModExactFlow.F90:535

modinterfaces
Definition: ModInterfaces.F90:39

min
Vector_n min(const Array_n_const &v1, const Array_n_const &v2)
Definition: Vector_n.h:346

mixtperf_c_grt
real(rfreal) function mixtperf_c_grt(G, R, T)
Definition: MixtPerf_C.F90:86

j
j indices j
Definition: Indexing.h:6

rflu_modexactflow::rflu_setexactflowtrig
subroutine, public rflu_setexactflowtrig(global, nx, ny, nz, x, y, z, iVar, var, gx, gy, gz)
Definition: RFLU_ModExactFlow.F90:698

modglobal::t_global
Definition: ModGlobal.F90:50

Color::alpha
unsigned char alpha() const
Definition: Color.h:75

rflu_modexactflow::rflu_setexactflowlinear
subroutine, public rflu_setexactflowlinear(x, y, z, iVar, var, gx, gy, gz)
Definition: RFLU_ModExactFlow.F90:622

cos
NT & cos
Definition: rational_rotation.h:79

moddatatypes
Definition: ModDataTypes.F90:40

cimg_library::CImg::atan2
CImg< T > & atan2(const CImg< t > &img)
Compute the arc-tangent of each pixel.
Definition: CImg.h:12671

Line_2::a
RT a() const
Definition: Line_2.h:140

mixtperf_p_gmapo
real(rfreal) function mixtperf_p_gmapo(G, Ma, Po)
Definition: MixtPerf_P.F90:69

rflu_modexactflow::rflu_computeexactflowproudman
subroutine, public rflu_computeexactflowproudman(global, x, y, height, dInc, vInj, pTot, d, u, v, w, p)
Definition: RFLU_ModExactFlow.F90:309