RFLO_FindSourceCell.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: given the indices of a dummy cell, find the source region
!          and the source cell by transformation between patches.
!
! Description: none.
!
! Input: regions  = dimensions and topology of all regions
!        iReg     = current region
!        iLev     = current grid level
!        i/j/kc   = indices of the dummy cell
!
! Output: found   = flag if a source cell was found and is within the physical
!                   domain of the source region (true/false)
!         rotate  = rotational periodicity involved (true/false)
!         i/j/kc  = indices of the source cell
!         icell   = index of the source cell
!         iRegSrc = index of the source region
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_FindSourceCell.F90,v 1.3 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_findsourcecell( regions,iReg,iLev,ic,jc,kc,icell, &
                                found,rotate,iregsrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region, t_level
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getpatchindices, &
                            rflo_sourcecell
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  INTEGER :: ireg, ilev, ic, jc, kc, icell, iregsrc

  LOGICAL :: found, rotate

  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ilb, ipatch

! ... local variables
  LOGICAL :: hit, debug

  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend, ipatchsrc
  INTEGER :: bctype, lbound, ibeg, iend, jbeg, jend, kbeg, kend

  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch, patchsrc

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_FindSourceCell',&
  'RFLO_FindSourceCell.F90' )

  found = .false.

! get dimensions --------------------------------------------------------------

  CALL rflo_getdimensphys( regions(ireg),ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )

! find a suitable patch to start from -----------------------------------------

  hit = .false.     ! no patch found yet

! cell within the patch?

  DO ipatch=1,regions(ireg)%nPatches
    patch => regions(ireg)%levels(ilev)%patches(ipatch)
    bctype = patch%bcType
    lbound = patch%lbound
    IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
        (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
        (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
      CALL rflo_getpatchindices( regions(ireg),patch,ilev, &
                                 ibeg,iend,jbeg,jend,kbeg,kend )
      IF      ((lbound==1 .AND. ic<ipcbeg) .OR. &
               (lbound==2 .AND. ic>ipcend)) THEN
        IF ((jc>=jbeg .AND. jc<=jend) .AND. &
            (kc>=kbeg .AND. kc<=kend)) THEN
          hit = .true.
          EXIT
        ENDIF
      ELSE IF ((lbound==3 .AND. jc<jpcbeg) .OR. &
               (lbound==4 .AND. jc>jpcend)) THEN 
        IF ((ic>=ibeg .AND. ic<=iend) .AND. &
            (kc>=kbeg .AND. kc<=kend)) THEN
          hit = .true.
          EXIT
        ENDIF
      ELSE IF ((lbound==5 .AND. kc<kpcbeg) .OR. &
               (lbound==6 .AND. kc>kpcend)) THEN
        IF ((jc>=jbeg .AND. jc<=jend) .AND. &
            (ic>=ibeg .AND. ic<=iend)) THEN
          hit = .true.
          EXIT
        ENDIF
      ENDIF
    ENDIF  ! bcType
  ENDDO    ! iPatch

! cell just outside the patch?

  IF (.NOT. hit) THEN
    DO ipatch=1,regions(ireg)%nPatches
      patch => regions(ireg)%levels(ilev)%patches(ipatch)
      bctype = patch%bcType
      lbound = patch%lbound
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        CALL rflo_getpatchindices( regions(ireg),patch,ilev, &
                                   ibeg,iend,jbeg,jend,kbeg,kend )
        IF      ((lbound==1 .AND. ic<ipcbeg) .OR. &
                 (lbound==2 .AND. ic>ipcend)) THEN       ! face 1, 2
          IF (kc<kpcbeg .AND. kbeg==kpcbeg .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (kc>kpcend .AND. kend==kpcend .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (jc<jpcbeg .AND. jbeg==jpcbeg .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (jc>jpcend .AND. jend==jpcend .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF ((lbound==3 .AND. jc<jpcbeg) .OR. &
                 (lbound==4 .AND. jc>jpcend)) THEN       ! face 3, 4
          IF (kc<kpcbeg .AND. kbeg==kpcbeg .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (kc>kpcend .AND. kend==kpcend .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic<ipcbeg .AND. ibeg==ipcbeg .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic>ipcend .AND. iend==ipcend .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF ((lbound==5 .AND. kc<kpcbeg) .OR. &
                 (lbound==6 .AND. kc>kpcend)) THEN       ! face 5, 6
          IF (jc<jpcbeg .AND. jbeg==jpcbeg .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (jc>jpcend .AND. jend==jpcend .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic<ipcbeg .AND. ibeg==ipcbeg .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic>ipcend .AND. iend==ipcend .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ENDIF
      ENDIF  ! bcType
    ENDDO    ! iPatch
  ENDIF      ! .NOT. hit

! cell at some corner?

  IF (.NOT. hit) THEN
    DO ipatch=1,regions(ireg)%nPatches
      patch => regions(ireg)%levels(ilev)%patches(ipatch)
      bctype = patch%bcType
      lbound = patch%lbound
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        CALL rflo_getpatchindices( regions(ireg),patch,ilev, &
                                   ibeg,iend,jbeg,jend,kbeg,kend )
        IF      (ic<ipcbeg .AND. jc<jpcbeg .AND. kc<kpcbeg) THEN   ! corner 1
          IF ((lbound==1 .AND. jbeg==jpcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==3 .AND. ibeg==ipcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. ibeg==ipcbeg .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic<ipcbeg .AND. jc<jpcbeg .AND. kc>kpcend) THEN   ! corner 2
          IF ((lbound==1 .AND. jbeg==jpcbeg .AND. kend==kpcend) .OR. &
              (lbound==3 .AND. ibeg==ipcbeg .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. ibeg==ipcbeg .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic<ipcbeg .AND. jc>jpcend .AND. kc>kpcend) THEN   ! corner 3
          IF ((lbound==1 .AND. jend==jpcend .AND. kend==kpcend) .OR. &
              (lbound==4 .AND. ibeg==ipcbeg .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. ibeg==ipcbeg .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic<ipcbeg .AND. jc>jpcend .AND. kc<kpcbeg) THEN   ! corner 4
          IF ((lbound==1 .AND. jend==jpcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==4 .AND. ibeg==ipcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. ibeg==ipcbeg .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc<jpcbeg .AND. kc<kpcbeg) THEN   ! corner 5
          IF ((lbound==2 .AND. jbeg==jpcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==3 .AND. iend==ipcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. iend==ipcend .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc<jpcbeg .AND. kc>kpcend) THEN   ! corner 6
          IF ((lbound==2 .AND. jbeg==jpcbeg .AND. kend==kpcend) .OR. &
              (lbound==3 .AND. iend==ipcend .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. iend==ipcend .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc>jpcend .AND. kc>kpcend) THEN   ! corner 7
          IF ((lbound==2 .AND. jend==jpcend .AND. kend==kpcend) .OR. &
              (lbound==4 .AND. iend==ipcend .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. iend==ipcend .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc>jpcend .AND. kc<kpcbeg) THEN   ! corner 8
          IF ((lbound==2 .AND. jend==jpcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==4 .AND. iend==ipcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. iend==ipcend .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ENDIF
      ENDIF  ! bcType
    ENDDO    ! iPatch
  ENDIF      ! .NOT. hit

! if patch was found, do the transformation -----------------------------------

  IF (hit) THEN
    bctype    = patch%bcType
    iregsrc   = patch%srcRegion
    ipatchsrc = patch%srcPatch
    patchsrc => regions(iregsrc)%levels(ilev)%patches(ipatchsrc)
    CALL rflo_sourcecell( regions(ireg),regions(iregsrc),patch,patchsrc, &
                          ilev,ic,jc,kc,icell,found )
    IF (found) THEN
      IF (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range) THEN
        rotate = .true.
      ELSE
        rotate = .false.
      ENDIF
    ENDIF
  ELSE
    iregsrc = ireg
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_findsourcecell

! #############################################################################
! #############################################################################

SUBROUTINE rflo_sourcecell( region,regionSrc,patch,patchSrc, &
                            ilev,ic,jc,kc,icell,found )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modindexing, ONLY   : indijkmap, getijk
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getpatchmapping, rflo_getdimensphys
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  INTEGER :: ilev, ic, jc, kc, icell

  LOGICAL :: found

  TYPE(t_region)          :: region, regionsrc
  TYPE(t_patch), POINTER  :: patch, patchsrc

! ... local variables
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, icoffsrc, ijcoffsrc, ijkcsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend

  LOGICAL :: align

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_SourceCell',&
  'RFLO_FindSourceCell.F90' )

! get dimensions

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindices( regionsrc,patchsrc,ilev,ibegsrc,iendsrc, &
                             jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getcelloffset( regionsrc,ilev,icoffsrc,ijcoffsrc )

! mapping between patches

                                       l1srcdir =  1
  IF (patch%srcL1beg > patch%srcL1end) l1srcdir = -1
                                       l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) l2srcdir = -1

  lb    = patch%lbound
  lbs   = patch%srcLbound
  align = patch%align

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

  icell = indijkmap( ic,jc,kc,mapmat,icoffsrc,ijcoffsrc )
  CALL getijk( icell,icoffsrc,ijcoffsrc,regionsrc%nDumCells,ic,jc,kc )

! check if ic,jc,kc within physical domain

  CALL rflo_getdimensphys( regionsrc,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )

  IF ((ic>=ipcbeg .AND. ic<=ipcend) .AND. &
      (jc>=jpcbeg .AND. jc<=jpcend) .AND. &
      (kc>=kpcbeg .AND. kc<=kpcend)) THEN
    found = .true.
  ELSE
    found = .false.
  ENDIF

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE rflo_sourcecell

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_FindSourceCell.F90,v $
! Revision 1.3  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.2  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.1  2003/02/03 19:20:47  jblazek
! Added treatment of edge and corner cells for one processor.
!
!******************************************************************************