RFLO_ExchangeGeometryCopy.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy geometry from a patch of the source region to dummy nodes
!          of the current region`s patch (both regions are on the same
!          processor).
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: region%levels(1)%grid%xyz = grid coordinates.
!
! Notes: operation carried out for the finest grid only. Intended for
!        conforming grid boundaries (also periodic) only. In the case
!        of rotationally periodic boundary, it is assumed that the
!        axis of rotation coincides with the x-axis.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeGeometryCopy.F90,v 1.3 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangegeometrycopy( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modindexing, ONLY   : indijkmap
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getpatchdirection, &
                            rflo_getnodeoffset, rflo_getpatchmapping
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: idum, i, j, k, ii, jj, kk

! ... local variables
  INTEGER :: bctype, ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, &
             inoff, ijnoff, ijkn, ijknb
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, inoffsrc, ijnoffsrc, ijknsrc, ijknbsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)

  LOGICAL :: align

  REAL(RFREAL)          :: dx, dy, dz, sina, cosa, v1(3), v2(3)
  REAL(RFREAL), POINTER :: xyz(:,:), xyzsrc(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_ExchangeGeometryCopy',&
  'RFLO_ExchangeGeometryCopy.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( region%global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  CALL rflo_getpatchindicesnodes( region,patch,1,ibeg,iend, &
                                  jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindicesnodes( regionsrc,patchsrc,1,ibegsrc,iendsrc, &
                                  jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getnodeoffset( region   ,1,inoff   ,ijnoff    )
  CALL rflo_getnodeoffset( regionsrc,1,inoffsrc,ijnoffsrc )

  xyz    => region%levels(1)%grid%xyz
  xyzsrc => regionsrc%levels(1)%grid%xyz

  lb     = patch%lbound
  lbs    = patch%srcLbound
  align  = patch%align
  bctype = patch%bcType

! mapping between patches

  l1srcdir = 1
  IF (patch%srcL1beg > patch%srcL1end) THEN
    l1srcdir = -1
  ELSE IF (patch%srcL1beg == patch%srcL1end) THEN
    IF (lbs==1 .OR. lbs==2) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jendsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==3 .OR. lbs==4) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jbegsrc,kendsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==5 .OR. lbs==6) THEN
      v1(:) = xyzsrc(:,indijk(iendsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ENDIF
    IF (lb==1 .OR. lb==2) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ENDIF
    IF (dot_product(v1,v2) < 0._rfreal) l1srcdir = -1
  ENDIF

  l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) THEN
    l2srcdir = -1
  ELSE IF (patch%srcL2beg == patch%srcL2end) THEN
    IF (lbs==1 .OR. lbs==2) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jbegsrc,kendsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==3 .OR. lbs==4) THEN
      v1(:) = xyzsrc(:,indijk(iendsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==5 .OR. lbs==6) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jendsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ENDIF
    IF (lb==1 .OR. lb==2) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ENDIF
    IF (dot_product(v1,v2) < 0._rfreal) l2srcdir = -1
  ENDIF

  ibegsrc = ibegsrc + idirsrc    ! shift by one node into the interior
  iendsrc = iendsrc + idirsrc    ! (otherwise would start at the boundary)
  jbegsrc = jbegsrc + jdirsrc
  jendsrc = jendsrc + jdirsrc
  kbegsrc = kbegsrc + kdirsrc
  kendsrc = kendsrc + kdirsrc

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

! loop over dummy nodes of current patch

  DO idum=1,region%nDumCells

! - inter-region boundary

    IF (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) THEN
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ii      = i - idum*idir
            jj      = j - idum*jdir
            kk      = k - idum*kdir
            ijkn    = indijk(ii,jj,kk,inoff,ijnoff)
            ijknsrc = indijkmap(ii,jj,kk,mapmat,inoffsrc,ijnoffsrc)
            xyz(xcoord,ijkn) = xyzsrc(xcoord,ijknsrc)
            xyz(ycoord,ijkn) = xyzsrc(ycoord,ijknsrc)
            xyz(zcoord,ijkn) = xyzsrc(zcoord,ijknsrc)
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k

! - translational periodicity

    ELSE IF (bctype>=bc_tra_peri .AND. bctype<=bc_tra_peri+bc_range) THEN
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ii       = i - idum*idir
            jj       = j - idum*jdir
            kk       = k - idum*kdir
            ijkn     = indijk(ii,jj,kk,inoff,ijnoff)
            ijknb    = indijk(i ,j ,k ,inoff,ijnoff)
            ijknsrc  = indijkmap(ii,jj,kk,mapmat,inoffsrc,ijnoffsrc)
            ijknbsrc = indijkmap(i ,j ,k ,mapmat,inoffsrc,ijnoffsrc)
            dx       = xyzsrc(xcoord,ijknsrc) - xyzsrc(xcoord,ijknbsrc)
            dy       = xyzsrc(ycoord,ijknsrc) - xyzsrc(ycoord,ijknbsrc)
            dz       = xyzsrc(zcoord,ijknsrc) - xyzsrc(zcoord,ijknbsrc)
            xyz(xcoord,ijkn) = xyz(xcoord,ijknb) + dx
            xyz(ycoord,ijkn) = xyz(ycoord,ijknb) + dy
            xyz(zcoord,ijkn) = xyz(zcoord,ijknb) + dz
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k

! - rotational periodicity (around x-axis)

    ELSE IF (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range) THEN
      cosa = cos(patch%periodAngle)
      sina = sin(patch%periodAngle)
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ii      = i - idum*idir
            jj      = j - idum*jdir
            kk      = k - idum*kdir
            ijkn    = indijk(ii,jj,kk,inoff,ijnoff)
            ijknsrc = indijkmap(ii,jj,kk,mapmat,inoffsrc,ijnoffsrc)
            xyz(xcoord,ijkn) = xyzsrc(xcoord,ijknsrc)
            xyz(ycoord,ijkn) = cosa*xyzsrc(ycoord,ijknsrc) - &
                               sina*xyzsrc(zcoord,ijknsrc)
            xyz(zcoord,ijkn) = sina*xyzsrc(ycoord,ijknsrc) + &
                               cosa*xyzsrc(zcoord,ijknsrc)
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDIF

  ENDDO   ! idum

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_exchangegeometrycopy

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeGeometryCopy.F90,v $
! Revision 1.3  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.11  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.7  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.6  2002/12/06 22:29:26  jblazek
! Corrected bug for geometry exchange between minimal patches.
!
! Revision 1.5  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.4  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.3  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
! Revision 1.2  2002/06/22 01:13:38  jblazek
! Modified interfaces to BC routines.
!
! Revision 1.1  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
!******************************************************************************