RFLO_ExchangeGeometryLevels.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: coarsen dummy cells at patches associated with interblock
!          or periodic boundaries (where real geometry was copied to).
!
! Description: none.
!
! Input: region = current region
!        iPatch = current patch
!
! Output: region%levels%grid%xyz = geometry in dummy cells at coarse levels.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeGeometryLevels.F90,v 1.3 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangegeometrylevels( region,iPatch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getpatchdirection, &
                            rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

  INTEGER :: ipatch

! ... loop variables
  INTEGER :: idum, ilev, i, j, k, ii, jj, kk

! ... local variables
  INTEGER :: ibegf, iendf, jbegf, jendf, kbegf, kendf, idir, jdir, kdir, &
             inofffine, ijnofffine, ijkf
  INTEGER :: ibegc, iendc, jbegc, jendc, kbegc, kendc, &
             inoffcoarse, ijnoffcoarse, ijkc

  REAL(RFREAL), POINTER :: xyzfine(:,:), xyzcoarse(:,:)

  TYPE(t_patch), POINTER :: patchfine, patchcoarse

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_ExchangeGeometryLevels',&
  'RFLO_ExchangeGeometryLevels.F90' )

! loop over dummy nodes of current patch

  DO ilev=2,region%nGridLevels

    xyzfine     => region%levels(ilev-1)%grid%xyz
    xyzcoarse   => region%levels(ilev  )%grid%xyz
    patchfine   => region%levels(ilev-1)%patches(ipatch)
    patchcoarse => region%levels(ilev  )%patches(ipatch)

    CALL rflo_getpatchindicesnodes( region,patchfine  ,ilev-1,ibegf,iendf, &
                                    jbegf,jendf,kbegf,kendf )
    CALL rflo_getpatchindicesnodes( region,patchcoarse,ilev  ,ibegc,iendc, &
                                    jbegc,jendc,kbegc,kendc )
    CALL rflo_getpatchdirection( patchfine,idir,jdir,kdir )
    CALL rflo_getnodeoffset( region,ilev-1,inofffine  ,ijnofffine   )
    CALL rflo_getnodeoffset( region,ilev  ,inoffcoarse,ijnoffcoarse )

    DO idum=1,region%nDumCells
      DO k=kbegc,kendc
        kk = (k-kbegc)*(2-abs(kdir)) + kbegf
        DO j=jbegc,jendc
          jj = (j-jbegc)*(2-abs(jdir)) + jbegf
          DO i=ibegc,iendc
            ii   = (i-ibegc)*(2-abs(idir)) + ibegf
            ijkf = indijk(ii-idum*idir,jj-idum*jdir,kk-idum*kdir,inofffine ,ijnofffine )
            ijkc = indijk( i-idum*idir, j-idum*jdir, k-idum*kdir,inoffcoarse,ijnoffcoarse)

            xyzcoarse(xcoord,ijkc) = xyzfine(xcoord,ijkf)
            xyzcoarse(ycoord,ijkc) = xyzfine(ycoord,ijkf)
            xyzcoarse(zcoord,ijkc) = xyzfine(zcoord,ijkf)
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDDO        ! idum

  ENDDO          ! iLev

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_exchangegeometrylevels

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeGeometryLevels.F90,v $
! Revision 1.3  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.9  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.5  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.4  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.3  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.2  2002/06/22 01:13:38  jblazek
! Modified interfaces to BC routines.
!
! Revision 1.1  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
!******************************************************************************