RFLO_CorrectCornerEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: correct values in the corner and edge cells at noslip (viscous)
!          walls, symmetry boundaries, and non-burning injection boundaries.
!
! Description: none.
!
! Input: region = region dimensions, user input
!        patch  = current patch
!        bcType = type of boundary condition.
!
! Output: region%levels%mixt = flow variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_CorrectCornerEdgeCells.F90,v 1.5 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_correctcorneredgecells( region,patch,bcType )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, mixtureproperties, mixtperf_r_m, mixtperf_g_cpr, &
        mixtperf_d_prt, mixtperf_eo_dgpuvw, rflo_getdimensphys, &
        rflo_getdimensdummy, rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER        :: bctype
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: idum, i, j, k, n1, n2, iside

! ... local variables
  LOGICAL :: dodummy(4), movegrid

  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ibegp, iendp, jbegp, jendp, kbegp, kendp, idir, jdir, kdir
  INTEGER :: ibeg(4), iend(4), jbeg(4), jend(4), kbeg(4), kend(4), nsides
  INTEGER :: ilev, lbound, icoff, ijcoff, noff, distrib, bcopt
  INTEGER :: gasmodel, ijkc, ijkd, i2d, inoff, ijnoff, ijkn(4)
  INTEGER :: inode, jnode, knode

  REAL(RFREAL)          :: dt, mrate, sgn(3), dxn(4), dyn(4), dzn(4)
  REAL(RFREAL)          :: usurf, vsurf, wsurf
  REAL(RFREAL), POINTER :: cv(:,:), vals(:,:), xyz(:,:), xyzold(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CorrectCornerEdgeCells', &
                         'RFLO_CorrectCornerEdgeCells.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getpatchindices( region,patch,ilev, &
                             ibegp,iendp,jbegp,jendp,kbegp,kendp )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  noff      = abs(patch%l1end-patch%l1beg) + 1
  distrib   = patch%mixt%distrib
  gasmodel = region%mixtInput%gasModel
  movegrid  = region%mixtInput%moveGrid
  dt        = region%global%dtMin

  cv   => region%levels(ilev)%mixt%cv
  vals => patch%mixt%vals
  xyz  => region%levels(ilev)%grid%xyz
  IF (movegrid) xyzold => region%levels(ilev)%gridOld%xyz

! to take the correct surface coordinates

  inode = 0
  jnode = 0
  knode = 0
  IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
    inode = -idir
    jnode = -jdir
    knode = -kdir
  ENDIF

! set loop indices ------------------------------------------------------------

  dodummy(:) = .false.
  nsides     = 0

  IF      (lbound==1 .OR. lbound==2) THEN
    ibeg(:) = ibegp
    iend(:) = iendp
    IF (jbegp == jpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jdcbeg
      jend(nsides)    = jpcbeg - 1
      IF (kbegp == kpcbeg) THEN
        kbeg(nsides)  = kdcbeg
      ELSE
        kbeg(nsides)  = kbegp
      ENDIF
      IF (kendp == kpcend) THEN
        kend(nsides)  = kdcend
      ELSE
        kend(nsides)  = kendp
      ENDIF
    ENDIF
    IF (jendp == jpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jpcend + 1
      jend(nsides)    = jdcend
      IF (kbegp == kpcbeg) THEN
        kbeg(nsides)  = kdcbeg
      ELSE
        kbeg(nsides)  = kbegp
      ENDIF
      IF (kendp == kpcend) THEN
        kend(nsides)  = kdcend
      ELSE
        kend(nsides)  = kendp
      ENDIF
    ENDIF
    IF (kbegp == kpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jbegp
      jend(nsides)    = jendp
      kbeg(nsides)    = kdcbeg
      kend(nsides)    = kpcbeg - 1
    ENDIF
    IF (kendp == kpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jbegp
      jend(nsides)    = jendp
      kbeg(nsides)    = kpcend + 1
      kend(nsides)    = kdcend
    ENDIF

  ELSE IF (lbound==3 .OR. lbound==4) THEN
    jbeg(:) = jbegp
    jend(:) = jendp
    IF (kbegp == kpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kdcbeg
      kend(nsides)    = kpcbeg - 1
      IF (ibegp == ipcbeg) THEN
        ibeg(nsides)  = idcbeg
      ELSE
        ibeg(nsides)  = ibegp
      ENDIF
      IF (iendp == ipcend) THEN
        iend(nsides)  = idcend
      ELSE
        iend(nsides)  = iendp
      ENDIF
    ENDIF
    IF (kendp == kpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kpcend + 1
      kend(nsides)    = kdcend
      IF (ibegp == ipcbeg) THEN
        ibeg(nsides)  = idcbeg
      ELSE
        ibeg(nsides)  = ibegp
      ENDIF
      IF (iendp == ipcend) THEN
        iend(nsides)  = idcend
      ELSE
        iend(nsides)  = iendp
      ENDIF
    ENDIF
    IF (ibegp == ipcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kbegp
      kend(nsides)    = kendp
      ibeg(nsides)    = idcbeg
      iend(nsides)    = ipcbeg - 1
    ENDIF
    IF (iendp == ipcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kbegp
      kend(nsides)    = kendp
      ibeg(nsides)    = ipcend + 1
      iend(nsides)    = idcend
    ENDIF

  ELSE IF (lbound==5 .OR. lbound==6) THEN
    kbeg(:) = kbegp
    kend(:) = kendp
    IF (ibegp == ipcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = idcbeg
      iend(nsides)    = ipcbeg - 1
      IF (jbegp == jpcbeg) THEN
        jbeg(nsides)  = jdcbeg
      ELSE
        jbeg(nsides)  = jbegp
      ENDIF
      IF (jendp == jpcend) THEN
        jend(nsides)  = jdcend
      ELSE
        jend(nsides)  = jendp
      ENDIF
    ENDIF
    IF (iendp == ipcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = ipcend + 1
      iend(nsides)    = idcend
      IF (jbegp == jpcbeg) THEN
        jbeg(nsides)  = jdcbeg
      ELSE
        jbeg(nsides)  = jbegp
      ENDIF
      IF (jendp == jpcend) THEN
        jend(nsides)  = jdcend
      ELSE
        jend(nsides)  = jendp
      ENDIF
    ENDIF
    IF (jbegp == jpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = ibegp
      iend(nsides)    = iendp
      jbeg(nsides)    = jdcbeg
      jend(nsides)    = jpcbeg - 1
    ENDIF
    IF (jendp == jpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = ibegp
      iend(nsides)    = iendp
      jbeg(nsides)    = jpcend + 1
      jend(nsides)    = jdcend
    ENDIF
  ENDIF

! settings to mirror velocity components (symmetry) ---------------------------

  IF      (lbound==1 .OR. lbound==2) THEN
    sgn(1) = -1._rfreal
    sgn(2) = +1._rfreal
    sgn(3) = +1._rfreal
  ELSE IF (lbound==3 .OR. lbound==4) THEN
    sgn(1) = +1._rfreal
    sgn(2) = -1._rfreal
    sgn(3) = +1._rfreal
  ELSE IF (lbound==5 .OR. lbound==6) THEN
    sgn(1) = +1._rfreal
    sgn(2) = +1._rfreal
    sgn(3) = -1._rfreal
  ENDIF

! loop over all cells of a patch ----------------------------------------------

  DO iside=1,nsides
    IF (dodummy(iside)) THEN

      DO idum=1,region%nDumCells
        DO k=kbeg(iside),kend(iside)
          DO j=jbeg(iside),jend(iside)
            DO i=ibeg(iside),iend(iside)
              ijkd = indijk(i-idum*idir,j-idum*jdir,k-idum*kdir,icoff,ijcoff)
              ijkc = indijk(i+(idum-1)*idir,j+(idum-1)*jdir,k+(idum-1)*kdir,icoff,ijcoff)

! ----------- noslip wall

              IF (bctype>=bc_noslipwall .AND. &
                  bctype<=bc_noslipwall+bc_range) THEN
                IF (movegrid) THEN
                  ijkn(1) = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
                  IF      (lbound==1 .OR. lbound==2) THEN
                    ijkn(2) = indijk(i+inode,j+jnode+1,k+knode  ,inoff,ijnoff)
                    ijkn(3) = indijk(i+inode,j+jnode+1,k+knode+1,inoff,ijnoff)
                    ijkn(4) = indijk(i+inode,j+jnode  ,k+knode+1,inoff,ijnoff)
                  ELSE IF (lbound==3 .OR. lbound==4) THEN
                    ijkn(2) = indijk(i+inode  ,j+jnode,k+knode+1,inoff,ijnoff)
                    ijkn(3) = indijk(i+inode+1,j+jnode,k+knode+1,inoff,ijnoff)
                    ijkn(4) = indijk(i+inode+1,j+jnode,k+knode  ,inoff,ijnoff)
                  ELSE IF (lbound==5 .OR. lbound==6) THEN
                    ijkn(2) = indijk(i+inode+1,j+jnode  ,k+knode,inoff,ijnoff)
                    ijkn(3) = indijk(i+inode+1,j+jnode+1,k+knode,inoff,ijnoff)
                    ijkn(4) = indijk(i+inode  ,j+jnode+1,k+knode,inoff,ijnoff)
                  ENDIF
                  dxn(1) = xyz(xcoord,ijkn(1)) - xyzold(xcoord,ijkn(1))
                  dyn(1) = xyz(ycoord,ijkn(1)) - xyzold(ycoord,ijkn(1))
                  dzn(1) = xyz(zcoord,ijkn(1)) - xyzold(zcoord,ijkn(1))
                  dxn(2) = xyz(xcoord,ijkn(2)) - xyzold(xcoord,ijkn(2))
                  dyn(2) = xyz(ycoord,ijkn(2)) - xyzold(ycoord,ijkn(2))
                  dzn(2) = xyz(zcoord,ijkn(2)) - xyzold(zcoord,ijkn(2))
                  dxn(3) = xyz(xcoord,ijkn(3)) - xyzold(xcoord,ijkn(3))
                  dyn(3) = xyz(ycoord,ijkn(3)) - xyzold(ycoord,ijkn(3))
                  dzn(3) = xyz(zcoord,ijkn(3)) - xyzold(zcoord,ijkn(3))
                  dxn(4) = xyz(xcoord,ijkn(4)) - xyzold(xcoord,ijkn(4))
                  dyn(4) = xyz(ycoord,ijkn(4)) - xyzold(ycoord,ijkn(4))
                  dzn(4) = xyz(zcoord,ijkn(4)) - xyzold(zcoord,ijkn(4))
                  usurf  = 0.25_rfreal*(dxn(1)+dxn(2)+dxn(3)+dxn(4))/dt
                  vsurf  = 0.25_rfreal*(dyn(1)+dyn(2)+dyn(3)+dyn(4))/dt
                  wsurf  = 0.25_rfreal*(dzn(1)+dzn(2)+dzn(3)+dzn(4))/dt
                ELSE
                  usurf = 0._rfreal
                  vsurf = 0._rfreal
                  wsurf = 0._rfreal
                ENDIF
                cv(cv_mixt_dens,ijkd) = cv(cv_mixt_dens,ijkc)
                cv(cv_mixt_xmom,ijkd) = 2._rfreal*usurf - cv(cv_mixt_xmom,ijkc)
                cv(cv_mixt_ymom,ijkd) = 2._rfreal*vsurf - cv(cv_mixt_ymom,ijkc)
                cv(cv_mixt_zmom,ijkd) = 2._rfreal*wsurf - cv(cv_mixt_zmom,ijkc)
                cv(cv_mixt_ener,ijkd) = cv(cv_mixt_ener,ijkc)

! ----------- symmetry boundary

              ELSE IF (bctype>=bc_symmetry .AND. &
                       bctype<=bc_symmetry+bc_range) THEN
                cv(cv_mixt_dens,ijkd) =        cv(cv_mixt_dens,ijkc)
                cv(cv_mixt_xmom,ijkd) = sgn(1)*cv(cv_mixt_xmom,ijkc)
                cv(cv_mixt_ymom,ijkd) = sgn(2)*cv(cv_mixt_ymom,ijkc)
                cv(cv_mixt_zmom,ijkd) = sgn(3)*cv(cv_mixt_zmom,ijkc)
                cv(cv_mixt_ener,ijkd) =        cv(cv_mixt_ener,ijkc)

! ----------- non-burning injection boundary (like noslip wall)

              ELSE IF (bctype>=bc_injection .AND. &
                       bctype<=bc_injection+bc_range) THEN
                IF      (lbound==1 .OR. lbound==2) THEN
                  n1 = max(min(j,jendp),jbegp) - jbegp
                  n2 = max(min(k,kendp),kbegp) - kbegp
                ELSE IF (lbound==3 .OR. lbound==4) THEN
                  n1 = max(min(k,kendp),kbegp) - kbegp
                  n2 = max(min(i,iendp),ibegp) - ibegp
                ELSE IF (lbound==5 .OR. lbound==6) THEN
                  n1 = max(min(i,iendp),ibegp) - ibegp
                  n2 = max(min(j,jendp),jbegp) - jbegp
                ENDIF
                i2d   = distrib * indij(n1,n2,noff)
                mrate = vals(bcdat_inject_mfrate,i2d)
                IF (mrate <= 0._rfreal) THEN
                  cv(cv_mixt_dens,ijkd) =  cv(cv_mixt_dens,ijkc)
                  cv(cv_mixt_xmom,ijkd) = -cv(cv_mixt_xmom,ijkc)
                  cv(cv_mixt_ymom,ijkd) = -cv(cv_mixt_ymom,ijkc)
                  cv(cv_mixt_zmom,ijkd) = -cv(cv_mixt_zmom,ijkc)
                  cv(cv_mixt_ener,ijkd) =  cv(cv_mixt_ener,ijkc)
                ENDIF
              ENDIF

              IF (gasmodel == gas_model_tcperf) THEN
                CALL mixtureproperties( region,ijkd,ijkd,.false. )
              ELSE
                CALL mixtureproperties( region,ijkd,ijkd,.true.  )
              ENDIF

            ENDDO  ! i
          ENDDO    ! j
        ENDDO      ! k
      ENDDO        ! idum

    ENDIF  ! doDummy
  ENDDO    ! iside

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_correctcorneredgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CorrectCornerEdgeCells.F90,v $
! Revision 1.5  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/08/19 15:39:33  mparmar
! Renamed patch variables
!
! Revision 1.2  2005/10/31 21:09:36  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.2  2003/10/01 23:52:10  jblazek
! Corrected bug in moving noslip wall BC and grid speeds.
!
! Revision 1.1  2003/05/20 20:46:57  jblazek
! Values in edge & corner cells now corrected at noslip and symmetry walls.
!
!******************************************************************************