RFLO_ExchangeDummyConf.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: exchange values between interior and dummy cells of the
!          corresponding patches of the adjacent regions (both regions
!          are on the same processor).
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: regions%levels%mixt%cv = flow variables in dummy cells.
!
! Notes: intended for conforming grid boundaries only.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeDummyConf.F90,v 1.4 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangedummyconf( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modindexing, ONLY   : indijkmap
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getpatchmapping, mixtureproperties
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: idum, i, j, k, ii, jj, kk

! ... local variables
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, &
             icoff, ijcoff, ijkd, ilev, gasmodel
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, icoffsrc, ijcoffsrc, ijkcsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)

  LOGICAL :: align

  REAL(RFREAL), POINTER :: cv(:,:), cvsrc(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_ExchangeDummyConf',&
  'RFLO_ExchangeDummyConf.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( region%global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindices( regionsrc,patchsrc,ilev,ibegsrc,iendsrc, &
                             jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getcelloffset( region   ,ilev,icoff   ,ijcoff    )
  CALL rflo_getcelloffset( regionsrc,ilev,icoffsrc,ijcoffsrc )

  gasmodel = region%mixtInput%gasModel

  cv    => region%levels(ilev)%mixt%cv
  cvsrc => regionsrc%levels(ilev)%mixt%cv

! mapping between patches

                                       l1srcdir =  1
  IF (patch%srcL1beg > patch%srcL1end) l1srcdir = -1
                                       l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) l2srcdir = -1

  lb    = patch%lbound
  lbs   = patch%srcLbound
  align = patch%align

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

! loop over dummy nodes of current patch

  DO idum=1,region%nDumCells
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ii      = i - idum*idir
          jj      = j - idum*jdir
          kk      = k - idum*kdir
          ijkd    = indijk(ii,jj,kk,icoff,ijcoff)
          ijkcsrc = indijkmap(ii,jj,kk,mapmat,icoffsrc,ijcoffsrc)

          cv(cv_mixt_dens,ijkd) = cvsrc(cv_mixt_dens,ijkcsrc)
          cv(cv_mixt_xmom,ijkd) = cvsrc(cv_mixt_xmom,ijkcsrc)
          cv(cv_mixt_ymom,ijkd) = cvsrc(cv_mixt_ymom,ijkcsrc)
          cv(cv_mixt_zmom,ijkd) = cvsrc(cv_mixt_zmom,ijkcsrc)
          cv(cv_mixt_ener,ijkd) = cvsrc(cv_mixt_ener,ijkcsrc)

          IF (gasmodel == gas_model_tcperf) THEN
            CALL mixtureproperties( region,ijkd,ijkd,.false. )
          ELSE
            CALL mixtureproperties( region,ijkd,ijkd,.true.  )
          ENDIF
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k
  ENDDO        ! idum

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_exchangedummyconf

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeDummyConf.F90,v $
! Revision 1.4  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/10/31 21:09:36  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.12  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.8  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.7  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.6  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.5  2002/08/16 21:33:48  jblazek
! Changed interface to MixtureProperties.
!
! Revision 1.4  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.3  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.2  2002/01/31 20:56:30  jblazek
! Added basic boundary conditions.
!
! Revision 1.1  2002/01/28 23:55:22  jblazek
! Added flux computation (central scheme).
!
!******************************************************************************