RFLO_SetCornerEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: set values in edge and corner cells of a region.
!
! Description: this is for the case if the cells are not located
!              within another region.
!
! Input: region = region data.
!
! Output: new values of conservative variables.
!
! Notes: values in ALL edge and corner cells are averaged from neighboring
!        cells. Hence, this routine should be called first, before values
!        from adjacent regions are copied.
!
!******************************************************************************
!
! $Id: RFLO_SetCornerEdgeCells.F90,v 1.4 2008/12/06 08:44:28 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_setcorneredgecells( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensphys, &
                            rflo_getcelloffset
  USE moderror
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, gasmodel, icoff, ijcoff, ijkd, ijkc1, ijkc2

  REAL(RFREAL), POINTER :: cv(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_SetCornerEdgeCells',&
  'RFLO_SetCornerEdgeCells.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  gasmodel = region%mixtInput%gasModel

  cv => region%levels(ilev)%mixt%cv

! edges 9, 10, 11, 12 ---------------------------------------------------------

  DO i=ipcbeg,ipcend
    DO j=jpcbeg-1,jdcbeg,-1         ! edges 9, 10
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i,j  ,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j+1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k+1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i,j,k,icoff,ijcoff)
        ijkc1 = indijk(i,j+1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k-1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
    ENDDO

    DO j=jpcend+1,jdcend           ! edges 11, 12
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i,j,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k+1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i,j,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k-1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
    ENDDO
  ENDDO

! edges 2, 4, 6, 8 ------------------------------------------------------------

  DO j=jpcbeg,jpcend
    DO i=ipcbeg-1,idcbeg,-1        ! edges 2, 4
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i+1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k-1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i+1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k+1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
    ENDDO

    DO i=ipcend+1,idcend           ! edges 6, 8
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k-1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k+1,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
    ENDDO
  ENDDO

! edges 1, 3, 5, 7 ------------------------------------------------------------

  DO k=kdcbeg,kdcend
    DO i=ipcbeg-1,idcbeg,-1        ! edges 1, 3
      DO j=jpcbeg-1,jdcbeg,-1
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i+1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j+1,k,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
      DO j=jpcend+1,jdcend
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i+1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j-1,k,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
    ENDDO

    DO i=ipcend+1,idcend           ! edges 5, 7
      DO j=jpcbeg-1,jdcbeg,-1
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j+1,k,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
      DO j=jpcend+1,jdcend
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j-1,k,icoff,ijcoff)
        CALL rflo_averageedgecells( ijkd,ijkc1,ijkc2,gasmodel,cv,region )
      ENDDO
    ENDDO
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

! =============================================================================
!   Averaging subroutine
! =============================================================================

  CONTAINS

    SUBROUTINE rflo_averageedgecells( ijkD,ijkC1,ijkC2,gasModel,cv,region )
      USE moddatatypes
      USE moddatastruct, ONLY : t_region
      USE modinterfaces, ONLY : mixtureproperties
      USE modparameters
      IMPLICIT NONE

      INTEGER               :: ijkd, ijkc1, ijkc2, gasmodel
      REAL(RFREAL), POINTER :: cv(:,:)
      TYPE(t_region)        :: region

      cv(cv_mixt_dens,ijkd) = 0.5_rfreal*(cv(cv_mixt_dens,ijkc1)+ &
                                          cv(cv_mixt_dens,ijkc2))
      cv(cv_mixt_xmom,ijkd) = 0.5_rfreal*(cv(cv_mixt_xmom,ijkc1)+ &
                                          cv(cv_mixt_xmom,ijkc2))
      cv(cv_mixt_ymom,ijkd) = 0.5_rfreal*(cv(cv_mixt_ymom,ijkc1)+ &
                                          cv(cv_mixt_ymom,ijkc2))
      cv(cv_mixt_zmom,ijkd) = 0.5_rfreal*(cv(cv_mixt_zmom,ijkc1)+ &
                                          cv(cv_mixt_zmom,ijkc2))
      cv(cv_mixt_ener,ijkd) = 0.5_rfreal*(cv(cv_mixt_ener,ijkc1)+ &
                                          cv(cv_mixt_ener,ijkc2))

      IF (gasmodel == gas_model_tcperf) THEN
        CALL mixtureproperties( region,ijkd,ijkd,.false. )
      ELSE
        CALL mixtureproperties( region,ijkd,ijkd,.true.  )
      ENDIF

    END SUBROUTINE rflo_averageedgecells

END SUBROUTINE rflo_setcorneredgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_SetCornerEdgeCells.F90,v $
! Revision 1.4  2008/12/06 08:44:28  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:39  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/10/31 21:09:36  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/11/29 20:51:40  wasistho
! lower to upper case
!
! Revision 1.12  2003/11/20 16:40:40  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.8  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.7  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.6  2002/08/16 21:33:48  jblazek
! Changed interface to MixtureProperties.
!
! Revision 1.5  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.4  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.3  2002/02/16 07:16:00  jblazek
! Added implicit residual smoothing.
!
! Revision 1.2  2002/02/06 00:15:39  jblazek
! Improved injection BC. Added pointers to gradients.
!
! Revision 1.1  2002/01/31 20:20:13  jblazek
! Added treatment of edge & corner cells.
!
!******************************************************************************