RFLO_ComputeIntegralValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute integrals for GENx checking.
!
! Description: None.
!
! Input:
!   regions     Region data
!
! Output:
!   integ       Vector of integrals (for output by Rocman)
!
! Notes: None.
!
!******************************************************************************
!
! $Id: RFLO_ComputeIntegralValues.F90,v 1.4 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

#ifdef GENX
SUBROUTINE rflo_computeintegralvalues(regions,integ)
#else
SUBROUTINE rflo_computeintegralvalues(regions)
#endif

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset
  USE moderror
  USE modparameters
  USE modmpi
  
  IMPLICIT NONE
#include "Indexing.h"

#ifdef GENX
  include 'rocmanf90.h'
#endif

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k

! ... local variables
  INTEGER :: ilev, ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: icoff, ijcoff, ijkc

  REAL(RFREAL) :: enerlocal,ibarealocal,inbarealocal,masslocal,xmomlocal, & 
                  ymomlocal,zmomlocal,vollocal
#ifdef GENX
  DOUBLE PRECISION, DIMENSION(MAN_INTEG_SIZE) :: integ
  REAL(RFREAL), DIMENSION(MAN_INTEG_SIZE) :: globalvals,localvals
#else
  REAL(RFREAL), DIMENSION(2) :: globalvals,localvals
#endif
  REAL(RFREAL), POINTER :: cv(:,:), vol(:)

  TYPE(t_global), POINTER :: global

! *****************************************************************************

  global => regions(1)%global

  CALL registerfunction(global,'RFLO_ComputeIntegralValues',&
  'RFLO_ComputeIntegralValues.F90')

! get dimensions and pointers -------------------------------------------------

! Compute total volume and total mass -----------------------------------------

  vollocal  = 0.0_rfreal
  masslocal = 0.0_rfreal

  DO ireg = 1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active) THEN             ! on my processor

      ilev = regions(ireg)%currLevel

      CALL rflo_getdimensphys( regions(ireg),ilev,ipcbeg,ipcend, &
                               jpcbeg,jpcend,kpcbeg,kpcend )
      CALL rflo_getcelloffset( regions(ireg),ilev,icoff,ijcoff )

      cv  => regions(ireg)%levels(ilev)%mixt%cv
      vol => regions(ireg)%levels(ilev)%grid%vol
    
! --- loop over cells ---------------------------------------------------------

      DO k=kpcbeg,kpcend
        DO j=jpcbeg,jpcend
          DO i=ipcbeg,ipcend
            ijkc = indijk(i,j,k,icoff,ijcoff)
            vollocal  = vollocal + vol(ijkc)
            masslocal = masslocal + cv(cv_mixt_dens,ijkc)*vol(ijkc)
          ENDDO
        ENDDO
      ENDDO
    ENDIF
  ENDDO ! iReg

#ifdef GENX
! Compute momenta components and energy ---------------------------------------

  xmomlocal = 0.0_rfreal ! Not computed at present
  ymomlocal = 0.0_rfreal
  zmomlocal = 0.0_rfreal
  enerlocal = 0.0_rfreal 

! Compute interacting surface areas -------------------------------------------

  inbarealocal = 0.0_rfreal ! Not computed at present 
  ibarealocal  = 0.0_rfreal
#endif 

! *****************************************************************************
! Gather data
! *****************************************************************************

#ifdef GENX
  localvals(man_integ_vol    ) = vollocal
  localvals(man_integ_mass   ) = masslocal
  localvals(man_integ_xmom   ) = xmomlocal
  localvals(man_integ_ymom   ) = ymomlocal
  localvals(man_integ_zmom   ) = zmomlocal
  localvals(man_integ_ener   ) = enerlocal
  localvals(man_integ_ibarea ) = ibarealocal  
  localvals(man_integ_inbarea) = inbarealocal      
#else
  localvals(1) = vollocal
  localvals(2) = masslocal  
#endif

! Perform reduction operation -------------------------------------------------

#ifdef MPI
  CALL mpi_allreduce( localvals,globalvals,SIZE(localvals),mpi_rfreal,mpi_sum,&
                      global%mpiComm,global%mpierr )
  IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#else
  DO i = 1,SIZE(localvals)
    globalvals(i) = localvals(i)
  END DO ! i
#endif   

! Assign data -----------------------------------------------------------------

#ifdef GENX
  DO i = 1,man_integ_size
    integ(i) = globalvals(i)
  END DO ! i
#else
  global%totalVol  = globalvals(1)
  global%totalMass = globalvals(2)  
#endif

! Finalize --------------------------------------------------------------------

  CALL deregisterfunction(global)

END SUBROUTINE rflo_computeintegralvalues

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ComputeIntegralValues.F90,v $
! Revision 1.4  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:21  haselbac
! Removed tabs
!
! Revision 1.1  2005/02/26 04:07:17  wasistho
! added RFLO_ComputeIntegralValues
!
!
!******************************************************************************