RFLO_WriteGrid.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write x-,y-,z-coordinates of grid nodes to file.
!
! Description: the following grid formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary
!              - HDF.
!
! Input: regions            = dimensions and coordinates of all regions
!        global%currentTime = physical time.
!
! Output: to file.
!
! Notes: additionaly, the physical time is stored at the beginning of the file
!        (set to zero in the case of steady flow and/or fixed grid). Only the
!        finest grid gets stored. All regions are written into one file.
!
!******************************************************************************
!
! $Id: RFLO_WriteGrid.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_writegrid( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_writedatafileint, rflo_writedatafilereal, &
                            rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, n

! ... local variables
  CHARACTER(2*CHRLEN+17) :: fname

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: iregfile, ipc, jpc, kpc, ndim
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend
  INTEGER :: inoff, ijnoff, ijkn, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  LOGICAL :: movegrid

  REAL(RFREAL), POINTER     :: xyz(:,:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), xyzfile(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_WriteGrid',&
  'RFLO_WriteGrid.F90' )

! allocate fixed-size temporary data arrays -----------------------------------

  ALLOCATE( ivar(4,1),stat=errorflag )
  ALLOCATE( rvar(1,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open grid file (only master proc.) ------------------------------------------

  IF (global%myProcid == masterproc) THEN

    movegrid = .false.
    DO ireg=1,global%nRegions
      IF (regions(ireg)%mixtInput%moveGrid) movegrid = .true.
    ENDDO

! - unsteady flow

    IF (global%flowType==flow_unsteady .AND. &
        movegrid .AND. global%currentTime>0._rfreal) THEN
      IF (global%gridFormat == format_ascii) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.grda_', &
                                   global%currentTime
        OPEN(if_grid,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%gridFormat == format_binary) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.grdb_', &
                                   global%currentTime
        OPEN(if_grid,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = global%currentTime

! - steady flow

    ELSE
      IF (global%gridFormat == format_ascii) THEN
        WRITE(fname,'(A)') trim(global%outDir)//trim(global%casename)//'.grda'
        OPEN(if_grid,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%gridFormat == format_binary) THEN
        WRITE(fname,'(A)') trim(global%outDir)//trim(global%casename)//'.grdb'
        OPEN(if_grid,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = 0._rfreal
    ENDIF

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  ENDIF   ! MASTERPROC

! write time to file ----------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CALL rflo_writedatafilereal( global,if_grid,global%gridFormat,1,1,rvar )
  ENDIF

! write grid data -------------------------------------------------------------

  DO ireg=1,global%nRegions

! - allocate memory for data field

    IF (regions(ireg)%procid==global%myProcid .OR. &
        global%myProcid==masterproc) THEN
      ndim = (regions(ireg)%levels(1)%grid%ipc+1)* &
             (regions(ireg)%levels(1)%grid%jpc+1)* &
             (regions(ireg)%levels(1)%grid%kpc+1)
      ALLOCATE( xyzfile(3,ndim),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
    ENDIF

! - copy grid into data structure

    IF (regions(ireg)%procid == global%myProcid) THEN
      CALL rflo_getdimensphysnodes( regions(ireg),1,ipnbeg,ipnend, &
                                    jpnbeg,jpnend,kpnbeg,kpnend )
      CALL rflo_getnodeoffset( regions(ireg),1,inoff,ijnoff )
      xyz => regions(ireg)%levels(1)%grid%xyz

      n = 0
      DO k=kpnbeg,kpnend
        DO j=jpnbeg,jpnend
          DO i=ipnbeg,ipnend
            n    = n + 1
            ijkn = indijk(i,j,k,inoff,ijnoff)
            xyzfile(1,n) = xyz(xcoord,ijkn)
            xyzfile(2,n) = xyz(ycoord,ijkn)
            xyzfile(3,n) = xyz(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDDO
    ENDIF

! - write region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      ivar(1,1) = ireg
      ivar(2,1) = regions(ireg)%levels(1)%grid%ipc
      ivar(3,1) = regions(ireg)%levels(1)%grid%jpc
      ivar(4,1) = regions(ireg)%levels(1)%grid%kpc
      CALL rflo_writedatafileint( global,if_grid,global%gridFormat,4,1,ivar )
    ENDIF

! - master receives and writes data, others send them

    IF (global%myProcid == masterproc) THEN
#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_recv( xyzfile,3*ndim,mpi_rfreal,regions(ireg)%procid,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
      CALL rflo_writedatafilereal( global,if_grid,global%gridFormat,3,ndim, &
                                   xyzfile )

    ELSE   ! not the master
#ifdef MPI
      IF (regions(ireg)%procid == global%myProcid) THEN
        CALL mpi_send( xyzfile,3*ndim,mpi_rfreal,masterproc,ireg, &
                       global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
    ENDIF

    IF (ALLOCATED(xyzfile)) THEN
      DEALLOCATE( xyzfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_grid,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

END SUBROUTINE rflo_writegrid

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_WriteGrid.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.12  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.9  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.8  2002/10/23 18:43:24  jblazek
! Changed temporary pointer arrays into allocatable arrays
! in grid and solution I/O routines.
!
! Revision 1.7  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.6  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.5  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.4  2002/06/07 16:40:36  jblazek
! Grid & solution for all regions in one file.
!
! Revision 1.3  2002/02/21 23:25:04  jblazek
! Blocks renamed as regions.
!
! Revision 1.2  2002/01/08 22:09:16  jblazek
! Added calculation of face vectors and volumes.
!
! Revision 1.1  2001/12/22 00:09:37  jblazek
! Added routines to store grid and solution.
!
!******************************************************************************