RFLO_CalcFaceCentroids.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate face centroids (optionally).
!
! Description: none.
!
! Input: region%levels%grid = dimensions, coordinates (current region)
!
! Output: region%levels%grid%cfcI,J,K = i,j,k-face centroids
!
!
!******************************************************************************
!
! $Id: RFLO_CalcFaceCentroids.F90,v 1.4 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calcfacecentroids( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ilev, i, j, k, l

! ... local variables
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: inoff, ijnoff
  INTEGER, PARAMETER :: idir=1, jdir=2, kdir=3

  REAL(RFREAL), POINTER :: xyz(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcFaceCentroids',&
       'RFLO_CalcFaceCentroids.F90' )

! loop over all grid levels

  DO ilev=1,region%nGridLevels

    IF (region%global%calcFaceCtr) THEN
      CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                     jdnbeg,jdnend,kdnbeg,kdnend )
      CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

      xyz  => region%levels(ilev)%grid%xyz

! --- compute i, j, k-face centroids

      CALL computefacectr( idir )
      CALL computefacectr( jdir )
      CALL computefacectr( kdir )

    ENDIF  ! calcFaceCtr
  ENDDO    ! iLev

! finalize

  CALL deregisterfunction( region%global )

! =============================================================================
!   Face centroids computation subroutine
! =============================================================================

CONTAINS

  SUBROUTINE computefacectr( ijk )

! ... parameters
    INTEGER   :: ijk 

! ... local variables
    INTEGER   :: ibeg,iend,jbeg,jend,kbeg,kend
    INTEGER   :: i2,i3,i4,j2,j3,j4,k2,k3,k4
    INTEGER   :: corner(4)
    REAL(RFREAL), POINTER :: facectr(:,:)

! - Set limits and pointers ---------------------------------------------------
    IF (ijk==idir) THEN
      ibeg = idnbeg
      iend = idnend
      jbeg = jdnbeg
      jend = jdnend-1
      kbeg = kdnbeg
      kend = kdnend-1
      i2   = 0
      i3   = 0
      i4   = 0
      j2   = 0
      j3   = 1
      j4   = 1
      k2   = 1
      k3   = 1
      k4   = 0
      facectr => region%levels(ilev)%grid%cfcI
    ELSEIF (ijk==jdir) THEN
      ibeg = idnbeg
      iend = idnend-1
      jbeg = jdnbeg
      jend = jdnend
      kbeg = kdnbeg
      kend = kdnend-1
      i2   = 0
      i3   = 1
      i4   = 1
      j2   = 0
      j3   = 0
      j4   = 0
      k2   = 1
      k3   = 1
      k4   = 0
      facectr => region%levels(ilev)%grid%cfcJ
    ELSEIF (ijk==kdir) THEN
      ibeg = idnbeg
      iend = idnend-1
      jbeg = jdnbeg
      jend = jdnend-1
      kbeg = kdnbeg
      kend = kdnend
      i2   = 0
      i3   = 1
      i4   = 1
      j2   = 1
      j3   = 1
      j4   = 0
      k2   = 0
      k3   = 0
      k4   = 0
      facectr => region%levels(ilev)%grid%cfcK
    ENDIF

! - define face centroids

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          corner(1) = indijk(i    ,j    ,k    ,inoff,ijnoff)
          corner(2) = indijk(i+i2 ,j+j2 ,k+k2 ,inoff,ijnoff)
          corner(3) = indijk(i+i3 ,j+j3 ,k+k3 ,inoff,ijnoff)
          corner(4) = indijk(i+i4 ,j+j4 ,k+k4 ,inoff,ijnoff)
         
          DO l=1,3
            facectr(l,corner(1)) = 0.25_rfreal*(xyz(l,corner(1))+ &
                                                xyz(l,corner(2))+ &
                                                xyz(l,corner(3))+ &
                                                xyz(l,corner(4)))
          ENDDO         
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

    IF (ijk==idir) THEN

      DO j=jdnbeg,jdnend-1
        DO i=idnbeg,idnend
          corner(1) = indijk(i    ,j    ,kdnend  ,inoff,ijnoff)
          corner(2) = indijk(i    ,j    ,kdnend-1,inoff,ijnoff)
          DO l=1,3
            facectr(l,corner(1)) = facectr(l,corner(2))
          ENDDO
        ENDDO
      ENDDO
      DO k=kdnbeg,kdnend
        DO i=idnbeg,idnend
          corner(1) = indijk(i    ,jdnend  ,k    ,inoff,ijnoff)
          corner(2) = indijk(i    ,jdnend-1,k    ,inoff,ijnoff)
          DO l=1,3
            facectr(l,corner(1)) = facectr(l,corner(2))
          ENDDO
        ENDDO
      ENDDO

    ELSEIF (ijk==jdir) THEN

      DO k=kdnbeg,kdnend-1
        DO j=jdnbeg,jdnend
          corner(1) = indijk(idnend  ,j    ,k    ,inoff,ijnoff)
          corner(2) = indijk(idnend-1,j    ,k    ,inoff,ijnoff)
          DO l=1,3
            facectr(l,corner(1)) = facectr(l,corner(2))
          ENDDO
        ENDDO
      ENDDO
      DO j=jdnbeg,jdnend
        DO i=idnbeg,idnend
          corner(1) = indijk(i    ,j     ,kdnend  ,inoff,ijnoff)
          corner(2) = indijk(i    ,j     ,kdnend-1,inoff,ijnoff)
          DO l=1,3
            facectr(l,corner(1)) = facectr(l,corner(2))
          ENDDO
        ENDDO
      ENDDO

    ELSEIF (ijk==kdir) THEN

      DO k=kdnbeg,kdnend
        DO j=jdnbeg,jdnend-1
          corner(1) = indijk(idnend  ,j    ,k    ,inoff,ijnoff)
          corner(2) = indijk(idnend-1,j    ,k    ,inoff,ijnoff)
          DO l=1,3
            facectr(l,corner(1)) = facectr(l,corner(2))
          ENDDO
        ENDDO
      ENDDO
      DO k=kdnbeg,kdnend
        DO i=idnbeg,idnend
          corner(1) = indijk(i    ,jdnend  ,k    ,inoff,ijnoff)
          corner(2) = indijk(i    ,jdnend-1,k    ,inoff,ijnoff)
          DO l=1,3
            facectr(l,corner(1)) = facectr(l,corner(2))
          ENDDO
        ENDDO
      ENDDO

    ENDIF   ! ijk

  END SUBROUTINE computefacectr

END SUBROUTINE rflo_calcfacecentroids

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CalcFaceCentroids.F90,v $
! Revision 1.4  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:19  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/01/12 09:47:02  wasistho
! extrapolate to idnend, jdnend, kdnend
!
! Revision 1.1  2005/10/20 06:57:44  wasistho
! initial import RFLO_CalcFaceCentroids
!
!
!******************************************************************************