RFLO_CentralFlux.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute central convective fluxes by average of variables.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%mixt%rhs = convective fluxes added to the residual.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_CentralFlux.F90,v 1.3 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_centralflux( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset, &
        rflo_getnodeoffset, rflo_centralfluxpatch
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ipatch

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc0, ijkc1, ijkn, indsvel

  REAL(RFREAL)          :: rhoa, rhoua, rhova, rhowa, rhoea, pa, vcont, fc(5)
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), rhs(:,:), si(:,:), sj(:,:), sk(:,:)
  REAL(RFREAL), POINTER :: aci(:,:), acj(:,:), ack(:,:)
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CentralFlux',&
  'RFLO_CentralFlux.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  cv     => region%levels(ilev)%mixt%cv
  dv     => region%levels(ilev)%mixt%dv
  rhs    => region%levels(ilev)%mixt%rhs
  aci    => region%levels(ilev)%grid%c2fCoI
  acj    => region%levels(ilev)%grid%c2fCoJ
  ack    => region%levels(ilev)%grid%c2fCoK
  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

! flux in i-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg+1,ipcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        rhoa  = aci(2,ijkn)*cv(cv_mixt_dens,ijkc0)+ &
                aci(1,ijkn)*cv(cv_mixt_dens,ijkc1)
        rhoua = aci(2,ijkn)*cv(cv_mixt_xmom,ijkc0)+ &
                aci(1,ijkn)*cv(cv_mixt_xmom,ijkc1)
        rhova = aci(2,ijkn)*cv(cv_mixt_ymom,ijkc0)+ &
                aci(1,ijkn)*cv(cv_mixt_ymom,ijkc1)
        rhowa = aci(2,ijkn)*cv(cv_mixt_zmom,ijkc0)+ &
                aci(1,ijkn)*cv(cv_mixt_zmom,ijkc1)
        rhoea = aci(2,ijkn)*cv(cv_mixt_ener,ijkc0)+ &
                aci(1,ijkn)*cv(cv_mixt_ener,ijkc1)
        pa    = aci(2,ijkn)*dv(dv_mixt_pres,ijkc0)+ &
                aci(1,ijkn)*dv(dv_mixt_pres,ijkc1)
        vcont = (rhoua*si(xcoord,ijkn)+rhova*si(ycoord,ijkn)+&
                 rhowa*si(zcoord,ijkn))/rhoa - sivel(ijkn*indsvel)

        fc(1) = vcont*rhoa
        fc(2) = vcont*rhoua + pa*si(xcoord,ijkn)
        fc(3) = vcont*rhova + pa*si(ycoord,ijkn)
        fc(4) = vcont*rhowa + pa*si(zcoord,ijkn)
        fc(5) = vcont*(rhoea+pa) + sivel(ijkn*indsvel)*pa

        rhs(cv_mixt_dens,ijkc0) = rhs(cv_mixt_dens,ijkc0) + fc(1)
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + fc(2)
        rhs(cv_mixt_ymom,ijkc0) = rhs(cv_mixt_ymom,ijkc0) + fc(3)
        rhs(cv_mixt_zmom,ijkc0) = rhs(cv_mixt_zmom,ijkc0) + fc(4)
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + fc(5)

        rhs(cv_mixt_dens,ijkc1) = rhs(cv_mixt_dens,ijkc1) - fc(1)
        rhs(cv_mixt_xmom,ijkc1) = rhs(cv_mixt_xmom,ijkc1) - fc(2)
        rhs(cv_mixt_ymom,ijkc1) = rhs(cv_mixt_ymom,ijkc1) - fc(3)
        rhs(cv_mixt_zmom,ijkc1) = rhs(cv_mixt_zmom,ijkc1) - fc(4)
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) - fc(5)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in j-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg+1,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        rhoa  = acj(2,ijkn)*cv(cv_mixt_dens,ijkc0)+ &
                acj(1,ijkn)*cv(cv_mixt_dens,ijkc1)
        rhoua = acj(2,ijkn)*cv(cv_mixt_xmom,ijkc0)+ &
                acj(1,ijkn)*cv(cv_mixt_xmom,ijkc1)
        rhova = acj(2,ijkn)*cv(cv_mixt_ymom,ijkc0)+ &
                acj(1,ijkn)*cv(cv_mixt_ymom,ijkc1)
        rhowa = acj(2,ijkn)*cv(cv_mixt_zmom,ijkc0)+ &
                acj(1,ijkn)*cv(cv_mixt_zmom,ijkc1)
        rhoea = acj(2,ijkn)*cv(cv_mixt_ener,ijkc0)+ &
                acj(1,ijkn)*cv(cv_mixt_ener,ijkc1)
        pa    = acj(2,ijkn)*dv(dv_mixt_pres,ijkc0)+ &
                acj(1,ijkn)*dv(dv_mixt_pres,ijkc1)
        vcont = (rhoua*sj(xcoord,ijkn)+rhova*sj(ycoord,ijkn)+&
                 rhowa*sj(zcoord,ijkn))/rhoa - sjvel(ijkn*indsvel)

        fc(1) = vcont*rhoa
        fc(2) = vcont*rhoua + pa*sj(xcoord,ijkn)
        fc(3) = vcont*rhova + pa*sj(ycoord,ijkn)
        fc(4) = vcont*rhowa + pa*sj(zcoord,ijkn)
        fc(5) = vcont*(rhoea+pa) + sjvel(ijkn*indsvel)*pa

        rhs(cv_mixt_dens,ijkc0) = rhs(cv_mixt_dens,ijkc0) + fc(1)
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + fc(2)
        rhs(cv_mixt_ymom,ijkc0) = rhs(cv_mixt_ymom,ijkc0) + fc(3)
        rhs(cv_mixt_zmom,ijkc0) = rhs(cv_mixt_zmom,ijkc0) + fc(4)
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + fc(5)

        rhs(cv_mixt_dens,ijkc1) = rhs(cv_mixt_dens,ijkc1) - fc(1)
        rhs(cv_mixt_xmom,ijkc1) = rhs(cv_mixt_xmom,ijkc1) - fc(2)
        rhs(cv_mixt_ymom,ijkc1) = rhs(cv_mixt_ymom,ijkc1) - fc(3)
        rhs(cv_mixt_zmom,ijkc1) = rhs(cv_mixt_zmom,ijkc1) - fc(4)
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) - fc(5)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in k-direction (except through boundary) -------------------------------

  DO k=kpcbeg+1,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        rhoa  = ack(2,ijkn)*cv(cv_mixt_dens,ijkc0)+ &
                ack(1,ijkn)*cv(cv_mixt_dens,ijkc1)
        rhoua = ack(2,ijkn)*cv(cv_mixt_xmom,ijkc0)+ &
                ack(1,ijkn)*cv(cv_mixt_xmom,ijkc1)
        rhova = ack(2,ijkn)*cv(cv_mixt_ymom,ijkc0)+ &
                ack(1,ijkn)*cv(cv_mixt_ymom,ijkc1)
        rhowa = ack(2,ijkn)*cv(cv_mixt_zmom,ijkc0)+ &
                ack(1,ijkn)*cv(cv_mixt_zmom,ijkc1)
        rhoea = ack(2,ijkn)*cv(cv_mixt_ener,ijkc0)+ &
                ack(1,ijkn)*cv(cv_mixt_ener,ijkc1)
        pa    = ack(2,ijkn)*dv(dv_mixt_pres,ijkc0)+ &
                ack(1,ijkn)*dv(dv_mixt_pres,ijkc1)
        vcont = (rhoua*sk(xcoord,ijkn)+rhova*sk(ycoord,ijkn)+&
                 rhowa*sk(zcoord,ijkn))/rhoa - skvel(ijkn*indsvel)

        fc(1) = vcont*rhoa
        fc(2) = vcont*rhoua + pa*sk(xcoord,ijkn)
        fc(3) = vcont*rhova + pa*sk(ycoord,ijkn)
        fc(4) = vcont*rhowa + pa*sk(zcoord,ijkn)
        fc(5) = vcont*(rhoea+pa) + skvel(ijkn*indsvel)*pa

        rhs(cv_mixt_dens,ijkc0) = rhs(cv_mixt_dens,ijkc0) + fc(1)
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + fc(2)
        rhs(cv_mixt_ymom,ijkc0) = rhs(cv_mixt_ymom,ijkc0) + fc(3)
        rhs(cv_mixt_zmom,ijkc0) = rhs(cv_mixt_zmom,ijkc0) + fc(4)
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + fc(5)

        rhs(cv_mixt_dens,ijkc1) = rhs(cv_mixt_dens,ijkc1) - fc(1)
        rhs(cv_mixt_xmom,ijkc1) = rhs(cv_mixt_xmom,ijkc1) - fc(2)
        rhs(cv_mixt_ymom,ijkc1) = rhs(cv_mixt_ymom,ijkc1) - fc(3)
        rhs(cv_mixt_zmom,ijkc1) = rhs(cv_mixt_zmom,ijkc1) - fc(4)
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) - fc(5)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fluxes through boundaries ---------------------------------------------------

  DO ipatch=1,region%nPatches
    CALL rflo_centralfluxpatch( region,region%levels(ilev)%patches(ipatch) )
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_centralflux

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CentralFlux.F90,v $
! Revision 1.3  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.14  2004/08/02 21:56:23  wasistho
! replaced cell2face midpoint by linear averaging
!
! Revision 1.13  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.9  2003/10/01 23:52:10  jblazek
! Corrected bug in moving noslip wall BC and grid speeds.
!
! Revision 1.8  2003/05/15 02:57:03  jblazek
! Inlined index function.
!
! Revision 1.7  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.6  2002/08/30 18:25:55  jblazek
! Forgot to multiply grid speeds by face area ...
!
! Revision 1.5  2002/08/29 23:25:54  jblazek
! Added support for moving grids.
!
! Revision 1.4  2002/03/18 23:11:32  jblazek
! Finished multiblock and MPI.
!
! Revision 1.3  2002/02/21 23:25:05  jblazek
! Blocks renamed as regions.
!
! Revision 1.2  2002/01/28 23:55:22  jblazek
! Added flux computation (central scheme).
!
! Revision 1.1  2002/01/23 03:51:25  jblazek
! Added low-level time-stepping routines.
!
!******************************************************************************