RADI_FlimRkUpdate.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update FLD radiation solution for unsteady flow using RK scheme
!
! Description: none.
!
! Input: region = data of current region,
!
! Output: region%levels%radi%cv = new solution after each stage.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RADI_FlimRkUpdate.F90,v 1.3 2008/12/06 08:44:37 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_flimrkupdate( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE radi_modparameters
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset, &
                            rflo_extrapintcellvec

#include "Indexing.h"
#endif

  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ic, idx
  
! ... local variables
#ifdef RFLO
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, icoff, ijcoff
#endif
  INTEGER :: istage, ibc, iec, idxb, idxe

  LOGICAL :: movegrid

  REAL(RFREAL), POINTER :: cv(:,:), cvold(:,:), rhs(:,:), rhssum(:,:)
  REAL(RFREAL), POINTER :: vol(:), volold(:)
  REAL(RFREAL)          :: ark(5), grk(5), fac, adtv, volrat
  
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RADI_FlimRkUpdate',&
  'RADI_FlimRkUpdate.F90' )

! get stage number ------------------------------------------------------------

  istage = region%irkStep

! get dimensions and pointers -------------------------------------------------

  ark(:)   = region%mixtInput%ark(:)
  grk(:)   = region%mixtInput%grk(:)

  movegrid = region%mixtInput%moveGrid

  IF (region%radiInput%radiModel == radi_model_fldtran) THEN
    idxb = cv_radi_ener
    idxe = cv_radi_ener
  ENDIF

#ifdef RFLO
  ilev  = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
  iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

  cv     => region%levels(ilev)%radi%cv
  cvold  => region%levels(ilev)%radi%cvOld
  rhs    => region%levels(ilev)%radi%rhs
  rhssum => region%levels(ilev)%radi%rhsSum
  vol    => region%levels(ilev)%grid%vol
  IF (movegrid) volold => region%levels(ilev)%gridOld%vol
#endif

#ifdef RFLU
  ibc = 1
  iec = region%grid%nCellsTot        

  cv     => region%radi%cv
  cvold  => region%radi%cvOld
  rhs    => region%radi%rhs
  rhssum => region%radi%rhsSum
  vol    => region%grid%vol
  IF (movegrid) volold => region%gridOld%vol
#endif

! update FLD radiation solution, sum up residuals -----------------------------

  fac = ark(istage)*global%dtMin
    
  IF (movegrid) THEN

! - grid is moving (but only at every time step, NOT stage)

    IF (istage == 1) THEN
      DO ic=ibc,iec
        adtv   = fac/vol(ic)
        volrat = volold(ic)/vol(ic)
        DO idx = idxb,idxe
          cv(idx,ic)     = volrat*cvold(idx,ic) - adtv*rhs(idx,ic)
          rhssum(idx,ic) = rhs(idx,ic)
        ENDDO
      ENDDO ! ic
      
    ELSE IF (istage == global%nrkSteps) THEN
      DO ic=ibc,iec
        adtv   = fac/vol(ic)
        volrat = volold(ic)/vol(ic)                                        
        DO idx = idxb,idxe
          cv(idx,ic) = volrat*cvold(idx,ic) - adtv*(rhs(idx,ic)+ &
                                                    rhssum(idx,ic))
        ENDDO
      ENDDO ! ic
      
    ELSE
      DO ic=ibc,iec
        adtv   = fac/vol(ic)
        volrat = volold(ic)/vol(ic)
        DO idx = idxb,idxe
          cv(idx,ic)     = volrat*cvold(idx,ic) - adtv*rhs(idx,ic)
          rhssum(idx,ic) = rhssum(idx,ic) + grk(istage)*rhs(idx,ic)
        ENDDO
      ENDDO ! ic
    ENDIF   ! istage

  ELSE      ! moveGrid

! - grid is fixed

    IF (istage == 1) THEN
      DO ic=ibc,iec
        adtv = fac/vol(ic)                                
        DO idx = idxb,idxe
          cv(idx,ic)     = cvold(idx,ic) - adtv*rhs(idx,ic)
          rhssum(idx,ic) = rhs(idx,ic)
        ENDDO
      ENDDO ! ic
      
    ELSE IF (istage == global%nrkSteps) THEN
      DO ic=ibc,iec
        adtv = fac/vol(ic)
        DO idx = idxb,idxe
          cv(idx,ic) = cvold(idx,ic) - adtv*(rhs(idx,ic)+ &
                                             rhssum(idx,ic))
        ENDDO
      ENDDO !ic
      
    ELSE
      DO ic=ibc,iec
        adtv = fac/vol(ic)              
        DO idx = idxb,idxe
          cv(idx,ic)     = cvold(idx,ic) - adtv*rhs(idx,ic)
          rhssum(idx,ic) = rhssum(idx,ic) + grk(istage)*rhs(idx,ic)
        ENDDO
      ENDDO !ic
      
    ENDIF   ! istage
  ENDIF     ! moveGrid

! extrapolate solution to dummy cells

#ifdef RFLO
  CALL rflo_extrapintcellvec( region,idxb,idxe,cv )
#endif
#ifdef RFLU
!  CALL RFLU_ExtrapIntCellVec( region,idxb,idxe,cv )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE radi_flimrkupdate

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_FlimRkUpdate.F90,v $
! Revision 1.3  2008/12/06 08:44:37  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:50  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/30 17:49:10  wasistho
! prepared for full FLD radiation model
!
!
!
!******************************************************************************