RFLO_ReadBcInflowVelSection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in user input related to inflow boundary condition.
!
! Description: present inflow bc is based on prescribed velocities and 
!              either temperature or pressure.
!
! Input: boundary condition file.
!
! Output: regions = BC data.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ReadBcInflowVelSection.F90,v 1.11 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readbcinflowvelsection( regions,bcTitle )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : readpatchsection, rflo_readbcfromfile
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)
  INTEGER :: bctitle

! ... loop variables
  INTEGER :: ireg, ipatch

! ... local variables
  INTEGER, PARAMETER :: nvals_max = 8

  CHARACTER(10)  :: keys(nvals_max)
  CHARACTER(256) :: fname

  INTEGER :: nvals, brbeg, brend, prbeg, prend, distrib, switch
  INTEGER :: n1, n2, ioff, ijbeg, ijend, errorflag
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend
  INTEGER :: lbound, nijk

  LOGICAL :: defined(nvals_max)

  REAL(RFREAL) :: vals(nvals_max)

  TYPE(t_patch), POINTER  :: patch
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ReadBcInflowVelSection',&
  'RFLO_ReadBcInflowVelSection.F90' )

! specify keywords and search for them ----------------------------------------

  keys(1) = 'TYPE'
  keys(2) = 'VELX'
  keys(3) = 'VELY'
  keys(4) = 'VELZ'
  IF (bctitle==bc_inflow_veltemp) THEN
    keys(5) = 'TEMP'
    keys(6) = 'PRESS'
  ELSEIF (bctitle==bc_inflow_velpress) THEN
    keys(5) = 'PRESS'
    keys(6) = 'TEMP'
  ELSE
    CALL errorstop( global,err_unknown_bc,&
    __line__ )
  ENDIF
  keys(7) = 'RECYCTURB'
  keys(8) = 'AMPLITUDE'

  nvals = nvals_max

  CALL readpatchsection( global,if_input,nvals,keys,vals,brbeg,brend, &
                         prbeg,prend,distrib,fname,defined )


! module consistency check ----------------------------------------------------

  IF (vals(7) > 0.1_rfreal) THEN
#ifdef STATS
    IF ((global%flowType == flow_unsteady) .AND. &
        (global%doStat == active) .AND. &
        (global%mixtNStat > 0)) THEN
    ELSE
      CALL errorstop( global,err_val_bcval,&
      __line__, &
                 'inflow bc parameter RECYCTURB > 0 inconsistent with STATS' )
    ENDIF
#else
    CALL errorstop( global,err_val_bcval,&
    __line__, &
                   'Activate STATS for inflow bc parameter RECYCTURB > 0' )
#endif
  ENDIF

! get switches & check if all necessary values defined ------------------------

  DO ireg=brbeg,brend
    DO ipatch=prbeg,min(prend,regions(ireg)%nPatches)

      patch => regions(ireg)%levels(1)%patches(ipatch)

      IF ((patch%bcType>=bc_inflow .AND. &
           patch%bcType<=bc_inflow+bc_range)    .AND. &   ! my boundary type,
          regions(ireg)%procid==global%myProcid .AND. &   ! region active and
          regions(ireg)%active==active) THEN              ! on my processor

        patch%bcType = bctitle

        IF (patch%mixt%bcSet .eqv. .true.) &
          CALL errorstop( global,err_patch_overspec,&
          __line__,'Inflow boundary.' )

        patch%mixt%nSwitches = 3
        IF (patch%bcCoupled == bc_external) THEN   ! data from outside
          patch%mixt%distrib = bcdat_distrib    ! => always distribution
        ELSE
          patch%mixt%distrib = distrib
        ENDIF

        ALLOCATE( patch%mixt%switches(patch%mixt%nSwitches), &
                  stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

! ----- check if switch defined
        IF (defined(1).eqv..true.) THEN
          patch%mixt%switches(bcswi_inflow_type)   = bcopt_subsonic
          IF (vals(1) < 0.1) &
            patch%mixt%switches(bcswi_inflow_type) = bcopt_supersonic
          IF (vals(1) > 1.9) &
            patch%mixt%switches(bcswi_inflow_type) = bcopt_mixed
        ELSE
          CALL errorstop( global,err_no_bcswitch,&
          __line__,'(inflow type).' )
        ENDIF

        patch%mixt%switches(bcswi_inflow_model) = bcopt_steady
        IF (defined(7).eqv..true.) THEN
          IF (vals(7) > 0.1) &
            patch%mixt%switches(bcswi_inflow_model) = bcopt_unsteady
        ENDIF

! ----- check if appropriate values specified
        IF (patch%mixt%switches(bcswi_inflow_type) == bcopt_subsonic) THEN
          IF (patch%mixt%distrib==bcdat_constant .AND. &
              (.NOT. (defined(2).eqv..true.) .OR. &
               .NOT. (defined(3).eqv..true.) .OR. &
               .NOT. (defined(4).eqv..true.) .OR. &
               .NOT. (defined(5).eqv..true.))) CALL errorstop( global,err_bcval_missing,&
               __line__ )
        ENDIF
        IF (patch%mixt%switches(bcswi_inflow_type) == bcopt_supersonic .OR. &
            patch%mixt%switches(bcswi_inflow_type) == bcopt_mixed) THEN
          IF (patch%mixt%distrib==bcdat_constant .AND. &
              (.NOT. (defined(2).eqv..true.) .OR. &
               .NOT. (defined(3).eqv..true.) .OR. &
               .NOT. (defined(4).eqv..true.) .OR. &
               .NOT. (defined(5).eqv..true.) .OR. &
               .NOT. (defined(6).eqv..true.))) CALL errorstop( global,err_bcval_missing,&
               __line__ )
        ENDIF
        IF (defined(7).eqv..true.) THEN
          IF (patch%mixt%switches(bcswi_inflow_model) == bcopt_unsteady) THEN
            IF (defined(8).eqv..true.) THEN
              patch%mixt%amplitude = abs( vals(8) )
            ELSE
              CALL errorstop( global,err_bcval_missing,&
              __line__, &
                           'AMPLITUDE should be specified in inflow with recycturb' )
            ENDIF
          ENDIF
        ENDIF

! ----- set flag to BC specified
        patch%mixt%bcSet = .true.

      ENDIF   ! my BC & processor, active
    ENDDO
  ENDDO

! copy values/distribution to variables ---------------------------------------

  DO ireg=brbeg,brend
    DO ipatch=prbeg,min(prend,regions(ireg)%nPatches)

      patch => regions(ireg)%levels(1)%patches(ipatch)

      IF ((patch%bcType>=bc_inflow .AND. &
           patch%bcType<=bc_inflow+bc_range)    .AND. &   ! my boundary type,
          regions(ireg)%procid==global%myProcid .AND. &   ! region active and
          regions(ireg)%active==active) THEN              ! on my processor

        switch = patch%mixt%switches(bcswi_inflow_type)
        IF (switch == bcopt_subsonic) THEN
! -----  BUGFIX - Didn't allocate enough for this BC (MTC)
          patch%mixt%nData = 5
        ELSE
          patch%mixt%nData = 5
        ENDIF

! ----- allocate memory for the values

        IF (patch%mixt%distrib == bcdat_distrib) THEN
          n1    = abs(patch%l1end-patch%l1beg)
          n2    = abs(patch%l2end-patch%l2beg)
          ioff  = n1 + 1
          ijbeg = indij( 0, 0,ioff)
          ijend = indij(n1,n2,ioff)
        ELSE
          ijbeg = 0
          ijend = 1
        ENDIF
        ALLOCATE( patch%mixt%vals(patch%mixt%nData,ijbeg:ijend), &
                  stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

! ----- distribution from file

        IF (patch%mixt%distrib==bcdat_distrib .AND. &
            patch%bcCoupled      /=bc_external  ) THEN
           WRITE(*,*) 'Reading more bc from file',fname
          CALL rflo_readbcfromfile( global,fname,patch )

! ----- distribution from external source / constant value

        ELSE

          patch%mixt%vals(bcdat_inflow_u,:) = vals(2)
          patch%mixt%vals(bcdat_inflow_v,:) = vals(3)
          patch%mixt%vals(bcdat_inflow_w,:) = vals(4)
          IF (bctitle==bc_inflow_veltemp) THEN
            patch%mixt%vals(bcdat_inflow_t,:) = vals(5)
            IF (defined(6).eqv..true.) THEN
               patch%mixt%vals(bcdat_inflow_p,:) = vals(6)
            ENDIF
          ELSEIF (bctitle==bc_inflow_velpress) THEN
            patch%mixt%vals(bcdat_inflow_p,:) = vals(5)
            IF (defined(6).eqv..true.) &
            patch%mixt%vals(bcdat_inflow_t,:) = vals(6)
          ENDIF
        ENDIF  ! distribution?

      ENDIF    ! bcType, active region on my processor

    ENDDO      ! iPatch
  ENDDO        ! iReg

! search for max ijk-index for turbulence recycling ---------------------------

  IF (vals(7) > 0.1_rfreal) THEN
    nijk = global%infloNijk
    DO ireg=brbeg,brend
      CALL rflo_getdimensphysnodes( regions(ireg),1,ipnbeg,ipnend, &
                                    jpnbeg,jpnend,kpnbeg,kpnend )
      DO ipatch=prbeg,min(prend,regions(ireg)%nPatches)

        patch => regions(ireg)%levels(1)%patches(ipatch)

        IF ((patch%bcType>=bc_inflow .AND. &
             patch%bcType<=bc_inflow+bc_range)    .AND. &   ! my boundary type,
            regions(ireg)%procid==global%myProcid .AND. &   ! region active and
            regions(ireg)%active==active) THEN              ! on my processor
          lbound = patch%lbound
          IF (lbound==1 .OR. lbound==2) THEN
            nijk = abs(ipnend-ipnbeg)+1
          ELSEIF (lbound==3 .OR. lbound==4) THEN 
            nijk = abs(jpnend-jpnbeg)+1
          ELSEIF (lbound==5 .OR. lbound==6) THEN 
            nijk = abs(kpnend-kpnbeg)+1
          ENDIF
        ENDIF  ! bcType
        global%infloNijk = min( global%infloNijk,nijk )
      ENDDO  ! iPatch
    ENDDO    ! iReg
    global%infloNijk = global%infloNijk/2+1
  ENDIF      ! recycTurb

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_readbcinflowvelsection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadBcInflowVelSection.F90,v $
! Revision 1.11  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2008/10/23 18:20:53  mtcampbe
! Crazy number of changes to track and fix initialization and
! restart bugs.  Many improperly formed logical expressions
! were fixed, and bug in allocation for data associated with
! the BC_INFLOWVELTEMP boundary condition squashed in
! RFLO_ReadBcInflowVelSection.F90.
!
! Revision 1.8  2006/08/19 15:38:12  mparmar
! Renamed patch variables
!
! Revision 1.7  2006/04/13 21:37:43  wasistho
! take half of global%infloNijk
!
! Revision 1.6  2006/02/18 08:26:33  wasistho
! fixed reading temperature and pressure
!
! Revision 1.5  2005/11/19 03:25:36  wasistho
! bug fixed errorstop reading amplitude
!
! Revision 1.4  2005/11/18 07:18:42  wasistho
! added parameter AMPLITUDE
!
! Revision 1.3  2005/09/20 23:56:57  wasistho
! modified computation of global%infloNijk
!
! Revision 1.2  2005/09/20 23:03:22  wasistho
! added user input RECYCTURB
!
! Revision 1.1  2005/04/28 05:48:28  wasistho
! added velocity based inflow BC
!
!
!******************************************************************************