RFLO_SendDummyConf.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: send values to dummy cells of the corresponding patch
!          of the adjacent region which is on another processor.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = region to send data to
!        patch     = current patch of region.
!
! Output: patch%mixt%nSendBuff = send buffer.
!
! Notes: intended for conforming grid boundaries only.
!
!******************************************************************************
!
! $Id: RFLO_SendDummyConf.F90,v 1.4 2008/12/06 08:44:28 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_senddummyconf( region,regionSrc,patch )

  USE moddatatypes
  USE modglobal, ONLY     : t_global
  USE moddatastruct, ONLY : t_region
  USE modbndpatch, ONLY   : t_patch
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getcelloffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: idum, i, j, k, ijkbuff

! ... local variables
  INTEGER :: ilev, ibeg, iend, jbeg, jend, kbeg, kend, icoff, ijcoff, ijkc, &
             n1, n2, ndim, dest, tag
  INTEGER :: lb, l1srcdir, l2srcdir, l1beg, l1end, l1step, l2beg, l2end, l2step

  LOGICAL :: align

  REAL(RFREAL), POINTER :: cv(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_SendDummyConf',&
  'RFLO_SendDummyConf.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  cv => region%levels(ilev)%mixt%cv

  n1   = abs(patch%l1end-patch%l1beg) + 1   ! here, dimensions of current
  n2   = abs(patch%l2end-patch%l2beg) + 1   ! and source patch are identical
  ndim = n1*n2*regionsrc%nDumCells          ! ... but not the # of dummy cells

! mapping between patches

                                       l1srcdir =  1
  IF (patch%srcL1beg > patch%srcL1end) l1srcdir = -1
                                       l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) l2srcdir = -1

  lb    = patch%lbound
  align = patch%align

! loop over interior cells of current patch -----------------------------------

  ijkbuff = 0

  DO idum=0,regionsrc%nDumCells-1

! - face i=const.

    IF (lb==1 .OR. lb==2) THEN

      IF (lb == 1) i = ibeg + idum
      IF (lb == 2) i = iend - idum
      IF (align) THEN
        IF (l1srcdir > 0) THEN
          l1beg = jbeg
          l1end = jend
        ELSE
          l1beg = jend
          l1end = jbeg
        ENDIF
        l1step = l1srcdir
        IF (l2srcdir > 0) THEN
          l2beg = kbeg
          l2end = kend
        ELSE
          l2beg = kend
          l2end = kbeg
        ENDIF
        l2step = l2srcdir
        DO k=l2beg,l2end,l2step
          DO j=l1beg,l1end,l1step
            ijkc    = indijk(i,j,k,icoff,ijcoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = cv(cv_mixt_dens,ijkc)
            patch%mixt%sendBuff(ijkbuff+  ndim) = cv(cv_mixt_xmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = cv(cv_mixt_ymom,ijkc)
            patch%mixt%sendBuff(ijkbuff+3*ndim) = cv(cv_mixt_zmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+4*ndim) = cv(cv_mixt_ener,ijkc)
          ENDDO
        ENDDO
      ELSE
        IF (l1srcdir > 0) THEN
          l1beg = kbeg
          l1end = kend
        ELSE
          l1beg = kend
          l1end = kbeg
        ENDIF
        l1step = l1srcdir
        IF (l2srcdir > 0) THEN
          l2beg = jbeg
          l2end = jend
        ELSE
          l2beg = jend
          l2end = jbeg
        ENDIF
        l2step = l2srcdir
        DO j=l2beg,l2end,l2step
          DO k=l1beg,l1end,l1step
            ijkc    = indijk(i,j,k,icoff,ijcoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = cv(cv_mixt_dens,ijkc)
            patch%mixt%sendBuff(ijkbuff+  ndim) = cv(cv_mixt_xmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = cv(cv_mixt_ymom,ijkc)
            patch%mixt%sendBuff(ijkbuff+3*ndim) = cv(cv_mixt_zmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+4*ndim) = cv(cv_mixt_ener,ijkc)
          ENDDO
        ENDDO
      ENDIF

! - face j=const.

    ELSE IF (lb==3 .OR. lb==4) THEN

      IF (lb == 3) j = jbeg + idum
      IF (lb == 4) j = jend - idum
      IF (align) THEN
        IF (l1srcdir > 0) THEN
          l1beg = kbeg
          l1end = kend
        ELSE
          l1beg = kend
          l1end = kbeg
        ENDIF
        l1step = l1srcdir
        IF (l2srcdir > 0) THEN
          l2beg = ibeg
          l2end = iend
        ELSE
          l2beg = iend
          l2end = ibeg
        ENDIF
        l2step = l2srcdir
        DO i=l2beg,l2end,l2step
          DO k=l1beg,l1end,l1step
            ijkc    = indijk(i,j,k,icoff,ijcoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = cv(cv_mixt_dens,ijkc)
            patch%mixt%sendBuff(ijkbuff+  ndim) = cv(cv_mixt_xmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = cv(cv_mixt_ymom,ijkc)
            patch%mixt%sendBuff(ijkbuff+3*ndim) = cv(cv_mixt_zmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+4*ndim) = cv(cv_mixt_ener,ijkc)
          ENDDO
        ENDDO
      ELSE
        IF (l1srcdir > 0) THEN
          l1beg = ibeg
          l1end = iend
        ELSE
          l1beg = iend
          l1end = ibeg
        ENDIF
        l1step = l1srcdir
        IF (l2srcdir > 0) THEN
          l2beg = kbeg
          l2end = kend
        ELSE
          l2beg = kend
          l2end = kbeg
        ENDIF
        l2step = l2srcdir
        DO k=l2beg,l2end,l2step
          DO i=l1beg,l1end,l1step
            ijkc    = indijk(i,j,k,icoff,ijcoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = cv(cv_mixt_dens,ijkc)
            patch%mixt%sendBuff(ijkbuff+  ndim) = cv(cv_mixt_xmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = cv(cv_mixt_ymom,ijkc)
            patch%mixt%sendBuff(ijkbuff+3*ndim) = cv(cv_mixt_zmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+4*ndim) = cv(cv_mixt_ener,ijkc)
          ENDDO
        ENDDO
      ENDIF

! - face k=const.

    ELSE IF (lb==5 .OR. lb==6) THEN

      IF (lb == 5) k = kbeg + idum
      IF (lb == 6) k = kend - idum
      IF (align) THEN
        IF (l1srcdir > 0) THEN
          l1beg = ibeg
          l1end = iend
        ELSE
          l1beg = iend
          l1end = ibeg
        ENDIF
        l1step = l1srcdir
        IF (l2srcdir > 0) THEN
          l2beg = jbeg
          l2end = jend
        ELSE
          l2beg = jend
          l2end = jbeg
        ENDIF
        l2step = l2srcdir
        DO j=l2beg,l2end,l2step
          DO i=l1beg,l1end,l1step
            ijkc    = indijk(i,j,k,icoff,ijcoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = cv(cv_mixt_dens,ijkc)
            patch%mixt%sendBuff(ijkbuff+  ndim) = cv(cv_mixt_xmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = cv(cv_mixt_ymom,ijkc)
            patch%mixt%sendBuff(ijkbuff+3*ndim) = cv(cv_mixt_zmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+4*ndim) = cv(cv_mixt_ener,ijkc)
          ENDDO
        ENDDO
      ELSE
        IF (l1srcdir > 0) THEN
          l1beg = jbeg
          l1end = jend
        ELSE
          l1beg = jend
          l1end = jbeg
        ENDIF
        l1step = l1srcdir
        IF (l2srcdir > 0) THEN
          l2beg = ibeg
          l2end = iend
        ELSE
          l2beg = iend
          l2end = ibeg
        ENDIF
        l2step = l2srcdir
        DO i=l2beg,l2end,l2step
          DO j=l1beg,l1end,l1step
            ijkc    = indijk(i,j,k,icoff,ijcoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = cv(cv_mixt_dens,ijkc)
            patch%mixt%sendBuff(ijkbuff+  ndim) = cv(cv_mixt_xmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = cv(cv_mixt_ymom,ijkc)
            patch%mixt%sendBuff(ijkbuff+3*ndim) = cv(cv_mixt_zmom,ijkc)
            patch%mixt%sendBuff(ijkbuff+4*ndim) = cv(cv_mixt_ener,ijkc)
          ENDDO
        ENDDO
      ENDIF

    ENDIF    ! lb

  ENDDO      ! idum

! send data

#ifdef MPI
  dest = regionsrc%procid
  tag  = regionsrc%localNumber + mpi_patchoff*patch%srcPatch
  CALL mpi_isend( patch%mixt%sendBuff,cv_mixt_neqs*ndim,mpi_rfreal, &
                  dest,tag,global%mpiComm, &
                  global%requests(patch%mixt%iRequest),global%mpierr )
  IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE rflo_senddummyconf

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_SendDummyConf.F90,v $
! Revision 1.4  2008/12/06 08:44:28  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:39:44  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 20:51:40  wasistho
! lower to upper case
!
! Revision 1.13  2003/11/20 16:40:40  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.9  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.8  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.7  2002/09/20 22:22:36  jblazek
! Finalized integration into GenX.
!
! Revision 1.6  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.5  2002/03/30 00:50:49  jblazek
! Cleaned up with flint.
!
! Revision 1.4  2002/03/29 23:15:22  jblazek
! Corrected bug in MPI send.
!
! Revision 1.3  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.2  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.1  2002/01/28 23:55:22  jblazek
! Added flux computation (central scheme).
!
!******************************************************************************