RFLO_FindThrustPatches.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: search for all patches of a region to be used
!          for computing the thrust.
!
! Description: none.
!
! Input: region%levels%grid = dimensions, grid data, face vectors.
!
! Output: patch%thrustCalc = patch marked for thruct calculation (T/F).
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_FindThrustPatches.F90,v 1.4 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_findthrustpatches( region,iReg )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getcelloffset, rflo_getnodeoffset, &
                            rflo_getpatchindices, rflo_getpatchdirection
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER :: ireg

  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ipatch, i, j, k

! ... local variables
  INTEGER :: ilev, lbound, ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: plane, bctype, inoff, ijnoff, ijkn0, ijkn1

  LOGICAL :: found

  REAL(RFREAL), POINTER :: xyz(:,:)
  REAL(RFREAL) :: tol=1.0e-6

  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_FindThrustPatches',&
  'RFLO_FindThrustPatches.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  xyz   => region%levels(ilev)%grid%xyz
  plane =  global%thrustPlane

! thrust plane within region? use tolerance since plane will be at boundary ---

!  IF (global%thrustCoord<MINVAL(xyz(plane,:)) .OR. &
!      global%thrustCoord>MAXVAL(xyz(plane,:))) THEN
  IF (global%thrustCoord-minval(xyz(plane,:)) < -tol .OR. &
      global%thrustCoord-maxval(xyz(plane,:)) >  tol) THEN
    DO ipatch=1,region%nPatches
      region%levels(ilev)%patches(ipatch)%thrustCalc = .false.
    ENDDO
    goto 999
  ENDIF

! loop over patches -----------------------------------------------------------

  DO ipatch=1,region%nPatches

    patch => region%levels(ilev)%patches(ipatch)
    bctype = patch%bcType

    patch%thrustCalc = .false.

    IF ((bctype>=bc_outflow    .AND. bctype<=bc_outflow+   bc_range) .OR. &
        (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
        (bctype>=bc_regionint  .AND. bctype<=bc_regionint+ bc_range) .OR. &
        (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range)) THEN

! --- get dimensions of the patch

      lbound = patch%lbound

      CALL rflo_getpatchindicesnodes( region,patch,ilev,ibeg,iend, &
                                      jbeg,jend,kbeg,kend )
      CALL rflo_getpatchdirection( patch,idir,jdir,kdir )

! --- loop over all nodes of the patch

      found = .true.
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkn0 = indijk(i     ,j     ,k     ,inoff,ijnoff)
            ijkn1 = indijk(i+idir,j+jdir,k+kdir,inoff,ijnoff)
!            IF (MIN(xyz(plane,ijkN0),xyz(plane,ijkN1))>global%thrustCoord .OR.&
!                MAX(xyz(plane,ijkN0),xyz(plane,ijkN1))<global%thrustCoord) &
            IF (global%thrustCoord-min(xyz(plane,ijkn0),xyz(plane,ijkn1)) < -tol .OR.&
                global%thrustCoord-max(xyz(plane,ijkn0),xyz(plane,ijkn1)) >  tol) &
              found = .false.
          ENDDO
        ENDDO
      ENDDO
      IF (found) patch%thrustCalc = .true.

    ENDIF   ! bcType
    IF (global%verbLevel>=verbose_high .AND. patch%thrustCalc) &
      WRITE(stdout,'(A,I5,A,I3)') '   - region ',ireg,', patch ',ipatch

  ENDDO     ! iPatch

! finalize --------------------------------------------------------------------

999  CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE rflo_findthrustpatches

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_FindThrustPatches.F90,v $
! Revision 1.4  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2007/11/15 09:46:38  rfiedler
! Use a tolerance when checking whether nodes are on thrust plane.
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.5  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.1  2003/06/02 17:12:00  jblazek
! Added computation of thrust.
!
!******************************************************************************