RFLO_WriteSolution.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write flow solution to file (only mixture for now).
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions            = dimensions and cons. variables of all regions
!        global%currentTime = physical time
!        global%resInit     = initial residual.
!
! Output: to file.
!
! Notes: solution is stored only for the current grid level; it is also
!        stored for all dummy cells. All regions are written into one file.
!
!******************************************************************************
!
! $Id: RFLO_WriteSolution.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_writesolution( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_writedatafileint, rflo_writedatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset, &
                            rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, n

! ... local variables
  CHARACTER(2*CHRLEN+17) :: fname

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend, inoff, ijnoff
  INTEGER :: ndimc, ndimn, nrvar, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  REAL(RFREAL), POINTER     :: cv(:,:), sivel(:), sjvel(:), skvel(:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), cvfile(:,:), svelfile(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_WriteSolution',&
  'RFLO_WriteSolution.F90' )

! allocate fixed-size temporary data arrays -----------------------------------

#ifdef PERI
  nrvar = 3
#else
  nrvar = 2
#endif
  ALLOCATE( ivar(5,1),stat=errorflag )
  ALLOCATE( rvar(nrvar,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open solution file (only master proc.) --------------------------------------

  IF (global%myProcid == masterproc) THEN

! - unsteady flow

    IF (global%flowType == flow_unsteady) THEN
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.sola_', &
                                   global%currentTime
        OPEN(if_solut,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.solb_', &
                                   global%currentTime
        OPEN(if_solut,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = global%currentTime
      rvar(2,1) = 1._rfreal

! - steady flow

    ELSE
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,I6.6)') trim(global%outDir)//trim(global%casename)//'.sola_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,I6.6)') trim(global%outDir)//trim(global%casename)//'.solb_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = 0._rfreal
      rvar(2,1) = global%resInit
    ENDIF

#ifdef PERI
    rvar(3,1) = global%moduleVar(1)
#endif

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  ENDIF   ! MASTERPROC

! write time and initial residual to file -------------------------------------

  IF (global%myProcid == masterproc) THEN
    CALL rflo_writedatafilereal( global,if_solut,global%solutFormat,nrvar,1,rvar )
  ENDIF

! write solution data ---------------------------------------------------------

  DO ireg=1,global%nRegions

! - get dimensions and pointers

    ilev = regions(ireg)%currLevel
    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
    ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
    ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
    ndimc  = ijkend - ijkbeg + 1

    CALL rflo_getdimensphysnodes( regions(ireg),ilev,ipnbeg,ipnend, &
                                  jpnbeg,jpnend,kpnbeg,kpnend )
    CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
    ndimn = (regions(ireg)%levels(ilev)%grid%ipc+1)* &
            (regions(ireg)%levels(ilev)%grid%jpc+1)* &
            (regions(ireg)%levels(ilev)%grid%kpc+1)

! - allocate memory for data field

    IF (regions(ireg)%procid==global%myProcid .OR. &
        global%myProcid==masterproc) THEN
      ALLOCATE( cvfile(cv_mixt_neqs,ndimc),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      IF (regions(ireg)%mixtInput%moveGrid) THEN
        ALLOCATE( svelfile(3,ndimn),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
      ENDIF
    ENDIF

! - copy solution into data structure

    IF (regions(ireg)%procid == global%myProcid) THEN
      cv => regions(ireg)%levels(ilev)%mixt%cv
      n = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            cvfile(1,n) = cv(cv_mixt_dens,ijk)
            cvfile(2,n) = cv(cv_mixt_xmom,ijk)
            cvfile(3,n) = cv(cv_mixt_ymom,ijk)
            cvfile(4,n) = cv(cv_mixt_zmom,ijk)
            cvfile(5,n) = cv(cv_mixt_ener,ijk)
          ENDDO
        ENDDO
      ENDDO
      IF (regions(ireg)%mixtInput%moveGrid) THEN
        sivel => regions(ireg)%levels(ilev)%grid%siVel
        sjvel => regions(ireg)%levels(ilev)%grid%sjVel
        skvel => regions(ireg)%levels(ilev)%grid%skVel
        n = 0
        DO k=kpnbeg,kpnend
          DO j=jpnbeg,jpnend
            DO i=ipnbeg,ipnend
              n   = n + 1
              ijk = indijk(i,j,k,inoff,ijnoff)
              svelfile(1,n) = sivel(ijk)
              svelfile(2,n) = sjvel(ijk)
              svelfile(3,n) = skvel(ijk)
            ENDDO
          ENDDO
        ENDDO
      ENDIF
    ENDIF      ! global%myProcid

! - write region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      ivar(1,1) = ireg
      ivar(2,1) = regions(ireg)%levels(ilev)%grid%ipc
      ivar(3,1) = regions(ireg)%levels(ilev)%grid%jpc
      ivar(4,1) = regions(ireg)%levels(ilev)%grid%kpc
      ivar(5,1) = regions(ireg)%nDumCells
      CALL rflo_writedatafileint( global,if_solut,global%solutFormat,5,1,ivar )
    ENDIF

! - master receives and writes data, others send them

    IF (global%myProcid == masterproc) THEN
#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_recv( cvfile,cv_mixt_neqs*ndimc,mpi_rfreal, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )

        IF (regions(ireg)%mixtInput%moveGrid) THEN
          CALL mpi_recv( svelfile,3*ndimn,mpi_rfreal, &
                         regions(ireg)%procid,ireg, &
                         global%mpiComm,status,global%mpierr )
          IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
        ENDIF
      ENDIF
#endif
      CALL rflo_writedatafilereal( global,if_solut,global%solutFormat, &
                                   cv_mixt_neqs,ndimc,cvfile )

      IF (regions(ireg)%mixtInput%moveGrid) THEN
        CALL rflo_writedatafilereal( global,if_solut,global%solutFormat, &
                                     3,ndimn,svelfile )
      ENDIF

    ELSE   ! not the master
#ifdef MPI
      IF (regions(ireg)%procid == global%myProcid) THEN
        CALL mpi_send( cvfile,cv_mixt_neqs*ndimc,mpi_rfreal,masterproc,ireg, &
                       global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )

        IF (regions(ireg)%mixtInput%moveGrid) THEN
          CALL mpi_send( svelfile,3*ndimn,mpi_rfreal,masterproc,ireg, &
                         global%mpiComm,global%mpierr )
          IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
        ENDIF
      ENDIF
#endif
    ENDIF

    IF (ALLOCATED(cvfile)) THEN
      DEALLOCATE( cvfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF
    IF (ALLOCATED(svelfile)) THEN
      DEALLOCATE( svelfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_solut,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

END SUBROUTINE rflo_writesolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_WriteSolution.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.16  2003/11/20 16:40:35  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.13  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.12  2003/04/02 00:24:24  wasistho
! install ROCPERI
!
! Revision 1.11  2002/10/23 18:43:24  jblazek
! Changed temporary pointer arrays into allocatable arrays
! in grid and solution I/O routines.
!
! Revision 1.10  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.9  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.8  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.7  2002/08/29 21:52:21  jblazek
! Added I/O of grid speeds.
!
! Revision 1.6  2002/06/07 16:40:36  jblazek
! Grid & solution for all regions in one file.
!
! Revision 1.5  2002/02/21 23:25:05  jblazek
! Blocks renamed as regions.
!
! Revision 1.4  2002/02/04 15:30:25  jblazek
! Added injection boundary condition.
!
! Revision 1.3  2002/01/08 22:09:16  jblazek
! Added calculation of face vectors and volumes.
!
! Revision 1.2  2002/01/02 16:20:19  jblazek
! Added flow initialization and dummy cell geometry.
!
! Revision 1.1  2001/12/22 00:09:37  jblazek
! Added routines to store grid and solution.
!
!******************************************************************************