PLAG_PatchRemoveDataOutflow.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: remove particle from datastructure if exiting computational domain. 
!
! Description: none.
!
! Input: region = current region
!        iReg   = number of current region.
!
! Output: regions(iReg)%levels%patch%buffPlag%aiv,arv,cv,dv,tv = buffer data.
!         regions(iReg)%levels%plag%aiv,arv,cv,dv,tv           = Plag data.
!
! Notes:
!
!   Particle indices have been updated at the outflow BC only, so particles
!   are removed if their indices are no longer within the region
!
!******************************************************************************
!
! $Id: PLAG_PatchRemoveDataOutflow.F90,v 1.3 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_patchremovedataoutflow( region, iReg )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag, t_plag_input
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global  
  USE modinterfaces, ONLY : rflo_getdimensphys
  USE moderror
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  
  INTEGER        :: ireg

! ... loop variables
  INTEGER :: ipcls

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ilev, npcls, npclsprev, ipclsregionin
  INTEGER :: icplag, ipcbeg, ipcend
  INTEGER :: jcplag, jpcbeg, jpcend
  INTEGER :: kcplag, kpcbeg, kpcend

  INTEGER, POINTER, DIMENSION(:,:) :: paiv, paivold

  LOGICAL :: lboundskip(6)

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: parv, parvold, pcv, pcvold, &
                                           pdv, ptv, prhs, prhssum

  TYPE(t_plag),   POINTER :: pplag 
  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PLAG_PatchRemoveDataOutflow.F90,v $ $Revision: 1.3 $'

  global => region%global
    
  CALL registerfunction( global, 'PLAG_PatchRemoveDataOutflow',&
  'PLAG_PatchRemoveDataOutflow.F90' )

! Get dimensions --------------------------------------------------------------

  ilev  = region%currLevel
  npcls = region%levels(ilev)%plag%nPcls 

  IF (npcls == 0) goto 999 ! exit if no particles

! Set pointers ----------------------------------------------------------------

  pplag   => region%levels(ilev)%plag   
  paiv    => pplag%aiv
  parv    => pplag%arv
  pcv     => pplag%cv
  pdv     => pplag%dv
  ptv     => pplag%tv
  prhs    => pplag%rhs
  prhssum => pplag%rhsSum

  paivold => pplag%aivOld
  parvold => pplag%arvOld
  pcvold  => pplag%cvOld

! Get grid dimensions ---------------------------------------------------------
  
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
     
! Initialize counters for particles inside and outside region -----------------

  ipclsregionin = 0

! Loop over particles ---------------------------------------------------------

  DO ipcls = 1, npcls

    icplag = paiv(aiv_plag_indexi,ipcls)
    jcplag = paiv(aiv_plag_indexj,ipcls)
    kcplag = paiv(aiv_plag_indexk,ipcls)
    
! - Check if particle cell is within region -----------------------------------

    IF ( ipcbeg <= icplag .AND. icplag <= ipcend .AND. &
         jpcbeg <= jcplag .AND. jcplag <= jpcend .AND. &
         kpcbeg <= kcplag .AND. kcplag <= kpcend ) THEN

! --- Shift particle datastructure only if particle is not in its proper spot -
 
      ipclsregionin = ipclsregionin + 1 

      IF ( ipclsregionin /= ipcls ) THEN
        paiv(   :,ipclsregionin) = paiv(   :,ipcls)
        parv(   :,ipclsregionin) = parv(   :,ipcls)
        pcv(    :,ipclsregionin) = pcv(    :,ipcls)
        pdv(    :,ipclsregionin) = pdv(    :,ipcls)
        ptv(    :,ipclsregionin) = ptv(    :,ipcls)
        prhs(   :,ipclsregionin) = prhs(   :,ipcls)
        prhssum(:,ipclsregionin) = prhssum(:,ipcls)

        paivold(:,ipclsregionin) = paivold(:,ipcls)
        parvold(:,ipclsregionin) = parvold(:,ipcls)
        pcvold( :,ipclsregionin) = pcvold( :,ipcls)
      ENDIF ! iPclsRegionIn
 
    ENDIF   ! iCPlag, jCPlag, kCPlag

  ENDDO     ! iPcls

! Get new particle datasize ---------------------------------------------------

  npclsprev   = pplag%nPcls    
  pplag%nPcls = ipclsregionin

!  WRITE(STDOUT,'(A,I4,2I8)') &
!  '      PLAG_PatchRemoveDataOutflow: iReg, nPclsPrev,nPclsCurr',iReg,nPclsPrev,pPlag%nPcls
      
! finalize --------------------------------------------------------------------

999  CONTINUE
  CALL deregisterfunction( global )

END SUBROUTINE plag_patchremovedataoutflow

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_PatchRemoveDataOutflow.F90,v $
! Revision 1.3  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 20:57:58  fnajjar
! Initial revision after changing case
!
! Revision 1.8  2003/05/27 19:19:57  fnajjar
! Removed distPartBurning and all pertinent LOGICAL datastructure
!
! Revision 1.7  2003/05/01 22:58:30  jferry
! overhauled structure in order to optimize performance
!
! Revision 1.6  2003/05/01 18:07:25  jferry
! intermediate form checked in for documentation purposes only
!
! Revision 1.5  2003/04/17 00:00:27  fnajjar
! Commented out I/O to STDOUT
!
! Revision 1.4  2003/01/17 20:12:32  f-najjar
! Fixed FORMAT statements with iReg
!
! Revision 1.3  2003/01/17 19:30:24  f-najjar
! Added iReg in calling sequence
!
! Revision 1.2  2003/01/16 20:24:32  f-najjar
! Removed iRegionGlobal
!
! Revision 1.1  2002/10/25 14:18:35  f-najjar
! Initial Import of Rocpart
!
!******************************************************************************