RFLO_ExchangeGeometryPrepare.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: exchange orientation of l1- and l2-directions between regions
!          on different processors.
!
! Description: none.
!
! Input: regions%levels%grid = coordinates (physical cells) and dimensions
!
! Output: regions%levels%patches%l1/2Vec = vectors in l1/2-direction.
!
! Notes: only region interfaces with continuous grid are treated here.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeGeometryPrepare.F90,v 1.4 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangegeometryprepare( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getnodeoffset, &
                            rflo_clearsendrequests
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch

! ... local variables
  INTEGER :: bctype, iregsrc, ipatchsrc, lb, dest, source, tag
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, inoff, ijnoff
#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif

  REAL(RFREAL) :: vec(6)
  REAL(RFREAL), POINTER :: xyz(:,:)

  TYPE(t_patch), POINTER  :: patch, patchsrc
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ExchangeGeometryPrepare',&
  'RFLO_ExchangeGeometryPrepare.F90' )

! send direction vectors ------------------------------------------------------

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor

! --- loop over patches (finest grid level)

      DO ipatch=1,regions(ireg)%nPatches
        patch  => regions(ireg)%levels(1)%patches(ipatch)
        bctype =  patch%bcType

! ----- conforming inter-region boundary, translational
!       and rotational periodicity

        IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
            (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
            (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
          iregsrc = patch%srcRegion
          IF (regions(iregsrc)%active == off) &
            CALL errorstop( global,err_srcregion_off,__line__ )

          IF (regions(iregsrc)%procid /= global%myProcid) THEN
            CALL rflo_getpatchindicesnodes( regions(ireg),patch,1,ibeg,iend, &
                                            jbeg,jend,kbeg,kend )
            CALL rflo_getnodeoffset( regions(ireg),1,inoff,ijnoff )
            lb  =  patch%lbound
            xyz => regions(ireg)%levels(1)%grid%xyz
            IF (lb==1 .OR. lb==2) THEN
              vec(1:3) = xyz(1:3,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                         xyz(1:3,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
              vec(4:6) = xyz(1:3,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                         xyz(1:3,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
            ELSE IF (lb==3 .OR. lb==4) THEN
              vec(1:3) = xyz(1:3,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                         xyz(1:3,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
              vec(4:6) = xyz(1:3,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                         xyz(1:3,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
            ELSE IF (lb==5 .OR. lb==6) THEN
              vec(1:3) = xyz(1:3,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                         xyz(1:3,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
              vec(4:6) = xyz(1:3,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                         xyz(1:3,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
            ENDIF
#ifdef MPI
            dest = regions(iregsrc)%procid
            tag  = regions(iregsrc)%localNumber + mpi_patchoff*patch%srcPatch
            CALL mpi_isend( vec,6,mpi_rfreal,dest,tag,global%mpiComm, &
                            global%requests(patch%mixt%iRequest), &
                            global%mpierr )
            IF (global%mpierr /= 0) &
              CALL errorstop( global,err_mpi_trouble,__line__ )
#endif
          ENDIF
        ENDIF  ! bcType
      ENDDO    ! iPatch

    ENDIF      ! region on this processor and active
  ENDDO        ! iReg

! receive direction vectors ---------------------------------------------------

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor

! --- loop over patches (finest grid level)

      DO ipatch=1,regions(ireg)%nPatches
        patch  => regions(ireg)%levels(1)%patches(ipatch)
        bctype =  patch%bcType

! ----- conforming inter-region boundary, translational
!       or rotational periodicity

        IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
            (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
            (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
          iregsrc   =  patch%srcRegion
          ipatchsrc =  patch%srcPatch
          patchsrc  => regions(iregsrc)%levels(1)%patches(ipatchsrc)

          IF (regions(iregsrc)%procid /= global%myProcid) THEN
#ifdef MPI
            source = regions(iregsrc)%procid
            tag    = regions(ireg)%localNumber + mpi_patchoff*patchsrc%srcPatch
            CALL mpi_recv( vec,6,mpi_rfreal,source,tag,global%mpiComm, &
                           status,global%mpierr )
            IF (global%mpierr /= 0) &
              CALL errorstop( global,err_mpi_trouble,__line__ )

            patch%l1VecSrc(1:3) = vec(1:3)
            patch%l2VecSrc(1:3) = vec(4:6)
#endif
          ENDIF
        ENDIF  ! bcType
      ENDDO    ! iPatch

    ENDIF      ! region on this processor and active
  ENDDO        ! iReg

! clear send requests ---------------------------------------------------------

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor
      CALL rflo_clearsendrequests( regions,ireg,.true. )
    ENDIF
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_exchangegeometryprepare

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeGeometryPrepare.F90,v $
! Revision 1.4  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:39:35  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.2  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.1  2002/12/06 22:32:12  jblazek
! Corrected bug for geometry exchange between minimal patches.
!
!******************************************************************************