RADI_DiffRadIntens.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute diffusion approximation (Rosseland) radiation intensity
!          at specified directions.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%radi%radInt(:,n) = n-directions radiation intensities
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RADI_DiffRadIntens.F90,v 1.3 2008/12/06 08:44:37 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_diffradintens( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset
  USE moderror
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, l

! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, nang, icoff, ijcoff, ijkc

  REAL(RFREAL)          :: stboltz, pi, rad, avgfac
  REAL(RFREAL)          :: coefc, tempc, fact, rati, adir(3), thet, phi, sgrad
  REAL(RFREAL), POINTER :: dv(:,:), coef(:,:), radint(:,:), wvint(:,:)
  REAL(RFREAL), POINTER :: angles(:,:), gofact(:)

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'RADI_DiffRadIntens',&
  'RADI_DiffRadIntens.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel
  nang = region%radiInput%nAng

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  dv     => region%levels(ilev)%mixt%dv
  gofact => region%levels(ilev)%radi%goFact
  coef   => region%levels(ilev)%radi%radCoef
  radint => region%levels(ilev)%radi%radInt
  wvint  => region%levels(ilev)%radi%wvInt
  angles => region%radiInput%angles

  stboltz = region%radiInput%stBoltz
  pi      = global%pi
  rad     = global%rad
  avgfac  = 1._rfreal/6._rfreal

  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend
        ijkc = indijk(i  ,j,k,icoff,ijcoff)

        coefc = coef(ijkc,radi_coeff_extinct)
        tempc = dv(dv_mixt_temp,ijkc)
        fact  = gofact(ijkc)*stboltz*tempc**3/pi
        rati  = 4._rfreal/coefc

! ----- wvInt contains grad(T)n+s+e+w+f+b
        wvint(:,ijkc) = avgfac*wvint(:,ijkc)

! ----- get intensity in all given directions
        DO l = 1,nang
          thet    = angles(l,radi_angle_polar)
          phi     = angles(l,radi_angle_azimu)
          adir(1) = sin(thet)*cos(phi)
          adir(2) = sin(thet)*sin(phi)
          adir(3) = cos(thet)
          sgrad   = adir(1)*wvint(xcoord,ijkc) + &
                    adir(2)*wvint(ycoord,ijkc) + &
                    adir(3)*wvint(zcoord,ijkc)
          radint(l,ijkc) = fact*( tempc - rati*sgrad)
        ENDDO ! l

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE radi_diffradintens

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_DiffRadIntens.F90,v $
! Revision 1.3  2008/12/06 08:44:37  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/22 02:35:49  wasistho
! changed file nomenclature from lower to upper case
!
! Revision 1.3  2003/07/30 22:24:43  wasistho
! enter part and smoke data into radiation
!
! Revision 1.2  2003/07/23 03:14:22  wasistho
! cured baby illness
!
! Revision 1.1  2003/07/17 01:16:59  wasistho
! initial activation rocrad
!
!
!******************************************************************************