RFLO_CalcThrust.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate amount of thrust for a region.
!
! Description: none.
!
! Input: region%levels%mixt        = flow variables
!        region%levels%grid%si/j/k = face vectors (at boundaries)
!
! Output: global%thrustTotal = thrust
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_CalcThrust.F90,v 1.3 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calcthrust( region )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getcelloffset, rflo_getnodeoffset, &
                            rflo_getpatchindices, rflo_getpatchdirection
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ipatch, i, j, k

! ... local variables
  INTEGER :: ilev, lbound, ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: icoff, ijcoff, inoff, ijnoff, ijkc, ijkn
  INTEGER :: inode, jnode, knode

  REAL(RFREAL)          :: sgn, thrustmom, thrustpress, rhoua, rhova, rhowa, &
                           ua, va, wa, ds
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), sface(:,:)

  TYPE(t_patch), POINTER :: patch

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcThrust',&
  'RFLO_CalcThrust.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  cv => region%levels(ilev)%mixt%cv
  dv => region%levels(ilev)%mixt%dv

  thrustmom   = region%global%thrustMom
  thrustpress = region%global%thrustPress

! loop over patches -----------------------------------------------------------

  DO ipatch=1,region%nPatches

    patch => region%levels(ilev)%patches(ipatch)

    IF (patch%thrustCalc) THEN

! --- get dimensions of the patch

      lbound = patch%lbound

      CALL rflo_getpatchindices( region,patch,ilev, &
                                 ibeg,iend,jbeg,jend,kbeg,kend )
      CALL rflo_getpatchdirection( patch,idir,jdir,kdir )

! --- to take the right face vector and make it point outwards

      sgn   = +1._rfreal
      inode = 0
      jnode = 0
      knode = 0
      IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
        sgn   = -1._rfreal
        inode = -idir
        jnode = -jdir
        knode = -kdir
      ENDIF

! --- get the appropriate face vector

      IF (lbound==1 .OR. lbound==2) sface => region%levels(ilev)%grid%si
      IF (lbound==3 .OR. lbound==4) sface => region%levels(ilev)%grid%sj
      IF (lbound==5 .OR. lbound==6) sface => region%levels(ilev)%grid%sk

! --- loop over all cells of the patch

      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkc   = indijk(i,j,k,icoff,ijcoff)
            ijkn   = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
            rhoua  = cv(cv_mixt_xmom,ijkc)
            rhova  = cv(cv_mixt_ymom,ijkc)
            rhowa  = cv(cv_mixt_zmom,ijkc)
            ua     = dv(dv_mixt_uvel,ijkc)
            va     = dv(dv_mixt_vvel,ijkc)
            wa     = dv(dv_mixt_wvel,ijkc)
            thrustmom = sgn*sface(xcoord,ijkn)*rhoua*ua + &
                        sgn*sface(ycoord,ijkn)*rhova*va + &
                        sgn*sface(zcoord,ijkn)*rhowa*wa + thrustmom
            IF (region%global%thrustType == thrust_momp) THEN
              ds = sqrt(sface(xcoord,ijkn)*sface(xcoord,ijkn)+ &
                        sface(ycoord,ijkn)*sface(ycoord,ijkn)+ &
                        sface(zcoord,ijkn)*sface(zcoord,ijkn))
              thrustpress = (dv(dv_mixt_pres,ijkc)- &
                             region%global%thrustPamb)*ds + thrustpress
            ENDIF
          ENDDO
        ENDDO
      ENDDO

    ENDIF   ! thrustCalc

  ENDDO     ! iPatch

! finalize --------------------------------------------------------------------

  region%global%thrustMom   = thrustmom
  region%global%thrustPress = thrustpress

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_calcthrust

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CalcThrust.F90,v $
! Revision 1.3  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.5  2003/11/20 16:40:37  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.1  2003/06/02 17:12:00  jblazek
! Added computation of thrust.
!
!******************************************************************************