RFLO_RoeFluxFirst.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute convective fluxes based on 1st-order Roe upwind scheme.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%mixt%rhs = convective fluxes added to the residual.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_RoeFluxFirst.F90,v 1.3 2008/12/06 08:44:28 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_roefluxfirst( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset, &
                            rflo_getnodeoffset, rflo_roefluxpatch
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ipatch

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc0, ijkc1, ijkn, indsvel

  REAL(RFREAL)          :: rhl, rhr, qsl, qsr, pav, fc(5)
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), rhs(:,:), si(:,:), sj(:,:), sk(:,:)
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_RoeFluxFirst',&
  'RFLO_RoeFluxFirst.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  cv     => region%levels(ilev)%mixt%cv
  dv     => region%levels(ilev)%mixt%dv
  rhs    => region%levels(ilev)%mixt%rhs
  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

! flux in i-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg+1,ipcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        rhl   = dv(dv_mixt_pres,ijkc1) + cv(cv_mixt_ener,ijkc1)
        qsl   = dv(dv_mixt_uvel,ijkc1)*si(xcoord,ijkn) + &
                dv(dv_mixt_vvel,ijkc1)*si(ycoord,ijkn) + &
                dv(dv_mixt_wvel,ijkc1)*si(zcoord,ijkn) - sivel(ijkn*indsvel)
        rhr   = dv(dv_mixt_pres,ijkc0) + cv(cv_mixt_ener,ijkc0)
        qsr   = dv(dv_mixt_uvel,ijkc0)*si(xcoord,ijkn) + &
                dv(dv_mixt_vvel,ijkc0)*si(ycoord,ijkn) + &
                dv(dv_mixt_wvel,ijkc0)*si(zcoord,ijkn) - sivel(ijkn*indsvel)
        pav   = 0.5_rfreal*(dv(dv_mixt_pres,ijkc0)+dv(dv_mixt_pres,ijkc1))

        fc(1) = 0.5_rfreal*(qsl*cv(cv_mixt_dens,ijkc1)+ &
                            qsr*cv(cv_mixt_dens,ijkc0))
        fc(2) = 0.5_rfreal*(qsl*cv(cv_mixt_xmom,ijkc1)+ &
                            qsr*cv(cv_mixt_xmom,ijkc0)) + pav*si(xcoord,ijkn)
        fc(3) = 0.5_rfreal*(qsl*cv(cv_mixt_ymom,ijkc1)+ &
                            qsr*cv(cv_mixt_ymom,ijkc0)) + pav*si(ycoord,ijkn)
        fc(4) = 0.5_rfreal*(qsl*cv(cv_mixt_zmom,ijkc1)+ &
                            qsr*cv(cv_mixt_zmom,ijkc0)) + pav*si(zcoord,ijkn)
        fc(5) = 0.5_rfreal*(qsl*rhl+qsr*rhr) + sivel(ijkn*indsvel)*pav

        rhs(cv_mixt_dens,ijkc0) = rhs(cv_mixt_dens,ijkc0) + fc(1)
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + fc(2)
        rhs(cv_mixt_ymom,ijkc0) = rhs(cv_mixt_ymom,ijkc0) + fc(3)
        rhs(cv_mixt_zmom,ijkc0) = rhs(cv_mixt_zmom,ijkc0) + fc(4)
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + fc(5)

        rhs(cv_mixt_dens,ijkc1) = rhs(cv_mixt_dens,ijkc1) - fc(1)
        rhs(cv_mixt_xmom,ijkc1) = rhs(cv_mixt_xmom,ijkc1) - fc(2)
        rhs(cv_mixt_ymom,ijkc1) = rhs(cv_mixt_ymom,ijkc1) - fc(3)
        rhs(cv_mixt_zmom,ijkc1) = rhs(cv_mixt_zmom,ijkc1) - fc(4)
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) - fc(5)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in j-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg+1,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        rhl   = dv(dv_mixt_pres,ijkc1) + cv(cv_mixt_ener,ijkc1)
        qsl   = dv(dv_mixt_uvel,ijkc1)*sj(xcoord,ijkn) + &
                dv(dv_mixt_vvel,ijkc1)*sj(ycoord,ijkn) + &
                dv(dv_mixt_wvel,ijkc1)*sj(zcoord,ijkn) - sjvel(ijkn*indsvel)
        rhr   = dv(dv_mixt_pres,ijkc0) + cv(cv_mixt_ener,ijkc0)
        qsr   = dv(dv_mixt_uvel,ijkc0)*sj(xcoord,ijkn) + &
                dv(dv_mixt_vvel,ijkc0)*sj(ycoord,ijkn) + &
                dv(dv_mixt_wvel,ijkc0)*sj(zcoord,ijkn) - sjvel(ijkn*indsvel)
        pav   = 0.5_rfreal*(dv(dv_mixt_pres,ijkc0)+dv(dv_mixt_pres,ijkc1))

        fc(1) = 0.5_rfreal*(qsl*cv(cv_mixt_dens,ijkc1)+ &
                            qsr*cv(cv_mixt_dens,ijkc0))
        fc(2) = 0.5_rfreal*(qsl*cv(cv_mixt_xmom,ijkc1)+ &
                            qsr*cv(cv_mixt_xmom,ijkc0)) + pav*sj(xcoord,ijkn)
        fc(3) = 0.5_rfreal*(qsl*cv(cv_mixt_ymom,ijkc1)+ &
                            qsr*cv(cv_mixt_ymom,ijkc0)) + pav*sj(ycoord,ijkn)
        fc(4) = 0.5_rfreal*(qsl*cv(cv_mixt_zmom,ijkc1)+ &
                            qsr*cv(cv_mixt_zmom,ijkc0)) + pav*sj(zcoord,ijkn)
        fc(5) = 0.5_rfreal*(qsl*rhl+qsr*rhr) + sjvel(ijkn*indsvel)*pav

        rhs(cv_mixt_dens,ijkc0) = rhs(cv_mixt_dens,ijkc0) + fc(1)
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + fc(2)
        rhs(cv_mixt_ymom,ijkc0) = rhs(cv_mixt_ymom,ijkc0) + fc(3)
        rhs(cv_mixt_zmom,ijkc0) = rhs(cv_mixt_zmom,ijkc0) + fc(4)
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + fc(5)

        rhs(cv_mixt_dens,ijkc1) = rhs(cv_mixt_dens,ijkc1) - fc(1)
        rhs(cv_mixt_xmom,ijkc1) = rhs(cv_mixt_xmom,ijkc1) - fc(2)
        rhs(cv_mixt_ymom,ijkc1) = rhs(cv_mixt_ymom,ijkc1) - fc(3)
        rhs(cv_mixt_zmom,ijkc1) = rhs(cv_mixt_zmom,ijkc1) - fc(4)
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) - fc(5)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in k-direction (except through boundary) -------------------------------

  DO k=kpcbeg+1,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        rhl   = dv(dv_mixt_pres,ijkc1) + cv(cv_mixt_ener,ijkc1)
        qsl   = dv(dv_mixt_uvel,ijkc1)*sk(xcoord,ijkn) + &
                dv(dv_mixt_vvel,ijkc1)*sk(ycoord,ijkn) + &
                dv(dv_mixt_wvel,ijkc1)*sk(zcoord,ijkn) - skvel(ijkn*indsvel)
        rhr   = dv(dv_mixt_pres,ijkc0) + cv(cv_mixt_ener,ijkc0)
        qsr   = dv(dv_mixt_uvel,ijkc0)*sk(xcoord,ijkn) + &
                dv(dv_mixt_vvel,ijkc0)*sk(ycoord,ijkn) + &
                dv(dv_mixt_wvel,ijkc0)*sk(zcoord,ijkn) - skvel(ijkn*indsvel)
        pav   = 0.5_rfreal*(dv(dv_mixt_pres,ijkc0)+dv(dv_mixt_pres,ijkc1))

        fc(1) = 0.5_rfreal*(qsl*cv(cv_mixt_dens,ijkc1)+ &
                            qsr*cv(cv_mixt_dens,ijkc0))
        fc(2) = 0.5_rfreal*(qsl*cv(cv_mixt_xmom,ijkc1)+ &
                            qsr*cv(cv_mixt_xmom,ijkc0)) + pav*sk(xcoord,ijkn)
        fc(3) = 0.5_rfreal*(qsl*cv(cv_mixt_ymom,ijkc1)+ &
                            qsr*cv(cv_mixt_ymom,ijkc0)) + pav*sk(ycoord,ijkn)
        fc(4) = 0.5_rfreal*(qsl*cv(cv_mixt_zmom,ijkc1)+ &
                            qsr*cv(cv_mixt_zmom,ijkc0)) + pav*sk(zcoord,ijkn)
        fc(5) = 0.5_rfreal*(qsl*rhl+qsr*rhr) + skvel(ijkn*indsvel)*pav

        rhs(cv_mixt_dens,ijkc0) = rhs(cv_mixt_dens,ijkc0) + fc(1)
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + fc(2)
        rhs(cv_mixt_ymom,ijkc0) = rhs(cv_mixt_ymom,ijkc0) + fc(3)
        rhs(cv_mixt_zmom,ijkc0) = rhs(cv_mixt_zmom,ijkc0) + fc(4)
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + fc(5)

        rhs(cv_mixt_dens,ijkc1) = rhs(cv_mixt_dens,ijkc1) - fc(1)
        rhs(cv_mixt_xmom,ijkc1) = rhs(cv_mixt_xmom,ijkc1) - fc(2)
        rhs(cv_mixt_ymom,ijkc1) = rhs(cv_mixt_ymom,ijkc1) - fc(3)
        rhs(cv_mixt_zmom,ijkc1) = rhs(cv_mixt_zmom,ijkc1) - fc(4)
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) - fc(5)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fluxes through boundaries ---------------------------------------------------

  DO ipatch=1,region%nPatches
    CALL rflo_roefluxpatch( region,region%levels(ilev)%patches(ipatch) )
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_roefluxfirst

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_RoeFluxFirst.F90,v $
! Revision 1.3  2008/12/06 08:44:28  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:40  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:40  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.2  2003/10/01 23:52:10  jblazek
! Corrected bug in moving noslip wall BC and grid speeds.
!
! Revision 1.1  2003/05/29 17:28:43  jblazek
! Implemented Roe scheme.
!
!******************************************************************************