RADI_rFLO_WriteSolution.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write radiation solution, extinction coefficients and intensities, 
!          to file
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions            = dimensions and cons. variables of all regions
!        global%currentTime = physical time
!        global%resInit     = initial residual.
!
! Output: to file.
!
! Notes: solution is stored only for the current grid level; it is also
!        stored for all dummy cells. All regions are written into one file.
!
!******************************************************************************
!
! $Id: RADI_rFLO_WriteSolution.F90,v 1.4 2008/12/06 08:44:38 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_rflo_writesolution( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_writedatafileint, rflo_writedatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset, &
                            rflo_getnodeoffset
  USE moderror
  USE modmpi
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, l, n

! ... local variables
  TYPE(t_global), POINTER :: global

  CHARACTER(2*CHRLEN+17)  :: fname

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells
  INTEGER :: icoff, ijcoff, ijkc, inoff, ijnoff, ijkn, ijkni, ijknj, ijknk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: nang, ndimc, nrvar, nsolcomp, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  REAL(RFREAL), POINTER     :: radint(:,:), radcoef(:,:), qri(:),qrj(:),qrk(:)
  REAL(RFREAL), POINTER     :: rcv(:,:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), solfile(:,:)

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RADI_RFLO_WriteSolution',&
  'RADI_rFLO_WriteSolution.F90' )

! allocate fixed-size temporary data arrays -----------------------------------

  nrvar = 2

  ALLOCATE( ivar(5,1),stat=errorflag )
  ALLOCATE( rvar(nrvar,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open solution file (only master proc.) --------------------------------------

  IF (global%myProcid == masterproc) THEN

! - unsteady flow

    IF (global%flowType == flow_unsteady) THEN
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.rada_', &
                                   global%currentTime
        OPEN(if_solut,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.radb_', &
                                   global%currentTime
        OPEN(if_solut,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = global%currentTime
      rvar(2,1) = 1._rfreal

! - steady flow

    ELSE
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,I6.6)') trim(global%outDir)//trim(global%casename)//'.rada_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,I6.6)') trim(global%outDir)//trim(global%casename)//'.radb_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = 0._rfreal
      rvar(2,1) = global%resInit
    ENDIF

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  ENDIF   ! MASTERPROC

! write time and initial residual to file -------------------------------------

  IF (global%myProcid == masterproc) THEN
    CALL rflo_writedatafilereal( global,if_solut,global%solutFormat,nrvar,1,rvar )
  ENDIF

! write solution data ---------------------------------------------------------

  DO ireg=1,global%nRegions

! - get dimensions and pointers

    ilev = regions(ireg)%currLevel
    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,icoff,ijcoff )
    CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
    ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
    ijkend = indijk(idcend,jdcend,kdcend,icoff,ijcoff)
    ndimc  = ijkend - ijkbeg + 1

! - allocate memory for data field

    nang     = regions(ireg)%radiInput%nAng
    nsolcomp = 3+radi_coeff_ncomp+nang

    IF (regions(ireg)%radiInput%radiModel == radi_model_fldtran) THEN
      nsolcomp = nsolcomp+1
    ENDIF

    IF (regions(ireg)%procid==global%myProcid .OR. &
        global%myProcid==masterproc) THEN
      ALLOCATE( solfile(nsolcomp,ndimc),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
    ENDIF

! - copy solution into data structure

    IF (regions(ireg)%procid == global%myProcid) THEN
      IF (regions(ireg)%mixtInput%radiUsed) THEN
        qri     => regions(ireg)%levels(ilev)%radi%qri
        qrj     => regions(ireg)%levels(ilev)%radi%qrj
        qrk     => regions(ireg)%levels(ilev)%radi%qrk
        radint  => regions(ireg)%levels(ilev)%radi%radInt
        radcoef => regions(ireg)%levels(ilev)%radi%radCoef
        n = 0
        IF (regions(ireg)%radiInput%radiModel /= radi_model_fldtran) THEN
          DO k=kdcbeg,kdcend
            DO j=jdcbeg,jdcend
              DO i=idcbeg,idcend
                n    = n + 1
                ijkc = indijk(i,j,k,icoff,ijcoff)
                ijkn = indijk(i,j,k,inoff,ijnoff)
                ijkni= indijk(i+1,j,k,inoff,ijnoff)
                ijknj= indijk(i,j+1,k,inoff,ijnoff)
                ijknk= indijk(i,j,k+1,inoff,ijnoff)
                solfile(1,n) = 0.5_rfreal*(qri(ijkn)+qri(ijkni))
                solfile(2,n) = 0.5_rfreal*(qrj(ijkn)+qrj(ijknj))
                solfile(3,n) = 0.5_rfreal*(qrk(ijkn)+qrk(ijknk))
                solfile(4,n) = radcoef(ijkc,radi_coeff_extinct)
                solfile(5,n) = radcoef(ijkc,radi_coeff_scatter)
                DO l = 1,nang
                  solfile(5+l,n) = radint(l,ijkc)
                ENDDO  ! l
              ENDDO  ! i
            ENDDO  ! j
          ENDDO  ! k
        ELSE
          rcv => regions(ireg)%levels(ilev)%radi%cv

          DO k=kdcbeg,kdcend
            DO j=jdcbeg,jdcend
              DO i=idcbeg,idcend
                n    = n + 1
                ijkc = indijk(i,j,k,icoff,ijcoff)
                ijkn = indijk(i,j,k,inoff,ijnoff)
                ijkni= indijk(i+1,j,k,inoff,ijnoff)
                ijknj= indijk(i,j+1,k,inoff,ijnoff)
                ijknk= indijk(i,j,k+1,inoff,ijnoff)
                solfile(1,n) = rcv(cv_radi_ener,ijkc)
                solfile(2,n) = 0.5_rfreal*(qri(ijkn)+qri(ijkni))
                solfile(3,n) = 0.5_rfreal*(qrj(ijkn)+qrj(ijknj))
                solfile(4,n) = 0.5_rfreal*(qrk(ijkn)+qrk(ijknk))
                solfile(5,n) = radcoef(ijkc,radi_coeff_extinct)
                solfile(6,n) = radcoef(ijkc,radi_coeff_scatter)
                DO l = 1,nang
                  solfile(6+l,n) = radint(l,ijkc)
                ENDDO  ! l
              ENDDO  ! i
            ENDDO  ! j
          ENDDO  ! k
        ENDIF  ! radiModel
      ELSE  ! radiUsed
        solfile = 0._rfreal
      ENDIF
    ENDIF      ! global%myProcid

! - write region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      ivar(1,1) = ireg
      ivar(2,1) = regions(ireg)%levels(ilev)%grid%ipc
      ivar(3,1) = regions(ireg)%levels(ilev)%grid%jpc
      ivar(4,1) = regions(ireg)%levels(ilev)%grid%kpc
      ivar(5,1) = regions(ireg)%nDumCells
      CALL rflo_writedatafileint( global,if_solut,global%solutFormat,5,1,ivar )
    ENDIF

! - master receives and writes data, others send them

    IF (global%myProcid == masterproc) THEN
#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_recv( solfile, nsolcomp*ndimc,mpi_rfreal, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
      CALL rflo_writedatafilereal( global,if_solut,global%solutFormat, &
                                   nsolcomp,ndimc,solfile )
    ELSE   ! not the master
#ifdef MPI
      IF (regions(ireg)%procid == global%myProcid) THEN
        CALL mpi_send( solfile,nsolcomp*ndimc,mpi_rfreal, &
                       masterproc,ireg,global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
    ENDIF

    IF (ALLOCATED(solfile)) THEN
      DEALLOCATE( solfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_solut,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

END SUBROUTINE radi_rflo_writesolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_rFLO_WriteSolution.F90,v $
! Revision 1.4  2008/12/06 08:44:38  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/09/30 17:49:10  wasistho
! prepared for full FLD radiation model
!
! Revision 1.1  2004/09/23 03:51:12  wasistho
! changed RADI_WriteSol.. to RADI_RFLO_WriteSol..
!
! Revision 1.1  2004/09/22 02:35:50  wasistho
! changed file nomenclature from lower to upper case
!
! Revision 1.4  2003/08/11 21:52:31  wasistho
! added cell avg. radiation fluxes to output solution
!
! Revision 1.3  2003/07/30 22:24:08  wasistho
! enter part and smoke data into radiation
!
! Revision 1.2  2003/07/22 03:05:58  wasistho
! include logical write-parameter
!
! Revision 1.1  2003/07/17 01:16:59  wasistho
! initial activation rocrad
!
!
!******************************************************************************