RFLO_WriteStat.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write time averaged solution to file for mixture
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary
!
! Input: regions              = dimensions and cons. variables of all regions
!        global%currentTime   = physical time
!        global%integrTime    = integrated time during time averaging process
!        mixtNStat, mixtStatId= number of mixture statistics variables and IDs 
!        mixttav              = time averaged mixture variables
!        turbNStat, turbStatId= number of TURB statistics variables and IDs 
!        turbtav              = time averaged TURB variables
!
! Output: to file
!
! Notes: solution is stored only for the current grid level; it is also
!        stored for all dummy cells; all regions are written into one file
!
!******************************************************************************
!
! $Id: RFLO_WriteStat.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_writestat( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_writedatafileint, rflo_writedatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, l, n

! ... local variables
  CHARACTER(2*CHRLEN+17) :: fname

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, ndim, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: maxnstat, allnstat, errorflag
  INTEGER :: mixtstatid(regions(1)%global%mixtnstat)
  INTEGER :: turbstatid(regions(1)%global%turbnstat)
  INTEGER, ALLOCATABLE :: ivar(:,:), jvar(:,:)

  REAL(RFREAL), POINTER     :: mixttav(:,:), turbtav(:,:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), tavfile(:,:)
  LOGICAL                   :: zeroturb

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_WriteStat',&
  'RFLO_WriteStat.F90' )

! allocate temporary data arrays ---------------------------------------------

  ALLOCATE( ivar(5,1),stat=errorflag )
  ALLOCATE( rvar(2,1),stat=errorflag )
  maxnstat = max( global%mixtNStat,global%turbNStat )
  ALLOCATE( jvar(maxnstat+1,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open statistics file (only master proc.) -----------------------------------

  IF (global%myProcid == masterproc) THEN

    IF (global%solutFormat == format_ascii) THEN
      WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.stata_', &
                                 global%currentTime
      OPEN(if_stat,file=fname,form='formatted',status='unknown', &
           iostat=errorflag)
    ELSE IF (global%solutFormat == format_binary) THEN
      WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.statb_', &
                                 global%currentTime
      OPEN(if_stat,file=fname,form='unformatted',status='unknown', &
           iostat=errorflag)
    ELSE
      CALL errorstop( global,err_unknown_format,__line__ )
    ENDIF
    rvar(1,1) = global%currentTime
    rvar(2,1) = global%integrTime

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

! write current and integrated time to file ----------------------------------

    CALL rflo_writedatafilereal( global,if_stat,global%solutFormat,2,1,rvar )

! mixture statistics NSTATS and ID

    IF (global%mixtNStat > 0) THEN
      jvar(1,1)    = global%mixtNStat
      mixtstatid(:)= global%mixtStatId(1,:)*10 + global%mixtStatId(2,:)
      jvar(2:global%mixtNStat+1,1) = mixtstatid(1:global%mixtNStat)
      CALL rflo_writedatafileint( global,if_stat,global%solutFormat, &
                                  global%mixtNStat+1,1,jvar )
    ENDIF

! turbulence statistics NSTATS and ID

#ifdef TURB
    IF (global%turbNStat > 0) THEN
      jvar(1,1)    = global%turbNStat
      turbstatid(:)= global%turbStatId(1,:)*10 + global%turbStatId(2,:)
      jvar(2:global%turbNStat+1,1) = turbstatid(1:global%turbNStat)
      CALL rflo_writedatafileint( global,if_stat,global%solutFormat, &
                                  global%turbNStat+1,1,jvar )
    ENDIF
#endif
  ENDIF

! write statistics data ------------------------------------------------------

  allnstat = global%mixtNStat+global%turbNStat

  DO ireg=1,global%nRegions

! - get dimensions and pointers

    ilev = regions(ireg)%currLevel
    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
    ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
    ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
    ndim   = ijkend - ijkbeg + 1

! - allocate memory for data field

    IF (regions(ireg)%procid==global%myProcid .OR. &
        global%myProcid==masterproc) THEN
      ALLOCATE( tavfile(allnstat,ndim),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
    ENDIF

! - copy statistics into data structure

    zeroturb = .false.

    IF (regions(ireg)%procid == global%myProcid) THEN
      IF (global%mixtNStat > 0) mixttav => regions(ireg)%levels(ilev)%mixt%tav
#ifdef TURB
      IF (global%turbNStat > 0) THEN
        IF ((regions(ireg)%mixtInput%flowModel == flow_navst) .AND. &
            (regions(ireg)%mixtInput%turbModel /= turb_model_none)) THEN
          turbtav => regions(ireg)%levels(ilev)%turb%tav
        ELSE
          ALLOCATE( turbtav(global%turbNStat,ndim) )
          turbtav = 0._rfreal
          zeroturb = .true.
        ENDIF
      ENDIF
#endif
      n = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            DO l=1,global%mixtNStat
              tavfile(l,n) = mixttav(l,ijk)
            ENDDO
#ifdef TURB
            DO l=1,global%turbNStat
              tavfile(global%mixtNStat+l,n) = turbtav(l,ijk)
            ENDDO
#endif
          ENDDO
        ENDDO
      ENDDO
    ENDIF

    IF (zeroturb) DEALLOCATE( turbtav )

! - write region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      ivar(1,1) = ireg
      ivar(2,1) = regions(ireg)%levels(ilev)%grid%ipc
      ivar(3,1) = regions(ireg)%levels(ilev)%grid%jpc
      ivar(4,1) = regions(ireg)%levels(ilev)%grid%kpc
      ivar(5,1) = regions(ireg)%nDumCells
      CALL rflo_writedatafileint( global,if_stat,global%solutFormat,5,1,ivar )
    ENDIF

! - master receives and writes data, others send them

    IF (global%myProcid == masterproc) THEN
#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_recv( tavfile,allnstat*ndim,mpi_rfreal, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
      CALL rflo_writedatafilereal( global,if_stat,global%solutFormat, &
                                   allnstat,ndim,tavfile )

    ELSE   ! not the master
#ifdef MPI
      IF (regions(ireg)%procid == global%myProcid) THEN
        CALL mpi_send( tavfile,allnstat*ndim,mpi_rfreal,masterproc, &
                       ireg,global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
    ENDIF  ! global%myProcid

    IF (ALLOCATED(tavfile)) THEN
      DEALLOCATE( tavfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize -----------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_stat,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

END SUBROUTINE rflo_writestat

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_WriteStat.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.13  2003/11/20 16:40:35  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.10  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.9  2002/12/12 03:39:37  wasistho
! facilitate the possibility of NO TURB statistics
!
! Revision 1.8  2002/11/04 18:42:08  wasistho
! Modified statistics restart
!
! Revision 1.7  2002/11/02 01:47:48  wasistho
! Added TURB statistics
!
! Revision 1.6  2002/10/23 18:43:24  jblazek
! Changed temporary pointer arrays into allocatable arrays
! in grid and solution I/O routines.
!
! Revision 1.5  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.4  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.3  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.2  2002/07/22 15:44:24  wasistho
! Cleaned-up conforming Coding Rule
!
! Revision 1.1  2002/06/14 20:53:05  wasistho
! add time avg statistics
!
!******************************************************************************