RADI_floFlimCentFlux.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute central convective flux FLD eq. by average of variables.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%radi%rhs = convective fluxes added to FLD residual.
!
! Notes: grid speeds si,j,kVel already contain face area
!
!******************************************************************************
!
! $Id: RADI_floFlimCentFlux.F90,v 1.3 2008/12/06 08:44:38 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_floflimcentflux( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset, &
                            rflo_getnodeoffset
  USE radi_modinterfaces, ONLY : radi_floflimcentfluxpatch
  USE moderror
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ipatch

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc0, ijkc1, ijkn, indsvel

  REAL(RFREAL)          :: radea, ua, va, wa, vcont, svel, fc
  REAL(RFREAL), POINTER :: dv(:,:), rcv(:,:), rrhs(:,:)
  REAL(RFREAL), POINTER :: aci(:,:), acj(:,:), ack(:,:)
  REAL(RFREAL), POINTER :: si(:,:), sj(:,:), sk(:,:)
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)

!******************************************************************************

  CALL registerfunction( region%global,'RADI_FloFlimCentFlux',&
  'RADI_floFlimCentFlux.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  dv     => region%levels(ilev)%mixt%dv
  rcv    => region%levels(ilev)%radi%cv
  rrhs   => region%levels(ilev)%radi%rhs
  aci    => region%levels(ilev)%grid%c2fCoI
  acj    => region%levels(ilev)%grid%c2fCoJ
  ack    => region%levels(ilev)%grid%c2fCoK
  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

! flux in i-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg+1,ipcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        radea  = aci(2,ijkn)*rcv(cv_radi_ener,ijkc0)+ &
                 aci(1,ijkn)*rcv(cv_radi_ener,ijkc1)
        ua     = aci(2,ijkn)*dv(dv_mixt_uvel,ijkc0)+ &
                 aci(1,ijkn)*dv(dv_mixt_uvel,ijkc1)
        va     = aci(2,ijkn)*dv(dv_mixt_vvel,ijkc0)+ &
                 aci(1,ijkn)*dv(dv_mixt_vvel,ijkc1)
        wa     = aci(2,ijkn)*dv(dv_mixt_wvel,ijkc0)+ &
                 aci(1,ijkn)*dv(dv_mixt_wvel,ijkc1)

        svel   = sivel(ijkn*indsvel)
        vcont  = ua*si(xcoord,ijkn)+va*si(ycoord,ijkn)+wa*si(zcoord,ijkn)-svel

        fc = vcont*radea

        rrhs(cv_radi_ener,ijkc0) = rrhs(cv_radi_ener,ijkc0) + fc
        rrhs(cv_radi_ener,ijkc1) = rrhs(cv_radi_ener,ijkc1) - fc
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in j-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg+1,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        radea  = acj(2,ijkn)*rcv(cv_radi_ener,ijkc0)+ &
                 acj(1,ijkn)*rcv(cv_radi_ener,ijkc1)
        ua     = acj(2,ijkn)*dv(dv_mixt_uvel,ijkc0)+ &
                 acj(1,ijkn)*dv(dv_mixt_uvel,ijkc1)
        va     = acj(2,ijkn)*dv(dv_mixt_vvel,ijkc0)+ &
                 acj(1,ijkn)*dv(dv_mixt_vvel,ijkc1)
        wa     = acj(2,ijkn)*dv(dv_mixt_wvel,ijkc0)+ &
                 acj(1,ijkn)*dv(dv_mixt_wvel,ijkc1)

        svel   = sjvel(ijkn*indsvel)
        vcont  = ua*sj(xcoord,ijkn)+va*sj(ycoord,ijkn)+wa*sj(zcoord,ijkn)-svel

        fc = vcont*radea

        rrhs(cv_radi_ener,ijkc0) = rrhs(cv_radi_ener,ijkc0) + fc
        rrhs(cv_radi_ener,ijkc1) = rrhs(cv_radi_ener,ijkc1) - fc
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in k-direction (except through boundary) -------------------------------

  DO k=kpcbeg+1,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        radea  = ack(2,ijkn)*rcv(cv_radi_ener,ijkc0)+ &
                 ack(1,ijkn)*rcv(cv_radi_ener,ijkc1)
        ua     = ack(2,ijkn)*dv(dv_mixt_uvel,ijkc0)+ &
                 ack(1,ijkn)*dv(dv_mixt_uvel,ijkc1)
        va     = ack(2,ijkn)*dv(dv_mixt_vvel,ijkc0)+ &
                 ack(1,ijkn)*dv(dv_mixt_vvel,ijkc1)
        wa     = ack(2,ijkn)*dv(dv_mixt_wvel,ijkc0)+ &
                 ack(1,ijkn)*dv(dv_mixt_wvel,ijkc1)

        svel   = skvel(ijkn*indsvel)
        vcont  = ua*sk(xcoord,ijkn)+va*sk(ycoord,ijkn)+wa*sk(zcoord,ijkn)-svel

        fc = vcont*radea

        rrhs(cv_radi_ener,ijkc0) = rrhs(cv_radi_ener,ijkc0) + fc
        rrhs(cv_radi_ener,ijkc1) = rrhs(cv_radi_ener,ijkc1) - fc
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fluxes through boundaries ---------------------------------------------------

  DO ipatch=1,region%nPatches
    CALL radi_floflimcentfluxpatch( region, &
                                    region%levels(ilev)%patches(ipatch) )
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE radi_floflimcentflux

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_floFlimCentFlux.F90,v $
! Revision 1.3  2008/12/06 08:44:38  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:50  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/30 17:49:10  wasistho
! prepared for full FLD radiation model
!
!
!
!******************************************************************************