PLAG_PatchLoadDataBuffers.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: loads data buffer size for patches
!          and shrinks particle datastructure. 
!
! Description: none.
!
! Input: region = current region,
!        iReg   = current region number.
!
! Output: regions(iReg)%levels%patch%buffPlag%aiv,arv,cv,dv,tv = buffer data.
!         regions(iReg)%levels%plag%aiv,arv,cv,dv,tv           = Plag data.
!
! Notes:
!
!   The cell index for the particle has been updated to its position
!
!******************************************************************************
!
! $Id: PLAG_PatchLoadDataBuffers.F90,v 1.3 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_patchloaddatabuffers( region, iReg )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag, t_plag_input, t_buffer_plag
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global  
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getdimensphys
  USE moderror
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  
  INTEGER        :: ireg

! ... loop variables
  INTEGER :: ipatch, ipcls

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype, ilev, npatches, npcls
  INTEGER :: ipclsregionin, ipclsregionbuf, npclsprev
  INTEGER :: icplag, ipcbeg, ipcend, ibeg, iend, idir
  INTEGER :: jcplag, jpcbeg, jpcend, jbeg, jend, jdir
  INTEGER :: kcplag, kpcbeg, kpcend, kbeg, kend, kdir
  INTEGER :: npclsbeg, npclsend
  INTEGER :: errorflag
  INTEGER :: ipatchcountersum

  INTEGER, POINTER, DIMENSION(:,:) :: paiv, paivold
  INTEGER, ALLOCATABLE, DIMENSION(:) ::patchcounter

  LOGICAL :: lboundskip(6)

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: parv, parvold, pcv, pcvold, &
                                           pdv, ptv, prhs, prhssum

  TYPE(t_patch),       POINTER :: ppatch
  TYPE(t_plag),        POINTER :: pplag 
  TYPE(t_buffer_plag), POINTER :: pbuffplag
  TYPE(t_global),      POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PLAG_PatchLoadDataBuffers.F90,v $ $Revision: 1.3 $'

  global => region%global
    
  CALL registerfunction( global, 'PLAG_PatchLoadDataBuffers',&
  'PLAG_PatchLoadDataBuffers.F90' )

! Get dimensions --------------------------------------------------------------

  ilev  = region%currLevel
  npcls = region%levels(ilev)%plag%nPcls 

  IF (npcls == 0) goto 999 ! exit if no particles

  npatches = region%nPatches

! Set pointers ----------------------------------------------------------------
   
  pplag   => region%levels(ilev)%plag   
  paiv    => pplag%aiv
  parv    => pplag%arv
  pcv     => pplag%cv
  pdv     => pplag%dv
  ptv     => pplag%tv
  prhs    => pplag%rhs
  prhssum => pplag%rhsSum

  paivold => pplag%aivOld
  parvold => pplag%arvOld
  pcvold  => pplag%cvOld
  
! Get grid dimensions ---------------------------------------------------------
  
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )

! Allocate patch buffer counter -----------------------------------------------

  ALLOCATE( patchcounter(npatches), stat=errorflag )
  global%error = errorflag
  IF ( global%error /= err_none ) &
    CALL errorstop( global,err_allocate,__line__ )

! Initialize counters for particles in inside and buffer regions --------------
  
  ipclsregionin  = 0
  ipclsregionbuf = 0
  patchcounter(1:npatches) = 0
  
! Loop over particles ---------------------------------------------------------

  DO ipcls = 1, npcls

    icplag = paiv(aiv_plag_indexi,ipcls)
    jcplag = paiv(aiv_plag_indexj,ipcls)
    kcplag = paiv(aiv_plag_indexk,ipcls)

! - Check if particle cell is within region -----------------------------------

    IF ( ipcbeg <= icplag .AND. icplag <= ipcend .AND. &
         jpcbeg <= jcplag .AND. jcplag <= jpcend .AND. &
         kpcbeg <= kcplag .AND. kcplag <= kpcend ) THEN

! --- Shift particle datastructure only if particle is not in its proper spot -
 
      ipclsregionin = ipclsregionin + 1 

      IF ( ipclsregionin /= ipcls ) THEN
        paiv(   :,ipclsregionin) = paiv(   :,ipcls)
        parv(   :,ipclsregionin) = parv(   :,ipcls)
        pcv(    :,ipclsregionin) = pcv(    :,ipcls)
        pdv(    :,ipclsregionin) = pdv(    :,ipcls)
        ptv(    :,ipclsregionin) = ptv(    :,ipcls)
        prhs(   :,ipclsregionin) = prhs(   :,ipcls)
        prhssum(:,ipclsregionin) = prhssum(:,ipcls)

        paivold(:,ipclsregionin) = paivold(:,ipcls)
        parvold(:,ipclsregionin) = parvold(:,ipcls)
        pcvold( :,ipclsregionin) = pcvold( :,ipcls)
      ENDIF ! iPclsRegionIn
 
    ELSE 

! --- Set lboundSkip(:) to .TRUE. for values of lbound adjacent to a boundary -

      lboundskip(1:6) = .true.

      IF (     icplag < ipcbeg) THEN
        lboundskip(1) = .false.
      ELSE IF (icplag > ipcend) THEN
        lboundskip(2) = .false.
      ENDIF ! iCPlag

      IF (     jcplag < jpcbeg) THEN
        lboundskip(3) = .false.
      ELSE IF (jcplag > jpcend) THEN
        lboundskip(4) = .false.
      ENDIF ! jCPlag

      IF (     kcplag < kpcbeg) THEN
        lboundskip(5) = .false.
      ELSE IF (kcplag > kpcend) THEN
        lboundskip(6) = .false.
      ENDIF ! kCPlag

! --- Remove particle from active datastructure -------------------------------

! --- Loop over patches -------------------------------------------------------

      DO ipatch=1,npatches

        ppatch => region%levels(ilev)%patches(ipatch)
        IF (lboundskip(ppatch%lbound)) cycle

        bctype = ppatch%bcType

! ----- Select communication boundary conditions ------------------------------
        
        IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
            (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
            (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN 

! ------- Check if particle cell is within (first dummy cell layer of) patch --

          CALL rflo_getpatchindices(   region,ppatch,ilev, &
                                       ibeg,iend,jbeg,jend,kbeg,kend )
          CALL rflo_getpatchdirection( ppatch,idir,jdir,kdir )

          IF ( ibeg - idir <= icplag .AND. icplag <= iend - idir .AND. &
               jbeg - jdir <= jcplag .AND. jcplag <= jend - jdir .AND. &
               kbeg - kdir <= kcplag .AND. kcplag <= kend - kdir ) THEN

! --------- Load communication buffer arrays ----------------------------------

! --------- Every variable packed down above is sent --------------------------

            patchcounter(ipatch) = patchcounter(ipatch)+1
            ipclsregionbuf       = patchcounter(ipatch)

            pbuffplag => ppatch%bufferPlag 

            pbuffplag%aiv(   :,ipclsregionbuf) = paiv(   :,ipcls)
            pbuffplag%arv(   :,ipclsregionbuf) = parv(   :,ipcls)
            pbuffplag%cv(    :,ipclsregionbuf) = pcv(    :,ipcls)
            pbuffplag%dv(    :,ipclsregionbuf) = pdv(    :,ipcls)
            pbuffplag%tv(    :,ipclsregionbuf) = ptv(    :,ipcls)
            pbuffplag%rhs(   :,ipclsregionbuf) = prhs(   :,ipcls)
            pbuffplag%rhsSum(:,ipclsregionbuf) = prhssum(:,ipcls)
  
            pbuffplag%aivOld(:,ipclsregionbuf) = paivold(:,ipcls)
            pbuffplag%arvOld(:,ipclsregionbuf) = parvold(:,ipcls)
            pbuffplag%cvOld( :,ipclsregionbuf) = pcvold( :,ipcls)

#ifdef PLAG_DEBUG    
            IF( pbuffplag%nBuffSize /= 0 )&
            WRITE(stdout,'(A,4I4)') &
            '      PLAG_PatchLoadDataBuffers-iReg: nBuffSize,iPatch,patchCounter', &
            ireg,pbuffplag%nBuffSize,ipatch,patchcounter(ipatch)
#endif    

          ENDIF ! iCPlag, jCPlag, kCPlag
        ENDIF   ! bcType  
      ENDDO     ! iPatch
    ENDIF       ! iCPlag, jCPlag, kCPlag
  ENDDO         ! iPcls

! Get new particle datasize and buffer ----------------------------------------

  npclsprev   = pplag%nPcls    
  pplag%nPcls = ipclsregionin
  ipatchcountersum = sum(patchcounter)

#ifdef PLAG_DEBUG    
  IF(npclsprev /= pplag%nPcls) &
  WRITE(stdout,'(A,I4,2I8,I4)') &
  '      PLAG_PatchLoadDataBuffers: iReg,nPclsPrev,nPclsCurr,iPatchCounterSum ',&
        ireg,npclsprev,pplag%nPcls,ipatchcountersum
#endif 

! Reinitialize reshuffled particle datastructure to account for ---------------
!   region with null size particle --------------------------------------------
!   perform if data reshuffled and particle size null -------------------------

  IF ( ipatchcountersum /=0 .AND. pplag%nPcls == 0) THEN 
    npclsbeg = max(1,pplag%nPcls+1)
    npclsend = npclsprev
  
    pplag%aiv(:   ,npclsbeg:npclsend) = 0
    pplag%aivOld(:,npclsbeg:npclsend) = 0
    pplag%arv(:   ,npclsbeg:npclsend) = 0.0_rfreal
    pplag%arvOld(:,npclsbeg:npclsend) = 0.0_rfreal
    pplag%cv(:    ,npclsbeg:npclsend) = 0.0_rfreal
    pplag%cvOld(: ,npclsbeg:npclsend) = 0.0_rfreal
    pplag%rhs(:   ,npclsbeg:npclsend) = 0.0_rfreal
    pplag%rhsSum(:,npclsbeg:npclsend) = 0.0_rfreal

#ifdef PLAG_DEBUG    
    WRITE(stdout,'(A,I4,2I6)') &
    '      PLAG_PatchLoadDataBuffers: iReg,nPclsBeg,nPclsEnd = ',&
           ireg,npclsbeg,npclsend
#endif
  ENDIF ! iPclsRegionBuf

! Deallocate patch buffer counter ----------------------------------------------

  DEALLOCATE( patchcounter, stat=errorflag )
  global%error = errorflag
  IF ( global%error /= err_none ) &
    CALL errorstop( global,err_deallocate,__line__ )

! finalize --------------------------------------------------------------------

999  CONTINUE
  CALL deregisterfunction( global )

END SUBROUTINE plag_patchloaddatabuffers

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_PatchLoadDataBuffers.F90,v $
! Revision 1.3  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 20:57:57  fnajjar
! Initial revision after changing case
!
! Revision 1.12  2004/04/09 23:14:57  fnajjar
! Added PatchCounter for multiple patches connecting to different regions
!
! Revision 1.11  2003/05/27 19:19:57  fnajjar
! Removed distPartBurning and all pertinent LOGICAL datastructure
!
! Revision 1.10  2003/05/06 23:56:40  fnajjar
! Bug fix to reinclude iPclsRegionIn
!
! Revision 1.9  2003/05/06 19:35:19  fnajjar
! Bug fix that removes nBuffSize=0 since it is computed in PLAG_patchGetBufferSize
!
! Revision 1.8  2003/05/01 22:58:30  jferry
! overhauled structure in order to optimize performance
!
! Revision 1.7  2003/04/17 00:00:27  fnajjar
! Commented out I/O to STDOUT
!
! Revision 1.6  2003/01/17 20:34:25  f-najjar
! Fixed FORMAT statements with iReg
!
! Revision 1.5  2003/01/17 19:34:08  f-najjar
! Added iReg in WRITE statements
!
! Revision 1.4  2003/01/16 15:39:51  f-najjar
! Included iReg in calling sequence since iRegionGlobal non-existent for Rocflo
!
! Revision 1.3  2003/01/16 15:34:24  f-najjar
! Move IF statement for nPcls check after extracting value
!
! Revision 1.2  2003/01/13 19:06:27  f-najjar
! Added aivOld, arvOld and cvOld to loading sequence
!
! Revision 1.1  2002/10/25 14:18:35  f-najjar
! Initial Import of Rocpart
!
!******************************************************************************