RADI_floFlimRecvDummyVals.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receive FLD radiation data to patch dummy cells from neighboring
!          region / periodic boundary located on a different processor.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: region%levels%radi = FLD radiation variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RADI_floFlimRecvDummyVals.F90,v 1.3 2008/12/06 08:44:38 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_floflimrecvdummyvals( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getcelloffset
  USE moderror
  USE modmpi
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: idum, i, j, k, l, ijkbuff

! ... local variables
#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: lb, ibeg, iend, jbeg, jend, kbeg, kend, icoff, ijcoff, ijkd, &
             n1, n2, ndim, source, tag, ilev, ncv

  REAL(RFREAL), POINTER :: rcv(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RADI_FloFlimRecvDummyVals',&
  'RADI_floFlimRecvDummyVals.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  rcv  => region%levels(ilev)%radi%cv
  ncv  =  region%radiInput%nCv

  n1   =  abs(patch%l1end-patch%l1beg) + 1   ! here, dimensions of current
  n2   =  abs(patch%l2end-patch%l2beg) + 1   ! and source patch are identical
  ndim =  n1*n2*region%nDumCells             ! ... but not the # of dummy cells

! receive data

#ifdef MPI
  source = regionsrc%procid
  tag    = region%localNumber + mpi_patchoff*patchsrc%srcPatch* &
           radi_tag_shift
  CALL mpi_recv( patch%valRadi%recvBuff,ncv*ndim,mpi_rfreal, &
                 source,tag,global%mpiComm,status,global%mpierr )
  IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! copy from buffer to dummy nodes ---------------------------------------------

  lb      = patch%lbound
  ijkbuff = 0

  DO idum=1,region%nDumCells

! - face i=const.

    IF (lb==1 .OR. lb==2) THEN
      IF (lb == 1) i = ibeg - idum
      IF (lb == 2) i = iend + idum
      DO k=kbeg,kend
        DO j=jbeg,jend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          DO l=1,ncv
            rcv(l,ijkd) = patch%valRadi%recvBuff(ijkbuff+(l-1)*ndim)
          ENDDO
        ENDDO
      ENDDO

! - face j=const.

    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (lb == 3) j = jbeg - idum
      IF (lb == 4) j = jend + idum
      DO i=ibeg,iend
        DO k=kbeg,kend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          DO l=1,ncv
            rcv(l,ijkd) = patch%valRadi%recvBuff(ijkbuff+(l-1)*ndim)
          ENDDO
        ENDDO
      ENDDO

! - face k=const.

    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (lb == 5) k = kbeg - idum
      IF (lb == 6) k = kend + idum
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          DO l=1,ncv
            rcv(l,ijkd) = patch%valRadi%recvBuff(ijkbuff+(l-1)*ndim)
          ENDDO
        ENDDO
      ENDDO
    ENDIF   ! lb

  ENDDO     ! idum

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE radi_floflimrecvdummyvals

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_floFlimRecvDummyVals.F90,v $
! Revision 1.3  2008/12/06 08:44:38  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:50  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/30 17:49:10  wasistho
! prepared for full FLD radiation model
!
!
!
!******************************************************************************