RFLO_ReadStat.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in time averaged statistics of the mixture.
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary
!
! Input: regions = dimensions of all regions
!
! Output: region%levels%mixt%tav = time avg mixture variables (current grid level)
!         region%levels%turb%tav = time avg TURB variables (current grid level)
!         global%integrTime      = integrated averaging time
!
! Notes: time averaged solution is read in only for the current grid level;
!        it is also read in for all dummy cells
!
!******************************************************************************
!
! $Id: RFLO_ReadStat.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readstat( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_readdatafileint, rflo_readdatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, l, n, ind

! ... local variables
  CHARACTER(2*CHRLEN+17) :: fname
  CHARACTER(CHRLEN)      :: msg

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, ndim, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: mixtvarid(2,regions(1)%global%mixtnstat)
  INTEGER :: turbvarid(2,regions(1)%global%turbnstat)
  INTEGER :: ntavgvar, maxnstat, allnstat, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:), jvar(:,:)

  REAL(RFREAL), POINTER     :: mixttav(:,:), turbtav(:,:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), tavfile(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ReadStat',&
  'RFLO_ReadStat.F90' )

! allocate temporary data arrays --------------------------------------------

  ALLOCATE( ivar(5,1),stat=errorflag )
  ALLOCATE( rvar(2,1),stat=errorflag )
  maxnstat = global%mixtNStat
#ifdef TURB
  IF (global%turbNStat>0) maxnstat = max( global%mixtNStat,global%turbNStat )
#endif  
  ALLOCATE( jvar(maxnstat+1,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open statistics file (only master proc.) ----------------------------------

  IF (global%myProcid == masterproc) THEN

    IF (global%solutFormat == format_ascii) THEN
      WRITE(fname,'(A,1PE11.5)') trim(global%inDir)//trim(global%casename)//'.stata_', &
                                 global%timeStamp
      OPEN(if_stat,file=fname,form='formatted',status='old',iostat=errorflag)
    ELSE IF (global%solutFormat == format_binary) THEN
      WRITE(fname,'(A,1PE11.5)') trim(global%inDir)//trim(global%casename)//'.statb_', &
                                 global%timeStamp
      OPEN(if_stat,file=fname,form='unformatted',status='old',iostat=errorflag)
    ELSE 
      CALL errorstop( global,err_unknown_format,__line__ )
    ENDIF

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  ENDIF   ! MASTERPROC

! read & broadcast current and integrated time in file, and stats ID ---------------

  IF (global%myProcid == masterproc) THEN
    CALL rflo_readdatafilereal( global,if_stat,global%solutFormat,2,1,rvar )
  ENDIF

#ifdef MPI
  CALL mpi_bcast( rvar,2,mpi_rfreal,masterproc,global%mpiComm,global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

  IF (global%flowType==flow_unsteady .AND. global%currentTime>0._rfreal) THEN
    IF (global%currentTime /= rvar(1,1)) THEN
      WRITE(msg,1000) rvar(1,1),global%currentTime
      CALL errorstop( global,err_time_solution,__line__,msg//' File: '//trim(fname) )
    ENDIF
  ELSE
    global%currentTime = rvar(1,1)
  ENDIF
  global%integrTime = rvar(2,1)

  IF (global%myProcid == masterproc) THEN

! - mixture statistics NSTATS and ID

    IF (global%mixtNStat > 0) THEN
      CALL rflo_readdatafileint( global,if_stat,global%solutFormat, &
                                 global%mixtNStat+1,1,jvar )
      ntavgvar  = jvar(1,1)
      IF (ntavgvar /= global%mixtNStat) THEN
        CALL errorstop( global,err_stats_restart,__line__ )
      ENDIF

      mixtvarid(1,:) = jvar(2:global%mixtNStat+1,1)
      mixtvarid(2,:) = mod(mixtvarid(1,:),10)
      mixtvarid(1,:) = (mixtvarid(1,:)-mixtvarid(2,:))/10

      DO ind=1,2
        DO l=1,global%mixtNStat
          IF (mixtvarid(ind,l) /= global%mixtStatId(ind,l)) &
          CALL errorstop( global,err_stats_restart,__line__ )
        ENDDO 
      ENDDO
    ENDIF

! - turbulence statistics NSTATS and ID

#ifdef TURB
    IF (global%turbNStat > 0) THEN
      CALL rflo_readdatafileint( global,if_stat,global%solutFormat, &
                                 global%turbNStat+1,1,jvar )
      ntavgvar  = jvar(1,1)
      IF (ntavgvar /= global%turbNStat) THEN
        CALL errorstop( global,err_stats_restart,__line__ )
      ENDIF

      turbvarid(1,:) = jvar(2:global%turbNStat+1,1)
      turbvarid(2,:) = mod(turbvarid(1,:),10)
      turbvarid(1,:) = (turbvarid(1,:)-turbvarid(2,:))/10

      DO ind=1,2
        DO l=1,global%turbNStat
          IF (turbvarid(ind,l) /= global%turbStatId(ind,l)) &
          CALL errorstop( global,err_stats_restart,__line__ )
        ENDDO 
      ENDDO
    ENDIF
#endif
  ENDIF

! read statistics data from all regions ------------------------------------------

  allnstat = global%mixtNStat+global%turbNStat

  DO ireg=1,global%nRegions

! - get dimensions and pointers

    ilev = regions(ireg)%currLevel
    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
    ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
    ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
    ndim   = ijkend - ijkbeg + 1

! - read region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      CALL rflo_readdatafileint( global,if_stat,global%solutFormat,5,1,ivar )
      iregfile  = ivar(1,1)
      ipc       = ivar(2,1)
      jpc       = ivar(3,1)
      kpc       = ivar(4,1)
      ndumcells = ivar(5,1)
      
      IF (iregfile /= ireg) &
        CALL errorstop( global,err_region_number,__line__,'File: '//trim(fname) )
      IF ((ipc /= regions(ireg)%levels(ilev)%grid%ipc) .OR. &
          (jpc /= regions(ireg)%levels(ilev)%grid%jpc) .OR. &
          (kpc /= regions(ireg)%levels(ilev)%grid%kpc)) THEN
        WRITE(msg,1005) ireg,ipc,jpc,kpc
        CALL errorstop( global,err_grid_dimensions,__line__,msg )
      ENDIF
      IF (ndumcells /= regions(ireg)%nDumCells) THEN
        WRITE(msg,1010) ireg,ndumcells,regions(ireg)%nDumCells
        CALL errorstop( global,err_grid_dumcells,__line__,msg )
      ENDIF

! - master reads & sends data, others receive them

      ALLOCATE( tavfile(allnstat,ndim),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      CALL rflo_readdatafilereal( global,if_stat,global%solutFormat, &
                                  allnstat,ndim,tavfile )
#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_send( tavfile,allnstat*ndim,mpi_rfreal, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
    ELSE   ! not the master

      IF (regions(ireg)%procid == global%myProcid) THEN
        ALLOCATE( tavfile(allnstat,ndim),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
#ifdef MPI
        CALL mpi_recv( tavfile,allnstat*ndim,mpi_rfreal,masterproc, &
                       ireg,global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif
      ENDIF

    ENDIF  ! global%myProcid

! - copy statistics into data structure

    IF (regions(ireg)%procid == global%myProcid) THEN
      IF (global%mixtNStat > 0) mixttav => regions(ireg)%levels(ilev)%mixt%tav
      n = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            DO l=1,global%mixtNStat
              mixttav(l,ijk) = tavfile(l,n)
            ENDDO
          ENDDO
        ENDDO
      ENDDO
#ifdef TURB
      IF (global%turbNStat > 0) THEN
        IF ((regions(ireg)%mixtInput%flowModel == flow_navst) .AND. &
            (regions(ireg)%mixtInput%turbModel /= turb_model_none)) THEN
          turbtav => regions(ireg)%levels(ilev)%turb%tav
          n = 0
          DO k=kdcbeg,kdcend
            DO j=jdcbeg,jdcend
              DO i=idcbeg,idcend
                n   = n + 1
                ijk = indijk(i,j,k,ioff,ijoff)
                DO l=1,global%turbNStat
                  turbtav(l,ijk) = tavfile(l+global%mixtNStat,n)
                ENDDO
              ENDDO
            ENDDO
          ENDDO
        ENDIF
      ENDIF
#endif
    ENDIF

    IF (ALLOCATED(tavfile)) THEN
      DEALLOCATE( tavfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize -----------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_stat,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

1000 FORMAT('Time in file is= ',1pe12.5,' but it should be= ',e12.5,'.')
1005 FORMAT('Region ',i5,', ipc= ',i6,', jpc= ',i6,', kpc= ',i6,'.')
1010 FORMAT('Region ',i5,', # dummy cells=',i2,' but should be= ',i1)

END SUBROUTINE rflo_readstat

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadStat.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.14  2004/11/09 10:51:48  wasistho
! provide maximum size for jvar
!
! Revision 1.13  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.10  2003/08/11 20:12:51  wasistho
! put safety in reading turbulence statistics
!
! Revision 1.9  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.8  2002/11/04 18:41:57  wasistho
! Modified statistics restart
!
! Revision 1.7  2002/11/02 01:47:23  wasistho
! Added TURB statistics
!
! Revision 1.6  2002/10/23 18:43:24  jblazek
! Changed temporary pointer arrays into allocatable arrays
! in grid and solution I/O routines.
!
! Revision 1.5  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.4  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.3  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.2  2002/07/22 15:44:08  wasistho
! Cleaned-up conforming Coding Rule
!
! Revision 1.1  2002/06/14 20:53:05  wasistho
! add time avg statistics
!
!******************************************************************************