RFLO_ReceiveDummyVals.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receive values to the dummy cells of the patch from neighboring
!          region / periodic boundary, which is located on a different
!          processor.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: region%levels%mixt = flow variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ReceiveDummyVals.F90,v 1.5 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_receivedummyvals( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getcelloffset, &
                            mixtureproperties
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: idum, i, j, k, ijkbuff

! ... local variables
#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: lb, ibeg, iend, jbeg, jend, kbeg, kend, icoff, ijcoff, ijkd, &
             n1, n2, ndim, source, tag, ilev, gasmodel

  REAL(RFREAL), POINTER :: cv(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_ReceiveDummyVals',&
  'RFLO_ReceiveDummyVals.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  gasmodel = region%mixtInput%gasModel

  cv => region%levels(ilev)%mixt%cv

  n1   = abs(patch%l1end-patch%l1beg) + 1   ! here, dimensions of current
  n2   = abs(patch%l2end-patch%l2beg) + 1   ! and source patch are identical
  ndim = n1*n2*region%nDumCells             ! ... but not the # of dummy cells

! receive data

#ifdef MPI
  source = regionsrc%procid
  tag    = region%localNumber + mpi_patchoff*patchsrc%srcPatch
  CALL mpi_recv( patch%mixt%recvBuff,cv_mixt_neqs*ndim,mpi_rfreal, &
                 source,tag,global%mpiComm,status,global%mpierr )
  IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! copy from buffer to dummy nodes ---------------------------------------------

  lb      = patch%lbound
  ijkbuff = 0

  DO idum=1,region%nDumCells

! - face i=const.

    IF (lb==1 .OR. lb==2) THEN
      IF (lb == 1) i = ibeg - idum
      IF (lb == 2) i = iend + idum
      DO k=kbeg,kend
        DO j=jbeg,jend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          cv(cv_mixt_dens,ijkd) = patch%mixt%recvBuff(ijkbuff       )
          cv(cv_mixt_xmom,ijkd) = patch%mixt%recvBuff(ijkbuff+  ndim)
          cv(cv_mixt_ymom,ijkd) = patch%mixt%recvBuff(ijkbuff+2*ndim)
          cv(cv_mixt_zmom,ijkd) = patch%mixt%recvBuff(ijkbuff+3*ndim)
          cv(cv_mixt_ener,ijkd) = patch%mixt%recvBuff(ijkbuff+4*ndim)
          IF (gasmodel == gas_model_tcperf) THEN
            CALL mixtureproperties( region,ijkd,ijkd,.false. )
          ELSE
            CALL mixtureproperties( region,ijkd,ijkd,.true.  )
          ENDIF
        ENDDO
      ENDDO

! - face j=const.

    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (lb == 3) j = jbeg - idum
      IF (lb == 4) j = jend + idum
      DO i=ibeg,iend
        DO k=kbeg,kend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          cv(cv_mixt_dens,ijkd) = patch%mixt%recvBuff(ijkbuff       )
          cv(cv_mixt_xmom,ijkd) = patch%mixt%recvBuff(ijkbuff+  ndim)
          cv(cv_mixt_ymom,ijkd) = patch%mixt%recvBuff(ijkbuff+2*ndim)
          cv(cv_mixt_zmom,ijkd) = patch%mixt%recvBuff(ijkbuff+3*ndim)
          cv(cv_mixt_ener,ijkd) = patch%mixt%recvBuff(ijkbuff+4*ndim)
          IF (gasmodel == gas_model_tcperf) THEN
            CALL mixtureproperties( region,ijkd,ijkd,.false. )
          ELSE
            CALL mixtureproperties( region,ijkd,ijkd,.true.  )
          ENDIF
        ENDDO
      ENDDO

! - face k=const.

    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (lb == 5) k = kbeg - idum
      IF (lb == 6) k = kend + idum
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          cv(cv_mixt_dens,ijkd) = patch%mixt%recvBuff(ijkbuff       )
          cv(cv_mixt_xmom,ijkd) = patch%mixt%recvBuff(ijkbuff+  ndim)
          cv(cv_mixt_ymom,ijkd) = patch%mixt%recvBuff(ijkbuff+2*ndim)
          cv(cv_mixt_zmom,ijkd) = patch%mixt%recvBuff(ijkbuff+3*ndim)
          cv(cv_mixt_ener,ijkd) = patch%mixt%recvBuff(ijkbuff+4*ndim)
          IF (gasmodel == gas_model_tcperf) THEN
            CALL mixtureproperties( region,ijkd,ijkd,.false. )
          ELSE
            CALL mixtureproperties( region,ijkd,ijkd,.true.  )
          ENDIF
        ENDDO
      ENDDO
    ENDIF   ! lb

  ENDDO     ! idum

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_receivedummyvals

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReceiveDummyVals.F90,v $
! Revision 1.5  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/08/19 15:39:40  mparmar
! Renamed patch variables
!
! Revision 1.2  2005/10/31 21:09:36  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/11/29 20:51:40  wasistho
! lower to upper case
!
! Revision 1.16  2003/11/20 16:40:40  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.12  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.11  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.10  2002/09/20 22:22:36  jblazek
! Finalized integration into GenX.
!
! Revision 1.9  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.8  2002/08/16 21:33:48  jblazek
! Changed interface to MixtureProperties.
!
! Revision 1.7  2002/04/01 19:36:08  jblazek
! Added routine to clear send requests.
!
! Revision 1.6  2002/03/30 00:50:49  jblazek
! Cleaned up with flint.
!
! Revision 1.5  2002/03/29 23:15:22  jblazek
! Corrected bug in MPI send.
!
! Revision 1.4  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.3  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.2  2002/01/28 23:55:22  jblazek
! Added flux computation (central scheme).
!
! Revision 1.1  2002/01/16 22:03:35  jblazek
! Added time-stepping routines.
!
!******************************************************************************