RFLO_ArcLengthBounds.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate approximate arclengths for every grid line
!          between two oposite region boundaries (on the finest
!          grid only).
!
! Description: none.
!
! Input: region = grid dimensions
!        xyz    = node coordinates.
!
! Output: arcLen12 = arclength between i=const. boundaries for each j, k
!         arcLen34 = arclength between j=const. boundaries for each k, i
!         arcLen56 = arclength between k=const. boundaries for each i, j.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ArcLengthBounds.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_arclengthbounds( region,xyz,arcLen12,arcLen34,arcLen56 )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  REAL(RFREAL), POINTER :: arclen12(:,:), arclen34(:,:), arclen56(:,:)
  REAL(RFREAL), POINTER :: xyz(:,:)

  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  INTEGER :: ilev, inoff, ijnoff, ijkn, ijkn1
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_ArcLengthBounds',&
       'RFLO_ArcLengthBounds.F90' )

! get pointers and dimensions

  ilev = 1
  CALL rflo_getdimensphysnodes( region,ilev,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

! zero out variables

  arclen12(:,:) = 0._rfreal
  arclen34(:,:) = 0._rfreal
  arclen56(:,:) = 0._rfreal

! boundaries 1 and 2 (i=const.)

  DO i=ipnbeg+1,ipnend
    DO k=kpnbeg,kpnend
      DO j=jpnbeg,jpnend
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)
        ijkn1 = indijk(i-1,j,k,inoff,ijnoff)
        arclen12(j,k) = arclen12(j,k) + &
                        sqrt((xyz(xcoord,ijkn)-xyz(xcoord,ijkn1))**2 + &
                             (xyz(ycoord,ijkn)-xyz(ycoord,ijkn1))**2 + &
                             (xyz(zcoord,ijkn)-xyz(zcoord,ijkn1))**2)
      ENDDO
    ENDDO
  ENDDO

! boundaries 3 and 4 (j=const.)

  DO j=jpnbeg+1,jpnend
    DO i=ipnbeg,ipnend
      DO k=kpnbeg,kpnend
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)
        ijkn1 = indijk(i,j-1,k,inoff,ijnoff)
        arclen34(k,i) = arclen34(k,i) + &
                        sqrt((xyz(xcoord,ijkn)-xyz(xcoord,ijkn1))**2 + &
                             (xyz(ycoord,ijkn)-xyz(ycoord,ijkn1))**2 + &
                             (xyz(zcoord,ijkn)-xyz(zcoord,ijkn1))**2)
      ENDDO
    ENDDO
  ENDDO

! boundarie 5 and 6 (k=const.)

  DO k=kpnbeg+1,kpnend
    DO j=jpnbeg,jpnend
      DO i=ipnbeg,ipnend
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)
        ijkn1 = indijk(i,j,k-1,inoff,ijnoff)
        arclen56(i,j) = arclen56(i,j) + &
                        sqrt((xyz(xcoord,ijkn)-xyz(xcoord,ijkn1))**2 + &
                             (xyz(ycoord,ijkn)-xyz(ycoord,ijkn1))**2 + &
                             (xyz(zcoord,ijkn)-xyz(zcoord,ijkn1))**2)
      ENDDO
    ENDDO
  ENDDO

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_arclengthbounds

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ArcLengthBounds.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:19  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:15  wasistho
! lower to upper case
!
! Revision 1.7  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.4  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.3  2003/03/14 22:05:10  jblazek
! Improved mesh motion algorithm - node movement exchaged between blocks.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/08/15 19:48:04  jblazek
! Implemented grid deformation capability.
!
!******************************************************************************