RFLO_ExchangeGeometryRecv.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receive geometry of dummy nodes from adjacent region on
!          another processor.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: region%levels(1)%grid%xyz = grid coordinates.
!
! Notes: operation carried out for the finest grid only. Intended for
!        conforming grid boundaries (also periodic) only. In the case
!        of rotationally periodic boundary, it is assumed that the
!        axis of rotation coincides with the x-axis.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeGeometryRecv.F90,v 1.4 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangegeometryrecv( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getnodeoffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: idum, i, j, k, ijkbuff

! ... local variables
#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: bctype, ibeg, iend, jbeg, jend, kbeg, kend, inoff, ijnoff, &
             ijkn, ijknb, ibnd, jbnd, kbnd, n1, n2, ndim, lb, source, tag

  REAL(RFREAL)          :: dx, dy, dz, cosa, sina
  REAL(RFREAL), POINTER :: xyz(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_ExchangeGeometryRecv',&
  'RFLO_ExchangeGeometryRecv.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  CALL rflo_getpatchindicesnodes( region,patch,1,ibeg,iend, &
                                  jbeg,jend,kbeg,kend )
  CALL rflo_getnodeoffset( region,1,inoff,ijnoff )

  xyz => region%levels(1)%grid%xyz

  n1   = abs(patch%l1end-patch%l1beg) + 2   ! here, dimensions of current
  n2   = abs(patch%l2end-patch%l2beg) + 2   ! and source patch are identical
  ndim = n1*n2*region%nDumCells             ! ... but not the # of dummy cells

! receive data

#ifdef MPI
  source = regionsrc%procid
  tag    = region%localNumber + mpi_patchoff*patchsrc%srcPatch
  CALL mpi_recv( patch%mixt%recvBuff,3*ndim,mpi_rfreal,source,tag, &
                 global%mpiComm,status,global%mpierr )
  IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! copy from buffer to dummy nodes ---------------------------------------------

  lb      = patch%lbound
  bctype  = patch%bcType
  ijkbuff = 0

  DO idum=1,region%nDumCells

! - face i=const.

    IF (lb==1 .OR. lb==2) THEN

      IF (lb == 1) THEN
        i    = ibeg - idum
        ibnd = ibeg
      ELSE IF (lb == 2) THEN
        i    = iend + idum
        ibnd = iend
      ENDIF

      IF (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) THEN
        DO k=kbeg,kend
          DO j=jbeg,jend
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            xyz(xcoord,ijkn) = patch%mixt%recvBuff(ijkbuff       )
            xyz(ycoord,ijkn) = patch%mixt%recvBuff(ijkbuff+  ndim)
            xyz(zcoord,ijkn) = patch%mixt%recvBuff(ijkbuff+2*ndim)
          ENDDO
        ENDDO
      ELSE IF (bctype>=bc_tra_peri .AND. bctype<=bc_tra_peri+bc_range) THEN
        DO k=kbeg,kend
          DO j=jbeg,jend
            ijkn    = indijk(i   ,j,k,inoff,ijnoff)
            ijknb   = indijk(ibnd,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            dx      = patch%mixt%recvBuff(ijkbuff       )
            dy      = patch%mixt%recvBuff(ijkbuff+  ndim)
            dz      = patch%mixt%recvBuff(ijkbuff+2*ndim)
            xyz(xcoord,ijkn) = xyz(xcoord,ijknb) + dx
            xyz(ycoord,ijkn) = xyz(ycoord,ijknb) + dy
            xyz(zcoord,ijkn) = xyz(zcoord,ijknb) + dz
          ENDDO
        ENDDO
      ELSE IF (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range) THEN
        cosa = cos(patch%periodAngle)
        sina = sin(patch%periodAngle)
        DO k=kbeg,kend
          DO j=jbeg,jend
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            dy      = patch%mixt%recvBuff(ijkbuff+  ndim)
            dz      = patch%mixt%recvBuff(ijkbuff+2*ndim)
            xyz(xcoord,ijkn) = patch%mixt%recvBuff(ijkbuff)
            xyz(ycoord,ijkn) = cosa*dy - sina*dz
            xyz(zcoord,ijkn) = sina*dy + cosa*dz
          ENDDO
        ENDDO
      ENDIF

! - face j=const.

    ELSE IF (lb==3 .OR. lb==4) THEN

      IF (lb == 3) THEN
        j    = jbeg - idum
        jbnd = jbeg
      ELSE IF (lb == 4) THEN
        j    = jend + idum
        jbnd = jend
      ENDIF

      IF (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) THEN
        DO i=ibeg,iend
          DO k=kbeg,kend
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            xyz(xcoord,ijkn) = patch%mixt%recvBuff(ijkbuff       )
            xyz(ycoord,ijkn) = patch%mixt%recvBuff(ijkbuff+  ndim)
            xyz(zcoord,ijkn) = patch%mixt%recvBuff(ijkbuff+2*ndim)
          ENDDO
        ENDDO
      ELSE IF (bctype>=bc_tra_peri .AND. bctype<=bc_tra_peri+bc_range) THEN
        DO i=ibeg,iend
          DO k=kbeg,kend
            ijkn    = indijk(i,j   ,k,inoff,ijnoff)
            ijknb   = indijk(i,jbnd,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            dx      = patch%mixt%recvBuff(ijkbuff       )
            dy      = patch%mixt%recvBuff(ijkbuff+  ndim)
            dz      = patch%mixt%recvBuff(ijkbuff+2*ndim)
            xyz(xcoord,ijkn) = xyz(xcoord,ijknb) + dx
            xyz(ycoord,ijkn) = xyz(ycoord,ijknb) + dy
            xyz(zcoord,ijkn) = xyz(zcoord,ijknb) + dz
          ENDDO
        ENDDO
      ELSE IF (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range) THEN
        cosa = cos(patch%periodAngle)
        sina = sin(patch%periodAngle)
        DO i=ibeg,iend
          DO k=kbeg,kend
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            dy      = patch%mixt%recvBuff(ijkbuff+  ndim)
            dz      = patch%mixt%recvBuff(ijkbuff+2*ndim)
            xyz(xcoord,ijkn) = patch%mixt%recvBuff(ijkbuff)
            xyz(ycoord,ijkn) = cosa*dy - sina*dz
            xyz(zcoord,ijkn) = sina*dy + cosa*dz
          ENDDO
        ENDDO
      ENDIF

! - face k=const.

    ELSE IF (lb==5 .OR. lb==6) THEN

      IF (lb == 5) THEN
        k    = kbeg - idum
        kbnd = kbeg
      ELSE IF (lb == 6) THEN
        k    = kend + idum
        kbnd = kend
      ENDIF

      IF (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) THEN
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            xyz(xcoord,ijkn) = patch%mixt%recvBuff(ijkbuff       )
            xyz(ycoord,ijkn) = patch%mixt%recvBuff(ijkbuff+  ndim)
            xyz(zcoord,ijkn) = patch%mixt%recvBuff(ijkbuff+2*ndim)
          ENDDO
        ENDDO
      ELSE IF (bctype>=bc_tra_peri .AND. bctype<=bc_tra_peri+bc_range) THEN
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkn    = indijk(i,j,k   ,inoff,ijnoff)
            ijknb   = indijk(i,j,kbnd,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            dx      = patch%mixt%recvBuff(ijkbuff       )
            dy      = patch%mixt%recvBuff(ijkbuff+  ndim)
            dz      = patch%mixt%recvBuff(ijkbuff+2*ndim)
            xyz(xcoord,ijkn) = xyz(xcoord,ijknb) + dx
            xyz(ycoord,ijkn) = xyz(ycoord,ijknb) + dy
            xyz(zcoord,ijkn) = xyz(zcoord,ijknb) + dz
          ENDDO
        ENDDO
      ELSE IF (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range) THEN
        cosa = cos(patch%periodAngle)
        sina = sin(patch%periodAngle)
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            dy      = patch%mixt%recvBuff(ijkbuff+  ndim)
            dz      = patch%mixt%recvBuff(ijkbuff+2*ndim)
            xyz(xcoord,ijkn) = patch%mixt%recvBuff(ijkbuff)
            xyz(ycoord,ijkn) = cosa*dy - sina*dz
            xyz(zcoord,ijkn) = sina*dy + cosa*dz
          ENDDO
        ENDDO
      ENDIF

    ENDIF   ! lb

  ENDDO     ! idum

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_exchangegeometryrecv

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeGeometryRecv.F90,v $
! Revision 1.4  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:39:37  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.13  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.9  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.8  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.7  2002/09/20 22:22:36  jblazek
! Finalized integration into GenX.
!
! Revision 1.6  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.5  2002/06/22 01:13:38  jblazek
! Modified interfaces to BC routines.
!
! Revision 1.4  2002/04/01 19:36:08  jblazek
! Added routine to clear send requests.
!
! Revision 1.3  2002/03/30 00:50:49  jblazek
! Cleaned up with flint.
!
! Revision 1.2  2002/03/29 23:15:22  jblazek
! Corrected bug in MPI send.
!
! Revision 1.1  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
!******************************************************************************