PLAG_ModEulerian.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines for Eulerian-based particle infrastructure.
!
! Description: None.
!
! Notes: None. 
!
! ******************************************************************************
!
! $Id: PLAG_ModEulerian.F90,v 1.8 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
! ******************************************************************************

MODULE plag_modeulerian

  USE modparameters
  USE moddatatypes  
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modpartlag, ONLY: t_plag 
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modmpi
  USE plag_modparameters

#ifdef RFLO
#include "Indexing.h"  
  USE modinterfaces, ONLY: rflo_getcelloffset, &
                           rflo_getdimensdummy
#endif
 
  IMPLICIT NONE
  
! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Private data
! ==============================================================================

  CHARACTER(CHRLEN), PRIVATE :: & 
    RCSIdentString = '$RCSfile: PLAG_ModEulerian.F90,v $ $Revision: 1.8 $'        

! ==============================================================================
! Public functions
! ==============================================================================
  
  PUBLIC :: plag_calceulerianfield,    &
            plag_createeulerianfield,  & 
            plag_destroyeulerianfield, & 
            plag_initeulerianfield

! ==============================================================================
! Private functions
! ==============================================================================

!  PRIVATE :: 

! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS
  
  
  
  
  
  
  
  
  
  

  





! *******************************************************************************
!
! Purpose: Compute Eulerian-based field from Lagrangian datastructure.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: Routine relevant to RFLO.
!
! ******************************************************************************

  SUBROUTINE plag_calceulerianfield(pRegion)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
  
    TYPE(t_region), POINTER :: pregion
  
! ==============================================================================
!   Locals
! ==============================================================================

#ifdef RFLO
    INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend  
    INTEGER :: ilev,icelloffset, ijcelloffset   
#endif

    INTEGER :: errorflag,ibc,ic,icont,iec,ipcl,ivar,ncont,npcls,nplagcell,nvars
    INTEGER, POINTER, DIMENSION(:)   :: cvmass    

    REAL(RFREAL) :: diammicron,massl,masssqrl,nplagcellinv
    REAL(RFREAL), POINTER, DIMENSION(:,:) :: cv,dv,ev

    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************

    global => pregion%global
 
    CALL registerfunction(global,'PLAG_CalcEulerianField',&
  'PLAG_ModEulerian.F90')

#ifdef RFLO
    ilev  = pregion%currLevel
    pgrid => pregion%levels(ilev)%grid
    pplag => pregion%levels(ilev)%plag

    CALL rflo_getdimensdummy( pregion,ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( pregion,ilev,icelloffset,ijcelloffset )
    ibc = indijk(idcbeg,jdcbeg,kdcbeg,icelloffset,ijcelloffset)
    iec = indijk(idcend,jdcend,kdcend,icelloffset,ijcelloffset)
#endif

#ifdef RFLU
    pgrid => pregion%grid
    pplag => pregion%plag
    
    ibc = 1
    iec = pgrid%nCells
#endif
   
    ncont = pregion%plagInput%nCont
    npcls = pplag%nPcls
    nvars = pplag%nEv

    cvmass => pplag%cvPlagMass
    cv => pplag%cv
    dv => pplag%dv
    ev => pplag%ev

    IF ( pplag%nPcls > 0 ) THEN

! ******************************************************************************
!     Reinitialize Eulerian field to compute instantaneous variables
! ******************************************************************************

      DO ic = ibc,iec
      DO ivar = 1, nvars
        ev(ivar,ic) = 0.0_rfreal
      END DO ! iVar
      END DO ! ic

! ******************************************************************************
!     Compute instantaneous Eulerian field from Lagrangian datastructure
! ******************************************************************************

      DO ipcl = 1,npcls
        ic = pplag%aiv(aiv_plag_icells,ipcl)

        diammicron = dv(dv_plag_diam,ipcl)*1.0e+06_rfreal      
        massl = sum(cv(cvmass(:),ipcl))

        ev(ev_plag_diam3,ic) = ev(ev_plag_diam3,ic) +diammicron**3.0_rfreal
        ev(ev_plag_diam4,ic) = ev(ev_plag_diam4,ic) +diammicron**4.0_rfreal

        ev(ev_plag_numdens,ic) = ev(ev_plag_numdens,ic) +1.0_rfreal
 
        ev(ev_plag_uvel,ic) = ev(ev_plag_uvel,ic) +dv(dv_plag_uvel,ipcl)
        ev(ev_plag_vvel,ic) = ev(ev_plag_vvel,ic) +dv(dv_plag_vvel,ipcl)
        ev(ev_plag_wvel,ic) = ev(ev_plag_wvel,ic) +dv(dv_plag_wvel,ipcl)

        ev(ev_plag_mass,ic) = ev(ev_plag_mass,ic) +massl

        DO icont = 1, ncont
          ev(ev_plag_last+icont,ic) = ev(ev_plag_last+icont,ic) &
                                    + cv(cvmass(icont),ipcl)
        END DO ! iCont

      END DO ! iPcl

! ******************************************************************************
!     Scale field by cell-based number of particles
!       Do not apply scaling to number density
! ******************************************************************************

      DO ic = ibc,iec
        nplagcell = ev(ev_plag_numdens,ic)
   
        IF ( nplagcell > 0 ) THEN
          nplagcellinv = 1.0/REAL(nplagcell,kind=rfreal)
      
          DO ivar = 1, ev_plag_numdens-1
            ev(ivar,ic) = ev(ivar,ic) *nplagcellinv
          END DO ! iVar
      
          DO ivar = ev_plag_numdens+1, nvars
            ev(ivar,ic) = ev(ivar,ic) *nplagcellinv
          END DO ! iVar

         ENDIF ! nPlagCell 
       END DO ! ic  

    END IF ! pPlag%nPcls 

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_calceulerianfield

  
  
  
  
  

! *******************************************************************************
!
! Purpose: Create eulerian field.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   pPlag               Pointer to plag
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_createeulerianfield(pRegion,pPlag)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
    
#ifdef RFLO
    TYPE(t_region) :: pregion 
#endif

#ifdef RFLU
    TYPE(t_region), POINTER :: pregion
#endif

    TYPE(t_plag), POINTER :: pplag

! ==============================================================================
!   Locals
! ==============================================================================

#ifdef RFLO
    INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend  
    INTEGER :: ilev,icelloffset, ijcelloffset   
#endif

    INTEGER :: errorflag,ibc,iec,nev
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global
    
    CALL registerfunction(global,'PLAG_CreateEulerian',&
  'PLAG_ModEulerian.F90')

    nev = pplag%nEv        

#ifdef RFLO
    ilev  = pregion%currLevel
    pgrid => pregion%levels(ilev)%grid

    CALL rflo_getdimensdummy( pregion,ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( pregion,ilev,icelloffset,ijcelloffset )
    ibc = indijk(idcbeg,jdcbeg,kdcbeg,icelloffset,ijcelloffset)
    iec = indijk(idcend,jdcend,kdcend,icelloffset,ijcelloffset)
#endif

#ifdef RFLU
    pgrid => pregion%grid
    ibc = 1
    iec = pgrid%nCells
#endif
  
! ******************************************************************************
!   Allocate memory
! ******************************************************************************

    ALLOCATE(pplag%ev(nev,ibc:iec),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'pPlag%ev')
    END IF ! global%error                       

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_createeulerianfield






! *******************************************************************************
!
! Purpose: Destroy Eulerian field.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   pPlag               Pointer to plag
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_destroyeulerianfield(pRegion,pPlag)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
    
#ifdef RFLO
    TYPE(t_region) :: pregion 
#endif

#ifdef RFLU
    TYPE(t_region), POINTER :: pregion
#endif

    TYPE(t_plag), POINTER :: pplag
    
! ==============================================================================
!   Locals
! ==============================================================================
    
    INTEGER :: errorflag
    TYPE(t_global), POINTER :: global    

! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************

    global => pregion%global
    
    CALL registerfunction(global,'PLAG_DestroyEulerian',&
  'PLAG_ModEulerian.F90')

! ******************************************************************************
!   Deallocate memory
! ******************************************************************************
        
    DEALLOCATE(pplag%ev,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'pPlag%ev')
    END IF ! global%error

! ******************************************************************************
!   Nullify memory
! ******************************************************************************
 
    nullify(pplag%ev)

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_destroyeulerianfield

  



! *******************************************************************************
!
! Purpose: Initialize Eulerian field.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   pPlag               Pointer to plag
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_initeulerianfield(pRegion,pPlag)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
     
#ifdef RFLO
    TYPE(t_region) :: pregion
#endif

#ifdef RFLU
    TYPE(t_region), POINTER :: pregion
#endif

    TYPE(t_plag), POINTER :: pplag
  
! ==============================================================================
!   Locals
! ==============================================================================

#ifdef RFLO
    INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend  
    INTEGER :: ilev,icelloffset, ijcelloffset   
#endif

    INTEGER :: errorflag,ibc,iec,icell,ivar,nvars
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************

    global => pregion%global
 
    CALL registerfunction(global,'PLAG_InitEulerianField',&
  'PLAG_ModEulerian.F90')

    nvars = pplag%nEv       

#ifdef RFLO
    ilev  = pregion%currLevel
    pgrid => pregion%levels(ilev)%grid

    CALL rflo_getdimensdummy( pregion,ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( pregion,ilev,icelloffset,ijcelloffset )
    ibc = indijk(idcbeg,jdcbeg,kdcbeg,icelloffset,ijcelloffset)
    iec = indijk(idcend,jdcend,kdcend,icelloffset,ijcelloffset)
#endif

#ifdef RFLU
    pgrid => pregion%grid
    ibc = 1
    iec = pgrid%nCells
#endif

! ******************************************************************************
!   Initialize memory
! ******************************************************************************
        
    DO icell = ibc,iec
      DO ivar = 1, nvars
        pplag%ev(ivar,icell)  = 0.0_rfreal
      END DO ! iVar                  
    END DO ! iCell                      

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_initeulerianfield







#ifdef RFLU

! *******************************************************************************
!
! Purpose: Compute Eulerian-based field from Lagrangian datastructure.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   ev                  array containing Eulerian field
!
! Output: None.
!
! Notes: Routine relevant to write TECPLOT files in RFLU.
!
! ******************************************************************************

  SUBROUTINE plag_rflu_calceulerianfield(pRegion,ev)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================

    REAL(RFREAL), DIMENSION(:,:) :: ev     
    TYPE(t_region), POINTER :: pregion
  
! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: errorflag,ibc,icg,icont,iec,ipcl,ivar,ncells1d,ncont,npcls, & 
               nplagcell,nvars,nvarsplot
    INTEGER, POINTER, DIMENSION(:)   :: cvmass    

    REAL(RFREAL) :: diammicron,massl,masssqrl,nplagcellinv
    REAL(RFREAL) :: massfracl,densl,densmixt,sploadl,voll,volmixt
    REAL(RFREAL), POINTER, DIMENSION(:,:) :: cv,dv

    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************

    global => pregion%global
 
    CALL registerfunction(global,'PLAG_RFLU_CalcEulerianField',&
  'PLAG_ModEulerian.F90')

    pgrid => pregion%grid
    pplag => pregion%plag

    ibc = 1
    iec = pgrid%nCells
   
    ncont = pregion%plagInput%nCont
    npcls = pplag%nPcls
    nvars = pplag%nEv

    cvmass => pplag%cvPlagMass
    cv => pplag%cv
    dv => pplag%dv

    IF ( pplag%nPcls > 0 ) THEN

! ******************************************************************************
!     Check if size of array sent is aligned with the expected size
! ******************************************************************************

! CHECK
    nvarsplot = pplag%nEv -ncont
    
    IF ( nvarsplot /= SIZE(ev,1) ) THEN 
      WRITE(*,*) 'nVarsPlot   = ',nvars
      WRITE(*,*) 'SIZE(ev,1) = ',SIZE(ev,1)
      CALL errorstop(global,err_datadim_mismatch,__line__)
    END IF ! nVars 

    IF ( iec /= SIZE(ev,2) ) THEN 
      WRITE(*,*) 'iec        = ',iec
      WRITE(*,*) 'SIZE(ev,2) = ',SIZE(ev,2)
      CALL errorstop(global,err_datadim_mismatch,__line__)
    END IF ! nVars 
        
! END CHECK

! ******************************************************************************
!     Reinitialize Eulerian field to compute instantaneous variables
! ******************************************************************************

      DO icg = ibc,iec
      DO ivar = 1, nvarsplot
        ev(ivar,icg) = 0.0_rfreal
      END DO ! iVar
      END DO ! icg

! ******************************************************************************
!     Compute instantaneous Eulerian field from Lagrangian datastructure
! ******************************************************************************

      DO ipcl = 1,npcls
        icg = pplag%aiv(aiv_plag_icells,ipcl)

        diammicron = dv(dv_plag_diam,ipcl)*1.0e+06_rfreal      
        massl      = sum(cv(cvmass(:),ipcl))
        sploadl    = pplag%arv(arv_plag_spload,ipcl)
        densl      = dv(dv_plag_dens,ipcl)
        
        voll       = dv(dv_plag_volu,ipcl)
        massfracl  = densl*voll*sploadl

        ev(ev_plag_diam3,icg) = ev(ev_plag_diam3,icg) +diammicron**3.0_rfreal
        ev(ev_plag_diam4,icg) = ev(ev_plag_diam4,icg) +diammicron**4.0_rfreal

        ev(ev_plag_numdens,icg) = ev(ev_plag_numdens,icg) +1.0_rfreal
 
        ev(ev_plag_uvel,icg) = ev(ev_plag_uvel,icg) +dv(dv_plag_uvel,ipcl)
        ev(ev_plag_vvel,icg) = ev(ev_plag_vvel,icg) +dv(dv_plag_vvel,ipcl)
        ev(ev_plag_wvel,icg) = ev(ev_plag_wvel,icg) +dv(dv_plag_wvel,ipcl)
        
        ev(ev_plag_temp,icg) = ev(ev_plag_temp,icg) +dv(dv_plag_temp,ipcl)

        ev(ev_plag_mass,icg) = ev(ev_plag_mass,icg) +massfracl

! TEMPORARY
!    Not used for RFLU in tecplot files
!        DO iCont = 1, nCont
!          ev(EV_PLAG_LAST+iCont,icg) = ev(EV_PLAG_LAST+iCont,icg) &
!                                    + cv(cvMass(iCont),iPcl)
!        END DO ! iCont
! END TEMPORARY

      END DO ! iPcl

! ******************************************************************************
!     Scale field by cell-based number of particles
!       Do not apply scaling to number density and mass fraction
! ******************************************************************************

      DO icg = ibc,iec
        nplagcell = ev(ev_plag_numdens,icg)
   
        IF ( nplagcell > 0 ) THEN
          nplagcellinv = 1.0/REAL(nplagcell,kind=rfreal)
      
          DO ivar = 1, ev_plag_numdens-1
            ev(ivar,icg) = ev(ivar,icg) *nplagcellinv
          END DO ! iVar

          DO ivar = ev_plag_numdens+1, ev_plag_temp     
! TEMPORARY
!          DO iVar = EV_PLAG_NUMDENS+1, nVars
! END TEMPORARY

            ev(ivar,icg) = ev(ivar,icg) *nplagcellinv
          END DO ! iVar

! Compute Mass Fraction
          
          densmixt = pregion%mixt%cv(cv_mixt_dens,icg)
          volmixt  = pregion%grid%vol(icg)
          ev(ev_plag_mass,icg) = ev(ev_plag_mass,icg)/ &
                                (ev(ev_plag_mass,icg) +densmixt *volmixt)
         ENDIF ! nPlagCell 
       END DO ! icg  
    END IF ! pPlag%nPcls 

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_rflu_calceulerianfield
#endif





END MODULE plag_modeulerian

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_ModEulerian.F90,v $
! Revision 1.8  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.7  2008/11/19 22:17:46  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.6  2006/04/07 15:19:23  haselbac
! Removed tabs
!
! Revision 1.5  2006/02/16 14:51:58  fnajjar
! Bug fix for missing ev pointer array in PLAG_CalcEulerian
!
! Revision 1.4  2006/01/31 17:20:21  fnajjar
! Bug fix to embed PLAG_RFLU_CalcEulerian in ifdef RFLU
!
! Revision 1.3  2005/11/30 22:20:21  fnajjar
! Added PLAG_RFLU_CalcEulerianField
!
! Revision 1.2  2005/02/16 14:46:48  fnajjar
! Bug fix for w-velocity component of ev and cosmetics cleanup
!
! Revision 1.1  2005/01/08 20:44:32  fnajjar
! Initial import for PLAG statistics
!
! ******************************************************************************