RADI_DiffRadFlux.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute diffusion approximation, FLDSRC or ROSS, radiative fluxes 
!          by average of variables.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%mixt%rhs = radiative fluxes added to the residual.
!
! Notes: grad(T) is averaged to cell center in wvInt for computation of
!        radiation intensity later.
!
!******************************************************************************
!
! $Id: RADI_DiffRadFlux.F90,v 1.3 2008/12/06 08:44:37 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_diffradflux( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getdimensdummy, &
                            rflo_getcelloffset, rflo_getnodeoffset
  USE radi_modinterfaces, ONLY : radi_diffradfluxpatch
  USE moderror
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ipatch

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc0, ijkc1, ijkn

  REAL(RFREAL)          :: gfaca, flima, coefa, tempa, stboltz, rati, beta
  REAL(RFREAL)          :: qrx, qry, qrz, modsf, fr
  REAL(RFREAL), POINTER :: rhs(:,:), si(:,:), sj(:,:), sk(:,:)
  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:), gradk(:,:)
  REAL(RFREAL), POINTER :: rdv(:,:), qri(:), qrj(:), qrk(:) 
  REAL(RFREAL), POINTER :: gofact(:), flim(:), coef(:,:), wvint(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RADI_DiffRadFlux',&
  'RADI_DiffRadFlux.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk

  rhs    => region%levels(ilev)%mixt%rhs
  gradi  => region%levels(ilev)%mixt%gradi
  gradj  => region%levels(ilev)%mixt%gradj
  gradk  => region%levels(ilev)%mixt%gradk

  rdv    => region%levels(ilev)%radi%dv
  flim   => region%levels(ilev)%radi%fluxLim
  coef   => region%levels(ilev)%radi%radCoef
  gofact => region%levels(ilev)%radi%goFact
  qri    => region%levels(ilev)%radi%qri
  qrj    => region%levels(ilev)%radi%qrj
  qrk    => region%levels(ilev)%radi%qrk
  wvint  => region%levels(ilev)%radi%wvInt
 
  wvint   = 0._rfreal
  stboltz = region%radiInput%stBoltz
  rati    = -16._rfreal
  beta    = region%mixtInput%betrk(region%irkStep)

! flux in i-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg+1,ipcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        gfaca = 0.5_rfreal*(gofact(ijkc0)+gofact(ijkc1)) 
        flima = 0.5_rfreal*(flim(ijkc0)+flim(ijkc1)) 
        coefa = 0.5_rfreal*(coef(ijkc0,radi_coeff_extinct)+ &
                            coef(ijkc1,radi_coeff_extinct))
        tempa = 0.5_rfreal*(rdv(dv_radi_teff,ijkc0)+rdv(dv_radi_teff,ijkc1))
        coefa = gfaca*rati*flima*stboltz*tempa**3/coefa

        qrx   = coefa*gradi(gr_mixt_tx,ijkn)
        qry   = coefa*gradi(gr_mixt_ty,ijkn)
        qrz   = coefa*gradi(gr_mixt_tz,ijkn)

        fr    = qrx*si(xcoord,ijkn)+ &
                qry*si(ycoord,ijkn)+ &
                qrz*si(zcoord,ijkn)

        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) - fr*beta
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) + fr*beta

! ----- store radiant flux normal to cell face in positive direction in qri
        modsf     = sqrt( si(xcoord,ijkn)*si(xcoord,ijkn) + &
                          si(ycoord,ijkn)*si(ycoord,ijkn) + &
                          si(zcoord,ijkn)*si(zcoord,ijkn))
        qri(ijkn) = -fr/modsf
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg+1,idcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        wvint(xcoord,ijkc0) = wvint(xcoord,ijkc0) + gradi(gr_mixt_tx,ijkn)
        wvint(ycoord,ijkc0) = wvint(ycoord,ijkc0) + gradi(gr_mixt_ty,ijkn)
        wvint(zcoord,ijkc0) = wvint(zcoord,ijkc0) + gradi(gr_mixt_tz,ijkn)

        wvint(xcoord,ijkc1) = wvint(xcoord,ijkc1) + gradi(gr_mixt_tx,ijkn)
        wvint(ycoord,ijkc1) = wvint(ycoord,ijkc1) + gradi(gr_mixt_ty,ijkn)
        wvint(zcoord,ijkc1) = wvint(zcoord,ijkc1) + gradi(gr_mixt_tz,ijkn)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in j-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg+1,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        gfaca = 0.5_rfreal*(gofact(ijkc0)+gofact(ijkc1)) 
        flima = 0.5_rfreal*(flim(ijkc0)+flim(ijkc1)) 
        coefa = 0.5_rfreal*(coef(ijkc0,radi_coeff_extinct)+ &
                            coef(ijkc1,radi_coeff_extinct))
        tempa = 0.5_rfreal*(rdv(dv_radi_teff,ijkc0)+rdv(dv_radi_teff,ijkc1))

        coefa = gfaca*rati*flima*stboltz*tempa**3/coefa

        qrx   = coefa*gradj(gr_mixt_tx,ijkn)
        qry   = coefa*gradj(gr_mixt_ty,ijkn)
        qrz   = coefa*gradj(gr_mixt_tz,ijkn)

        fr    = qrx*sj(xcoord,ijkn)+ &
                qry*sj(ycoord,ijkn)+ &
                qrz*sj(zcoord,ijkn)

        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) - fr*beta
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) + fr*beta

! ----- store radiant flux normal to cell face in positive direction in qrj
        modsf     = sqrt( sj(xcoord,ijkn)*sj(xcoord,ijkn) + &
                          sj(ycoord,ijkn)*sj(ycoord,ijkn) + &
                          sj(zcoord,ijkn)*sj(zcoord,ijkn))
        qrj(ijkn) = -fr/modsf
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

  DO k=kdcbeg,kdcend
    DO j=jdcbeg+1,jdcend
      DO i=idcbeg,idcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        wvint(xcoord,ijkc0) = wvint(xcoord,ijkc0) + gradj(gr_mixt_tx,ijkn)
        wvint(ycoord,ijkc0) = wvint(ycoord,ijkc0) + gradj(gr_mixt_ty,ijkn)
        wvint(zcoord,ijkc0) = wvint(zcoord,ijkc0) + gradj(gr_mixt_tz,ijkn)

        wvint(xcoord,ijkc1) = wvint(xcoord,ijkc1) + gradj(gr_mixt_tx,ijkn)
        wvint(ycoord,ijkc1) = wvint(ycoord,ijkc1) + gradj(gr_mixt_ty,ijkn)
        wvint(zcoord,ijkc1) = wvint(zcoord,ijkc1) + gradj(gr_mixt_tz,ijkn)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in k-direction (except through boundary) -------------------------------

  DO k=kpcbeg+1,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        gfaca = 0.5_rfreal*(gofact(ijkc0)+gofact(ijkc1)) 
        flima = 0.5_rfreal*(flim(ijkc0)+flim(ijkc1)) 
        coefa = 0.5_rfreal*(coef(ijkc0,radi_coeff_extinct)+ &
                            coef(ijkc1,radi_coeff_extinct))
        tempa = 0.5_rfreal*(rdv(dv_radi_teff,ijkc0)+rdv(dv_radi_teff,ijkc1))

        coefa = gfaca*rati*flima*stboltz*tempa**3/coefa

        qrx   = coefa*gradk(gr_mixt_tx,ijkn)
        qry   = coefa*gradk(gr_mixt_ty,ijkn)
        qrz   = coefa*gradk(gr_mixt_tz,ijkn)

        fr    = qrx*sk(xcoord,ijkn)+ &
                qry*sk(ycoord,ijkn)+&
                qrz*sk(zcoord,ijkn)

        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) - fr*beta
        rhs(cv_mixt_ener,ijkc1) = rhs(cv_mixt_ener,ijkc1) + fr*beta

! ----- store radiant flux normal to cell face in positive direction in qrk
        modsf     = sqrt( sk(xcoord,ijkn)*sk(xcoord,ijkn) + &
                          sk(ycoord,ijkn)*sk(ycoord,ijkn) + &
                          sk(zcoord,ijkn)*sk(zcoord,ijkn))
        qrk(ijkn) = -fr/modsf
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

  DO k=kdcbeg+1,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        wvint(xcoord,ijkc0) = wvint(xcoord,ijkc0) + gradk(gr_mixt_tx,ijkn)
        wvint(ycoord,ijkc0) = wvint(ycoord,ijkc0) + gradk(gr_mixt_ty,ijkn)
        wvint(zcoord,ijkc0) = wvint(zcoord,ijkc0) + gradk(gr_mixt_tz,ijkn)

        wvint(xcoord,ijkc1) = wvint(xcoord,ijkc1) + gradk(gr_mixt_tx,ijkn)
        wvint(ycoord,ijkc1) = wvint(ycoord,ijkc1) + gradk(gr_mixt_ty,ijkn)
        wvint(zcoord,ijkc1) = wvint(zcoord,ijkc1) + gradk(gr_mixt_tz,ijkn)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fluxes through boundaries ---------------------------------------------------

  DO ipatch=1,region%nPatches
    CALL radi_diffradfluxpatch( region,region%levels(ilev)%patches(ipatch) )
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE radi_diffradflux

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_DiffRadFlux.F90,v $
! Revision 1.3  2008/12/06 08:44:37  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/22 02:35:49  wasistho
! changed file nomenclature from lower to upper case
!
! Revision 1.5  2004/09/22 01:32:03  wasistho
! switch LFD to FLD for flux limited diffusion
!
! Revision 1.4  2004/09/18 17:41:48  wasistho
! install Limited Flux Diffusion radiation
!
! Revision 1.3  2003/08/13 21:18:07  wasistho
! corrected sign and rk-stage of radiation flux
!
! Revision 1.2  2003/07/30 22:24:28  wasistho
! enter part and smoke data into radiation
!
! Revision 1.1  2003/07/17 01:16:59  wasistho
! initial activation rocrad
!
!
!******************************************************************************