RFLO_ReadSolution.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in flow solution (only the mixture) and grid speeds.
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions = dimensions of all regions.
!
! Output: region%levels%mixt%cv        = conservative variables (current grid
!                                        level)
!         region%levels%grid%si/j/kVel = grid speeds (if grid is moving)
!         global%currentTime           = physical time
!         global%resInit               = initial residual
!
! Notes: solution and grid speeds are read in only for the current grid level;
!        solution is also read in for all dummy cells.
!
!******************************************************************************
!
! $Id: RFLO_ReadSolution.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readsolution( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_readdatafileint, rflo_readdatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset, &
                            rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, n

! ... local variables
  CHARACTER(2*CHRLEN+17) :: fname
  CHARACTER(CHRLEN)      :: msg, timestring

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend, inoff, ijnoff
  INTEGER :: ndimc, ndimn, nrvar, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  REAL(RFREAL), POINTER     :: cv(:,:), sivel(:), sjvel(:), skvel(:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), cvfile(:,:), svelfile(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ReadSolution',&
  'RFLO_ReadSolution.F90' )

! allocate fixed-size temporary data arrays -----------------------------------

#ifdef PERI
  nrvar = 3
#else
  nrvar = 2
#endif
  ALLOCATE( ivar(5,1),stat=errorflag )
  ALLOCATE( rvar(nrvar,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! copy time to string ---------------------------------------------------------

  IF (global%flowType == flow_unsteady) THEN
    WRITE(timestring,'(1PE11.5)') global%timeStamp
  ELSE
    WRITE(timestring,'(1PE11.5)') 0._rfreal
  ENDIF

! open solution file (only master proc.) --------------------------------------

  IF (global%myProcid == masterproc) THEN

! - unsteady flow

    IF (global%flowType == flow_unsteady) THEN
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%inDir)//trim(global%casename)//'.sola_', &
                                   global%timeStamp
        OPEN(if_solut,file=fname,form='formatted',status='old',iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%inDir)//trim(global%casename)//'.solb_', &
                                   global%timeStamp
        OPEN(if_solut,file=fname,form='unformatted',status='old',iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF

! - steady flow

    ELSE
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,I6.6)') trim(global%inDir)//trim(global%casename)//'.sola_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='formatted',status='old',iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,I6.6)') trim(global%inDir)//trim(global%casename)//'.solb_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='unformatted',status='old',iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
    ENDIF

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  ENDIF   ! MASTERPROC

! read & broadcast time and initial residual in file --------------------------

  IF (global%myProcid == masterproc) THEN
    CALL rflo_readdatafilereal( global,if_solut,global%solutFormat,nrvar,1,rvar )
  ENDIF

#ifdef MPI
  CALL mpi_bcast( rvar,nrvar,mpi_rfreal,masterproc,global%mpiComm,global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

  IF (global%flowType==flow_unsteady .AND. global%currentTime>0._rfreal) THEN
    IF (global%currentTime /= rvar(1,1)) THEN
      WRITE(msg,1000) rvar(1,1),global%currentTime
      CALL errorstop( global,err_time_solution,__line__,msg//' File: '//trim(fname) )
    ENDIF
  ELSE
    IF (global%timeStamp > 0._rfreal) THEN
      global%currentTime = rvar(1,1)
    ELSE
      global%currentTime = 0._rfreal
    ENDIF
  ENDIF
  global%resInit      = rvar(2,1)
#ifdef PERI
  global%moduleVar(1) = rvar(3,1)
#endif

! read solution data ----------------------------------------------------------

  DO ireg=1,global%nRegions

! - get dimensions and pointers

    ilev = regions(ireg)%currLevel
    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
    ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
    ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
    ndimc  = ijkend - ijkbeg + 1

    CALL rflo_getdimensphysnodes( regions(ireg),ilev,ipnbeg,ipnend, &
                                  jpnbeg,jpnend,kpnbeg,kpnend )
    CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
    ndimn = (regions(ireg)%levels(ilev)%grid%ipc+1)* &
            (regions(ireg)%levels(ilev)%grid%jpc+1)* &
            (regions(ireg)%levels(ilev)%grid%kpc+1)

! - read region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      CALL rflo_readdatafileint( global,if_solut,global%solutFormat,5,1,ivar )
      iregfile  = ivar(1,1)
      ipc       = ivar(2,1)
      jpc       = ivar(3,1)
      kpc       = ivar(4,1)
      ndumcells = ivar(5,1)
      
      IF (iregfile /= ireg) &
        CALL errorstop( global,err_region_number,__line__,'File: '//trim(fname) )
      IF ((ipc /= regions(ireg)%levels(ilev)%grid%ipc) .OR. &
          (jpc /= regions(ireg)%levels(ilev)%grid%jpc) .OR. &
          (kpc /= regions(ireg)%levels(ilev)%grid%kpc)) THEN
        WRITE(msg,1005) ireg,ipc,jpc,kpc
        CALL errorstop( global,err_grid_dimensions,__line__,msg )
      ENDIF
      IF (ndumcells /= regions(ireg)%nDumCells) THEN
        WRITE(msg,1010) ireg,ndumcells,regions(ireg)%nDumCells
        CALL errorstop( global,err_grid_dumcells,__line__,msg )
      ENDIF
    ENDIF

! - master reads & sends data, others receive them

    IF (global%myProcid == masterproc) THEN

      ALLOCATE( cvfile(cv_mixt_neqs,ndimc),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      CALL rflo_readdatafilereal( global,if_solut,global%solutFormat, &
                                  cv_mixt_neqs,ndimc,cvfile )

      IF (regions(ireg)%mixtInput%moveGrid .AND. &
          trim(timestring)/='0.00000E+00') THEN
        ALLOCATE( svelfile(3,ndimn),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
        CALL rflo_readdatafilereal( global,if_solut,global%solutFormat, &
                                    3,ndimn,svelfile )
      ENDIF

#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_send( cvfile,cv_mixt_neqs*ndimc,mpi_rfreal, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )

        IF (regions(ireg)%mixtInput%moveGrid .AND. &
            trim(timestring)/='0.00000E+00') THEN
          CALL mpi_send( svelfile,3*ndimn,mpi_rfreal, &
                         regions(ireg)%procid,ireg, &
                         global%mpiComm,global%mpierr )
          IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
        ENDIF
      ENDIF
#endif

    ELSE   ! not the master

      IF (regions(ireg)%procid == global%myProcid) THEN
        ALLOCATE( cvfile(cv_mixt_neqs,ndimc),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

        IF (regions(ireg)%mixtInput%moveGrid .AND. &
            trim(timestring)/='0.00000E+00') THEN
          ALLOCATE( svelfile(3,ndimn),stat=errorflag )
          global%error = errorflag
          IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
        ENDIF
#ifdef MPI
        CALL mpi_recv( cvfile,cv_mixt_neqs*ndimc,mpi_rfreal,masterproc,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )

        IF (regions(ireg)%mixtInput%moveGrid .AND. &
            trim(timestring)/='0.00000E+00') THEN
          CALL mpi_recv( svelfile,3*ndimn,mpi_rfreal,masterproc,ireg, &
                         global%mpiComm,status,global%mpierr )
          IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
        ENDIF
#endif
      ENDIF

    ENDIF

! - copy solution into data structure

    IF (regions(ireg)%procid == global%myProcid) THEN
      cv => regions(ireg)%levels(ilev)%mixt%cv
      n  = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            cv(cv_mixt_dens,ijk) = cvfile(1,n)
            cv(cv_mixt_xmom,ijk) = cvfile(2,n)
            cv(cv_mixt_ymom,ijk) = cvfile(3,n)
            cv(cv_mixt_zmom,ijk) = cvfile(4,n)
            cv(cv_mixt_ener,ijk) = cvfile(5,n)
          ENDDO
        ENDDO
      ENDDO

! --- ... and grid speeds

      IF (regions(ireg)%mixtInput%moveGrid .AND. &
            trim(timestring)/='0.00000E+00') THEN
        sivel => regions(ireg)%levels(ilev)%grid%siVel
        sjvel => regions(ireg)%levels(ilev)%grid%sjVel
        skvel => regions(ireg)%levels(ilev)%grid%skVel
        n = 0
        DO k=kpnbeg,kpnend
          DO j=jpnbeg,jpnend
            DO i=ipnbeg,ipnend
              n   = n + 1
              ijk = indijk(i,j,k,inoff,ijnoff)
              sivel(ijk) = svelfile(1,n)
              sjvel(ijk) = svelfile(2,n)
              skvel(ijk) = svelfile(3,n)
            ENDDO
          ENDDO
        ENDDO
      ENDIF
    ENDIF      ! global%myProcid

    IF (ALLOCATED(cvfile)) THEN
      DEALLOCATE( cvfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF
    IF (ALLOCATED(svelfile)) THEN
      DEALLOCATE( svelfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_solut,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

1000 FORMAT('Time in file is= ',1pe12.5,' but it should be= ',e12.5,'.')
1005 FORMAT('Region ',i5,', ipc= ',i6,', jpc= ',i6,', kpc= ',i6,'.')
1010 FORMAT('Region ',i5,', # dummy cells=',i2,' but should be= ',i1)

END SUBROUTINE rflo_readsolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadSolution.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.18  2004/08/08 20:40:13  wasistho
! set current time to zero only if time-stamp=0
!
! Revision 1.17  2004/08/06 03:27:43  wasistho
! set current time to zero if timeStamp=0
!
! Revision 1.16  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.13  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.12  2003/04/02 00:24:05  wasistho
! install ROCPERI
!
! Revision 1.11  2002/10/23 18:43:24  jblazek
! Changed temporary pointer arrays into allocatable arrays
! in grid and solution I/O routines.
!
! Revision 1.10  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.9  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.8  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.7  2002/08/29 21:52:21  jblazek
! Added I/O of grid speeds.
!
! Revision 1.6  2002/06/07 16:40:36  jblazek
! Grid & solution for all regions in one file.
!
! Revision 1.5  2002/02/21 23:25:04  jblazek
! Blocks renamed as regions.
!
! Revision 1.4  2002/02/04 15:30:25  jblazek
! Added injection boundary condition.
!
! Revision 1.3  2002/01/08 22:09:16  jblazek
! Added calculation of face vectors and volumes.
!
! Revision 1.2  2002/01/02 16:20:19  jblazek
! Added flow initialization and dummy cell geometry.
!
! Revision 1.1  2001/12/19 23:09:20  jblazek
! Added routines to read grid and solution.
!
!******************************************************************************