PLAG_PatchGetBufferSize.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: obtains exact buffer size for patches. 
!
! Description: none.
!
! Input: region = current region.
!
! Output: regions(iReg)%levels%patch%buffPlag%nBuffSize = buffer size.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_PatchGetBufferSize.F90,v 1.4 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_patchgetbuffersize( region )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag, t_plag_input, t_buffer_plag
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global  
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset,   rflo_getnodeoffset

  USE moderror
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, idum, ipatch, ipcls, j,k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype, ibeg, ic, icoff, idir, iend, ijcoff, ijnoff,      &
             ijkcpatch, ijkcplag, ijkdpatch,ilev, inode, inoff,        &
             jbeg, jc, jdir, jend, jnode, kbeg, kc, kdir, kend, knode, & 
             lbound, n1, n2, ndumcells, npatches, npcls, npclsbufftot, noff 
  INTEGER, POINTER, DIMENSION(:,:) :: paiv

  
  TYPE(t_patch),       POINTER :: ppatch
  TYPE(t_plag),        POINTER :: pplag
  TYPE(t_buffer_plag), POINTER :: pbuffplag
  TYPE(t_global),      POINTER :: global
  
!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_PatchGetBufferSize.F90,v $ $Revision: 1.4 $'

  global => region%global
    
  CALL registerfunction( global, 'PLAG_PatchGetBufferSize',&
  'PLAG_PatchGetBufferSize.F90' )

! Get dimensions --------------------------------------------------------------

  ilev         = region%currLevel
  npatches     = region%nPatches
  ndumcells    = region%nDumCells
  
  npcls        = region%levels(ilev)%plag%nPcls 
  npclsbufftot = region%plagInput%nPclsBuffTot
  
! Set pointers ----------------------------------------------------------------
   
  pplag   => region%levels(ilev)%plag   
  paiv    => pplag%aiv

! Loop over patches -----------------------------------------------------------

  DO ipatch=1,npatches

    ppatch  => region%levels(ilev)%patches(ipatch)

    bctype = ppatch%bcType
    
! - Get patch dimensions ------------------------------------------------------

    lbound = ppatch%lbound

    CALL rflo_getpatchindices( region,ppatch,ilev, &
                               ibeg,iend,jbeg,jend,kbeg,kend )
    CALL rflo_getpatchdirection( ppatch,idir,jdir,kdir )
    CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
    CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

    noff        = abs(ppatch%l1end-ppatch%l1beg) + 1

    inode = 0
    jnode = 0
    knode = 0
    IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
      inode = -idir
      jnode = -jdir
      knode = -kdir
    ENDIF ! lbound
  
! - Set pointers and initialize buffer sizes ----------------------------------

    IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
        (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
        (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN 
    
      pbuffplag => ppatch%bufferPlag     
    
      pbuffplag%nBuffSize  = 0
    
      pbuffplag%nSendBuffI = 0
      pbuffplag%nSendBuffR = 0
          
      pbuffplag%nRecvBuffI = 0
      pbuffplag%nRecvBuffR = 0

!- Bypass loop for null number of particles -----------------------------------

      IF ( npcls == 0 ) goto 1999
    
! - Loop over particles -------------------------------------------------------

      DO ipcls = 1, npcls
        ijkcplag = paiv(aiv_plag_icells,ipcls)
        ic       = paiv(aiv_plag_indexi,ipcls)
        jc       = paiv(aiv_plag_indexj,ipcls)
        kc       = paiv(aiv_plag_indexk,ipcls)

! -- Loop over patch and dummy cells ------------------------------------------

        DO idum=1,ndumcells
          DO k=kbeg,kend
            DO j=jbeg,jend
              DO i=ibeg,iend
                ijkcpatch  = indijk(i-(idum-1)*idir,j-(idum-1)*jdir,k-(idum-1)*kdir, icoff,ijcoff)
                ijkdpatch  = indijk(i-idum*idir,j-idum*jdir,k-idum*kdir,icoff,ijcoff)
                IF ( ijkcplag == ijkdpatch ) THEN
                  pbuffplag%nBuffSize = pbuffplag%nBuffSize + 1
                END IF ! ijkCPlag
      
              END DO ! i
            END DO ! j
          END DO ! k
        END DO  ! idum 

      END DO ! iPcls

1999  CONTINUE 
    ENDIF  ! bcType         
  ENDDO    ! iPatch

! finalize --------------------------------------------------------------------

999 CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE plag_patchgetbuffersize

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_PatchGetBufferSize.F90,v $
! Revision 1.4  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:23  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 20:57:56  fnajjar
! Initial revision after changing case
!
! Revision 1.7  2004/04/09 23:14:00  fnajjar
! Moved bypass of null particle size after setting buffer sizes to zero
!
! Revision 1.6  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.5  2003/01/16 20:58:00  f-najjar
! Reincluded missing CVS comments
!
! Revision 1.4  2003/01/16 20:24:32  f-najjar
! Removed iRegionGlobal
!
! Revision 1.3  2003/01/13 19:52:10  f-najjar
! Remove WRITE statement
!
! Revision 1.2  2003/01/13 19:31:44  f-najjar
! Included I8 in FORMAT call
!
! Revision 1.1  2002/10/25 14:18:35  f-najjar
! Initial Import of Rocpart
!
!
!******************************************************************************