RFLO_C2fAvgCoeffsDummyConn.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Extrapolate coefficient from the interior domain or at the patch 
!          to the dummy points at connecting boundaries.
!
! Description: Dummy values of connecting bnd has been computed in prev. step 
!              up to second outerst layer. They are copied to the
!              outerst layer in this routine.
!
! Input: region   = current region data
!        lbound   = patch boundary ID
!        i,j,kdir = direction identifier
!        i,j,kndBeg = i,j,k begin index
!        i,j,kndEnd = i,j,k end index
!  
! Output: Averaging coefficients c2fCoI, c2fCoJ, c2fCoK at outerst layer of
!         conn. bc.
!
! Notes: Mother routine = RFLO_C2fAvgCoeffsDummy.
!
!******************************************************************************
!
! $Id: RFLO_C2fAvgCoeffsDummyConn.F90,v 1.3 2008/12/06 08:44:25 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_c2favgcoeffsdummyconn( region,lbound,idir,jdir,kdir, &
                                 indbeg,indend,jndbeg,jndend,kndbeg,kndend )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: lbound,idir,jdir,kdir
  INTEGER        :: indbeg, indend, jndbeg, jndend, kndbeg, kndend

! ... loop variables
  INTEGER :: i, j, k, idum, jdum, kdum

! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: ilev, inoff, ijnoff
  INTEGER :: ijkni, ijknj, ijknk, ijknd
  INTEGER :: ig(3), jg(3), kg(3)
  INTEGER :: idumb(3), jdumb(3), kdumb(3), idume(3), jdume(3), kdume(3)

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'RFLO_C2fAvgCoeffsDummyConn',&
  'RFLO_C2fAvgCoeffsDummyConn.F90' )

! get dimensions -------------------------------------------------------------

  ilev = region%currLevel
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  idumb(:) = -idir*region%nDumCells
  jdumb(:) = -jdir*region%nDumCells
  kdumb(:) = -kdir*region%nDumCells
  idume(:) = idumb(:)
  jdume(:) = jdumb(:)
  kdume(:) = kdumb(:)

  ig(:) = -idir*(region%nDumCells-1)
  jg(:) = -jdir*(region%nDumCells-1)
  kg(:) = -kdir*(region%nDumCells-1)

! 2D loop over patch nodes ----------------------------------------------------

  DO k=kndbeg,kndend
    DO j=jndbeg,jndend
      DO i=indbeg,indend

        ijkni = indijk(i+ig(1),j+jg(1),k+kg(1),inoff,ijnoff)  ! i reference
        ijknj = indijk(i+ig(2),j+jg(2),k+kg(2),inoff,ijnoff)  ! j reference
        ijknk = indijk(i+ig(3),j+jg(3),k+kg(3),inoff,ijnoff)  ! k reference

! ----- 1D loop in direction normal to patch to define grads at dummy faces

        DO idum=idumb(1),idume(1)
          DO jdum=jdumb(1),jdume(1)
            DO kdum=kdumb(1),kdume(1) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)
              region%levels(ilev)%grid%c2fCoI(2,ijknd) = &
              region%levels(ilev)%grid%c2fCoI(2,ijkni)
              region%levels(ilev)%grid%c2fCoI(1,ijknd) = &
              1._rfreal-region%levels(ilev)%grid%c2fCoI(2,ijknd)
            ENDDO
          ENDDO
        ENDDO

        DO idum=idumb(2),idume(2)
          DO jdum=jdumb(2),jdume(2)
            DO kdum=kdumb(2),kdume(2) 
              ijknd  = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)
              region%levels(ilev)%grid%c2fCoJ(2,ijknd) = &
              region%levels(ilev)%grid%c2fCoJ(2,ijknj)
              region%levels(ilev)%grid%c2fCoJ(1,ijknd) = &
              1._rfreal-region%levels(ilev)%grid%c2fCoJ(2,ijknd)
            ENDDO
          ENDDO
        ENDDO

        DO idum=idumb(3),idume(3)
          DO jdum=jdumb(3),jdume(3)
            DO kdum=kdumb(3),kdume(3) 
              ijknd  = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)
              region%levels(ilev)%grid%c2fCoK(2,ijknd) = &
              region%levels(ilev)%grid%c2fCoK(2,ijknk)
              region%levels(ilev)%grid%c2fCoK(1,ijknd) = &
              1._rfreal-region%levels(ilev)%grid%c2fCoK(2,ijknd)
            ENDDO
          ENDDO
        ENDDO

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! copy coefficients from region boundary to patch edge

  CALL avgcopatchedge

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

! ==============================================================================
! subroutine for copying to patch edges 
! ==============================================================================

CONTAINS
 
  SUBROUTINE avgcopatchedge

! ... local variables

  INTEGER :: inbeg, inend, jnbeg, jnend, knbeg, knend
  INTEGER :: ijkn, ijkn1, iref, jref, kref
  REAL(RFREAL), POINTER :: avgco(:,:)
      
  IF (lbound==1 .OR. lbound==3 .OR. lbound==5) THEN
    inbeg = indbeg-idir*region%nDumCells
    jnbeg = jndbeg-jdir*region%nDumCells
    knbeg = kndbeg-kdir*region%nDumCells
    inend = indend-idir
    jnend = jndend-jdir
    knend = kndend-kdir
  ELSE
    inbeg = indbeg
    jnbeg = jndbeg
    knbeg = kndbeg
    inend = indend-idir*region%nDumCells
    jnend = jndend-jdir*region%nDumCells
    knend = kndend-kdir*region%nDumCells
  ENDIF

  IF ((lbound==1).OR.(lbound==2)) THEN
    avgco => region%levels(ilev)%grid%c2fCoI
    IF (lbound==1) THEN
      iref = indend
    ELSE
      iref = indbeg-1
    ENDIF 
    DO i=inbeg,inend
      DO k=knbeg,knend-1
        ijkn    = indijk(i    ,jnbeg  ,k,inoff,ijnoff)
        ijkn1   = indijk(iref ,jnbeg  ,k,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
        ijkn    = indijk(i    ,jnend  ,k,inoff,ijnoff)
        ijkn1   = indijk(iref ,jnend  ,k,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
      END DO  
      DO j=jnbeg,jnend-1
        ijkn    = indijk(i    ,j,knbeg  ,inoff,ijnoff)
        ijkn1   = indijk(iref ,j,knbeg  ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
        ijkn    = indijk(i    ,j,knend  ,inoff,ijnoff)
        ijkn1   = indijk(iref ,j,knend  ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
      END DO  
    END DO
  ELSEIF ((lbound==3).OR.(lbound==4)) THEN
    avgco => region%levels(ilev)%grid%c2fCoJ
    IF (lbound==3) THEN
      jref = jndend
    ELSE
      jref = jndbeg-1
    ENDIF 
    DO j=jnbeg,jnend
      DO k=knbeg,knend-1
        ijkn    = indijk(inbeg ,j    ,k,inoff,ijnoff)
        ijkn1   = indijk(inbeg ,jref ,k,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
        ijkn    = indijk(inend ,j    ,k,inoff,ijnoff)
        ijkn1   = indijk(inend ,jref ,k,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
      END DO  
      DO i=inbeg,inend-1
        ijkn    = indijk(i,j    ,knbeg ,inoff,ijnoff)
        ijkn1   = indijk(i,jref ,knbeg ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
        ijkn    = indijk(i,j    ,knend ,inoff,ijnoff)
        ijkn1   = indijk(i,jref ,knend ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
      END DO  
    END DO  
  ELSEIF ((lbound==5).OR.(lbound==6)) THEN
    avgco => region%levels(ilev)%grid%c2fCoK
    IF (lbound==5) THEN
      kref = kndend
    ELSE
      kref = kndbeg-1
    ENDIF 
    DO k=knbeg,knend
      DO i=inbeg,inend-1
        ijkn    = indijk(i,jnbeg ,k    ,inoff,ijnoff)
        ijkn1   = indijk(i,jnbeg ,kref ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
        ijkn    = indijk(i,jnend ,k    ,inoff,ijnoff)
        ijkn1   = indijk(i,jnend ,kref ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
      END DO  
      DO j=jnbeg,jnend-1
        ijkn    = indijk(inbeg ,j,k    ,inoff,ijnoff)
        ijkn1   = indijk(inbeg ,j,kref ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
        ijkn    = indijk(inend ,j,k    ,inoff,ijnoff)
        ijkn1   = indijk(inend ,j,kref ,inoff,ijnoff)
        IF (avgco(1,ijkn)==0._rfreal .OR. avgco(2,ijkn)==0._rfreal) THEN
          avgco(:,ijkn)=avgco(:,ijkn1)
        ENDIF
      END DO  
    END DO  
  END IF

  END SUBROUTINE avgcopatchedge

END SUBROUTINE rflo_c2favgcoeffsdummyconn

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: RFLO_C2fAvgCoeffsDummyConn.F90,v $
! Revision 1.3  2008/12/06 08:44:25  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:36  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.3  2004/08/03 00:52:08  wasistho
! changed avgCo to c2fCo in the description
!
! Revision 1.2  2004/08/02 19:32:43  wasistho
! changed grid%avgCo to grid%c2fCo
!
! Revision 1.1  2004/07/30 17:30:31  wasistho
! initial import routines starting with RFLO_c2fAvg...
!
!
!
!******************************************************************************