RFLO_EdgeDeformationStraight.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate node displacements on straight edges whose points have
!          been moved by RFLO_EdgeDeformation (finest grid only).
!
! Description: points along an edge are shifted using 1-D linear transfinite
!              interpolation (TFI).
!
! Input: region     = grid dimensions
!        boundMoved = flag for boundaries of a region which have moved
!        boundFlat  = flag for boundaries of a region which are flat
!        arcLen12   = arclength between i=const. boundaries for each j, k
!        arcLen34   = arclength between j=const. boundaries for each k, i
!        arcLen56   = arclength between k=const. boundaries for each i, j
!        xyzOrig    = reference grid which TFI is based on
!        xyzOld     = grid from previous time step.
!
! Output: edgeMoved = flag if discretization at an edge was changed
!         dNode     = updated deformation at edges.
!
! Notes: variable dNode contains the whole 3-D field.
!
!******************************************************************************
!
! $Id: RFLO_EdgeDeformationStraight.F90,v 1.4 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_edgedeformationstraight( region,boundMoved,edgeStraight, &
                                   edgemoved,arclen12,arclen34,arclen56, &
                                   xyzorig,xyzold,dnode )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getnodeoffset, rflo_getdimensphysnodes, &
                            rflo_tfint1d
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  LOGICAL :: boundmoved(6), edgestraight(12), edgemoved(12)

  REAL(RFREAL), POINTER :: arclen12(:,:), arclen34(:,:), arclen56(:,:)
  REAL(RFREAL), POINTER :: dnode(:,:), xyzold(:,:), xyzorig(:,:)

  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: iedge, ind

! ... local variables
  INTEGER :: ilev, ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend, l1c, l2c
  INTEGER :: indbeg, indend, ijkn, ijkn1, ijknbeg, ijknend, inoff, ijnoff
  INTEGER :: switch(12,9)

  REAL(RFREAL) :: arclen, ds, s, dn(3), dnbeg(3), dnend(3)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_EdgeDeformationStraight',&
  'RFLO_EdgeDeformationStraight.F90')

! get dimensions --------------------------------------------------------------

  ilev = 1
  CALL rflo_getdimensphysnodes( region,ilev,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

! set edge switch -------------------------------------------------------------
! switch(:,1) = begins at boundary
! switch(:,2) = ends on boundary
! switch(:,3) = right boundary
! switch(:,4) = left boundary
! switch(:,5) = direction (from-to boundary)
! switch(:,6) = start index
! switch(:,7) = end index
! switch(:,8) = constant index in 1st direction
! switch(:,9) = constant index in 2nd direction

  switch( 1,:) = (/5, 6, 1, 3, 56, kpnbeg, kpnend, ipnbeg, jpnbeg/)
  switch( 2,:) = (/3, 4, 1, 6, 34, jpnbeg, jpnend, kpnend, ipnbeg/)
  switch( 3,:) = (/5, 6, 1, 4, 56, kpnbeg, kpnend, ipnbeg, jpnend/)
  switch( 4,:) = (/3, 4, 1, 5, 34, jpnbeg, jpnend, kpnbeg, ipnbeg/)
  switch( 5,:) = (/5, 6, 2, 3, 56, kpnbeg, kpnend, ipnend, jpnbeg/)
  switch( 6,:) = (/3, 4, 2, 6, 34, jpnbeg, jpnend, kpnend, ipnend/)
  switch( 7,:) = (/5, 6, 2, 4, 56, kpnbeg, kpnend, ipnend, jpnend/)
  switch( 8,:) = (/3, 4, 2, 5, 34, jpnbeg, jpnend, kpnbeg, ipnend/)
  switch( 9,:) = (/1, 2, 3, 5, 12, ipnbeg, ipnend, jpnbeg, kpnbeg/)
  switch(10,:) = (/1, 2, 3, 6, 12, ipnbeg, ipnend, jpnbeg, kpnend/)
  switch(11,:) = (/1, 2, 4, 5, 12, ipnbeg, ipnend, jpnend, kpnbeg/)
  switch(12,:) = (/1, 2, 4, 6, 12, ipnbeg, ipnend, jpnend, kpnend/)

! loop over all 12 edges ------------------------------------------------------

  DO iedge=1,12

    IF ((.NOT.boundmoved(switch(iedge,3))) .AND. &
        (.NOT.boundmoved(switch(iedge,4))) .AND. &
        (edgestraight(iedge) .EQV. .true.) .AND. &
        (edgemoved(   iedge) .EQV. .true.)) THEN

      ds     = 0._rfreal
      indbeg = switch(iedge,6)
      indend = switch(iedge,7)
      l1c    = switch(iedge,8)
      l2c    = switch(iedge,9)
      DO ind=indbeg+1,indend-1
        IF (switch(iedge,5) == 12) THEN
          ijkn     = indijk(ind   ,l1c,l2c,inoff,ijnoff)
          ijkn1    = indijk(ind-1 ,l1c,l2c,inoff,ijnoff)
          ijknbeg  = indijk(indbeg,l1c,l2c,inoff,ijnoff)
          ijknend  = indijk(indend,l1c,l2c,inoff,ijnoff)
          arclen   = arclen12(l1c,l2c)
          dnbeg(:) = dnode(:,ijknbeg) + xyzold(:,ijknbeg)
          dnend(:) = dnode(:,ijknend) + xyzold(:,ijknend)
        ELSE IF (switch(iedge,5) == 34) THEN
          ijkn     = indijk(l2c,ind   ,l1c,inoff,ijnoff)
          ijkn1    = indijk(l2c,ind-1 ,l1c,inoff,ijnoff)
          ijknbeg  = indijk(l2c,indbeg,l1c,inoff,ijnoff)
          ijknend  = indijk(l2c,indend,l1c,inoff,ijnoff)
          arclen   = arclen34(l1c,l2c)
          dnbeg(:) = dnode(:,ijknbeg) + xyzold(:,ijknbeg)
          dnend(:) = dnode(:,ijknend) + xyzold(:,ijknend)
        ELSE IF (switch(iedge,5) == 56) THEN
          ijkn     = indijk(l1c,l2c,ind   ,inoff,ijnoff)
          ijkn1    = indijk(l1c,l2c,ind-1 ,inoff,ijnoff)
          ijknbeg  = indijk(l1c,l2c,indbeg,inoff,ijnoff)
          ijknend  = indijk(l1c,l2c,indend,inoff,ijnoff)
          arclen   = arclen56(l1c,l2c)
          dnbeg(:) = dnode(:,ijknbeg) + xyzold(:,ijknbeg)
          dnend(:) = dnode(:,ijknend) + xyzold(:,ijknend)
        ENDIF
        ds = ds + sqrt((xyzorig(xcoord,ijkn)-xyzorig(xcoord,ijkn1))**2 + &
                       (xyzorig(ycoord,ijkn)-xyzorig(ycoord,ijkn1))**2 + &
                       (xyzorig(zcoord,ijkn)-xyzorig(zcoord,ijkn1))**2)
        s  = ds/arclen

        CALL rflo_tfint1d( s,dnbeg,dnend,dn )
        dnode(:,ijkn) = dn(:) - xyzold(:,ijkn)
      ENDDO   ! i

    ENDIF     ! boundMoved
  ENDDO       ! iEdge

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_edgedeformationstraight

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_EdgeDeformationStraight.F90,v $
! Revision 1.4  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/03/14 04:35:50  wasistho
! improved computation of straight edges
!
! Revision 1.1  2006/03/12 20:42:53  wasistho
! added RFLO_EdgeDeformationStraight
!
!
!******************************************************************************