RFLO_CalcGradPhysBc.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update of gradients at the current patch if physical 
!          boundary conditions apply
!
! Description: gradients at physical boundaries computed using half interior 
!              side of control volume; resulting gradients computation from 
!              RFLO_calcGradFaces corrected by taking face averaging
!              at physical boundary for linearly extrapolated variables or
!              multiplicating by two for constantly extrapolated variables
!
! Input: region        = data of current region.
!        patch         = current patch.
!        iBegV, iEndV  = begin and end var index
!        iBegG, iEndG  = begin and end gradient index
!        var           = variables, the gradient of which to be determined.
!  
! Output: gradi, gradj, gradk = gradients at the patch faces subject to 
!                               physical boundary conditions
!
! Notes: two other subroutines contained in this file:
!          RFLO_FinishGradPatchLinear for linearly extrapolated dummy variables
!          RFLO_FinishGradPatchConstant for constantly extrapolated dummy
!
!******************************************************************************
!
! $Id: RFLO_CalcGradPhysBc.F90,v 1.4 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calcgradphysbc( region,patch,iBegV,iEndV,iBegG,iEndG,var, &
                                gradi,gradj,gradk )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices,rflo_getpatchdirection, &
        rflo_getcelloffset,rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch
  INTEGER        :: ibegv, iendv, ibegg, iendg
  REAL(RFREAL), POINTER :: var(:,:), gradi(:,:), gradj(:,:), gradk(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, lx, ly, lz

! ... local variables
  INTEGER :: ilev, lbound, bctype
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: inode, jnode, knode, idir, jdir, kdir
  INTEGER :: icoff, ijcoff, inoff, ijnoff, ijkn, ijkn1, ijkc, ijkc1
  INTEGER :: nvar
  INTEGER :: iextrap_slipw,iextrap_inject

  REAL(RFREAL)          :: sgn, fnx, fny, fnz, avol, rvol, avar(ibegv:iendv)
  REAL(RFREAL)          :: snx, sny, snz, rsurf
  REAL(RFREAL)          :: sdotgrad(ibegv:iendv)
  REAL(RFREAL), POINTER :: sface(:,:), grad(:,:), vol(:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcGradPhysBc',&
  'RFLO_CalcGradPhysBc.F90' )

! get dimensions and pointers-------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound
  bctype = patch%bcType

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  nvar = iendv - ibegv + 1

  vol => region%levels(ilev)%grid%vol

! take the right face vector and make it point outwards ----------------------

  sgn   = +1._rfreal
  inode = 0
  jnode = 0
  knode = 0
  IF( lbound==2 .OR. lbound==4 .OR. lbound==6 ) THEN
    sgn   = -1._rfreal
    inode = -idir
    jnode = -jdir
    knode = -kdir
  ENDIF

  IF (lbound==1 .OR. lbound==2) THEN
    sface => region%levels(ilev)%grid%si
    grad  => gradi
  ELSE IF (lbound==3 .OR. lbound==4) THEN
    sface => region%levels(ilev)%grid%sj
    grad  => gradj
  ELSE IF (lbound==5 .OR. lbound==6) THEN
    sface => region%levels(ilev)%grid%sk
    grad  => gradk
  ENDIF

  IF (bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range) &
     iextrap_slipw  = patch%mixt%switches(bcswi_slipw_extrap)
  IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) &
     iextrap_inject = patch%mixt%switches(bcswi_inject_extrap)

  IF ((bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range &
                           .AND. iextrap_slipw==extrapol_linear) .OR. &
      (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) .OR. &
      (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range &
                            .AND. iextrap_inject==extrapol_linear) .OR. &
      (bctype>=bc_inflow .AND. bctype<=bc_inflow+bc_range) .OR. &
      (bctype>=bc_outflow .AND. bctype<=bc_outflow+bc_range) .OR. &
      (bctype>=bc_farfield .AND. bctype<=bc_farfield+bc_range)) THEN

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          CALL rflo_finishgradpatchlinear
        ENDDO
      ENDDO
    ENDDO

  ELSE IF((bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range &
                               .AND. iextrap_slipw==extrapol_const ) .OR. &
          (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range &
                                .AND. iextrap_inject==extrapol_const )) THEN

    CALL rflo_finishgradpatchconstant

  ELSE IF (bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range) THEN

! remove the portion normal to the bndry patch --------------------------------
! surface vectors pointed inwards/negative
! 2D loop over patch faces

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          CALL rflo_finishgradpatchlinear

          ijkn  = indijk(i+inode, j+jnode, k+knode, inoff,ijnoff)  ! bnd nodes
          rsurf = sface(xcoord,ijkn)**2+sface(ycoord,ijkn)**2+sface(zcoord,ijkn)**2
          rsurf = 1.0_rfreal/rsurf
          snx   = sface(xcoord,ijkn)*rsurf
          sny   = sface(ycoord,ijkn)*rsurf
          snz   = sface(zcoord,ijkn)*rsurf

          DO l=ibegv,iendv
            lx=l+ibegg-ibegv 
            ly=lx+nvar
            lz=ly+nvar

            sdotgrad(l) = sface(xcoord,ijkn)*grad(lx,ijkn)+ &
                          sface(ycoord,ijkn)*grad(ly,ijkn)+ &
                          sface(zcoord,ijkn)*grad(lz,ijkn)

            grad(lx,ijkn) = grad(lx,ijkn)-sdotgrad(l)*snx
            grad(ly,ijkn) = grad(ly,ijkn)-sdotgrad(l)*sny
            grad(lz,ijkn) = grad(lz,ijkn)-sdotgrad(l)*snz
          ENDDO

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  ELSE IF (bctype>=bc_regionint .AND. bctype<=bc_regionint+bc_range) THEN

  ELSE IF (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) THEN

! everything else 

  ELSE

  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

! ==============================================================================
! two patch gradient completion subroutines for linear and constant extrap. case
! ==============================================================================

CONTAINS

  SUBROUTINE rflo_finishgradpatchlinear

! correct gradients at boundary whose dummy variables are linearly extrapolated

      ijkc  = indijk(i        ,j        ,k        ,icoff,ijcoff)
      ijkc1 = indijk(i-idir   ,j-jdir   ,k-kdir   ,icoff,ijcoff)
      ijkn  = indijk(i+inode  ,j+jnode  ,k+knode  ,inoff,ijnoff)
      ijkn1 = indijk(i+inode-idir,j+jnode-jdir,k+knode-kdir,inoff,ijnoff)

      fnx =  .5_rfreal*(sface(xcoord,ijkn)+sface(xcoord,ijkn1))
      fny =  .5_rfreal*(sface(ycoord,ijkn)+sface(ycoord,ijkn1))
      fnz =  .5_rfreal*(sface(zcoord,ijkn)+sface(zcoord,ijkn1))
      avol=  .5_rfreal*(vol(ijkc)+vol(ijkc1))
      rvol= 2.0_rfreal/avol  ! - for the devision by half control volume    

      DO l=ibegv,iendv
        lx=l+ibegg-ibegv 
        ly=lx+nvar
        lz=ly+nvar

! - cancel existing patch contribution for front patches (lbound=1,3,5)

        grad(lx,ijkn)=grad(lx,ijkn)*avol-sgn*fnx*var(l,ijkc1)
        grad(ly,ijkn)=grad(ly,ijkn)*avol-sgn*fny*var(l,ijkc1)
        grad(lz,ijkn)=grad(lz,ijkn)*avol-sgn*fnz*var(l,ijkc1)

! - set correct patch contribution 
!   avg.coeffs. are not explicitly used as they are always 0.5 at linear patch

        avar(l)=.5_rfreal*(var(l,ijkc)+var(l,ijkc1))
        grad(lx,ijkn)=grad(lx,ijkn)+sgn*fnx*avar(l)
        grad(ly,ijkn)=grad(ly,ijkn)+sgn*fny*avar(l)
        grad(lz,ijkn)=grad(lz,ijkn)+sgn*fnz*avar(l)

! - division by half control volume

        grad(lx,ijkn)=grad(lx,ijkn)*rvol
        grad(ly,ijkn)=grad(ly,ijkn)*rvol
        grad(lz,ijkn)=grad(lz,ijkn)*rvol
      ENDDO

  END SUBROUTINE rflo_finishgradpatchlinear

! ##############################################################################

  SUBROUTINE rflo_finishgradpatchconstant

! correct gradients at boundary whose dummy variables are constantly extrapolated
! account for half control volume by multiplication by 2

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          ijkn  = indijk(i+inode  ,j+jnode  ,k+knode  ,inoff,ijnoff)

          DO l=ibegv,iendv
            lx=l+ibegg-ibegv 
            ly=lx+nvar
            lz=ly+nvar

            grad(lx,ijkn) = 2.0_rfreal*grad(lx,ijkn)
            grad(ly,ijkn) = 2.0_rfreal*grad(ly,ijkn)
            grad(lz,ijkn) = 2.0_rfreal*grad(lz,ijkn)
          ENDDO

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SUBROUTINE rflo_finishgradpatchconstant

END SUBROUTINE rflo_calcgradphysbc

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CalcGradPhysBc.F90,v $
! Revision 1.4  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:37:57  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.9  2004/08/03 22:48:50  wasistho
! changed cell2edge averaging to grid dependent avg
!
! Revision 1.8  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.5  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.4  2002/10/15 15:37:59  wasistho
! slipw and injection extrapolation switch
!
! Revision 1.3  2002/09/27 00:57:09  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/09/02 22:58:54  wasistho
! RFLO grad routines migrated from rocflo to libflo
!
! Revision 1.3  2002/07/22 22:59:11  jblazek
! Some more clean up.
!
! Revision 1.2  2002/07/19 23:44:24  wasistho
! made compliant with CODING RULE
!
!******************************************************************************