PLAG_InjcTileInitialize.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: initialize the tiles for the multiphase injection algorithm.
!
! Description: none.
!
! Input: region    = current region
!
! Output: regions(iReg)%levels%patch%tile = initial tile values
!                                           of current region.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_InjcTileInitialize.F90,v 1.4 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_injctileinitialize( region )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag_input, t_tile_plag
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modrandom, ONLY     : rand1uniform
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset, rflo_getnodeoffset
#endif
  USE plag_modinterfaces, ONLY : plag_injcmakeparticle
  USE moderror
  USE modparameters
  USE modmpi
  USE plag_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ipatch, itile

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype, npatches, ntiles
#ifdef RFLO
  INTEGER :: ilev, n1, n2
#endif
  INTEGER :: injcdiamdist
  INTEGER :: ncv, ndv
  INTEGER :: ejecmodel,icont,ncont
  
  REAL(RFREAL) :: randunif
  REAL(RFREAL) :: poolvolumeinit, ratiophidensinv   
  REAL(RFREAL), POINTER, DIMENSION(:) :: injcmassfluxratio, densplag

  TYPE(t_patch),     POINTER :: ppatch
  TYPE(t_tile_plag), POINTER :: ptileplag
  TYPE(t_global),    POINTER :: global
    
!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_InjcTileInitialize.F90,v $ $Revision: 1.4 $'

  global => region%global
  
  CALL registerfunction( global, 'PLAG_InjcTileInitialize',&
  'PLAG_InjcTileInitialize.F90' )

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,3X,A)') solver_name,'Initializing tile memory for PLAG...'
  END IF ! global%verbLevel
  
! Get dimensions --------------------------------------------------------------

#ifdef RFLO
  ilev     = region%currLevel
  npatches = region%nPatches
#endif
#ifdef RFLU
  npatches = region%grid%nPatches
#endif

  ncont        = region%plagInput%nCont  
  injcdiamdist = region%plagInput%injcDiamDist
  ejecmodel    = region%plagInput%ejecModel                

  injcmassfluxratio => region%plagInput%injcMassFluxRatio
  densplag          => region%plagInput%dens

! Loop over patches -----------------------------------------------------------

  DO ipatch=1,npatches

#ifdef RFLO
    ppatch  => region%levels(ilev)%patches(ipatch)
#endif
#ifdef RFLU
    ppatch  => region%patches(ipatch)
#endif

    bctype = ppatch%bcType

! - Select injection boundary condition ---------------------------------------

    IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) THEN

! - Get dimensions -----------------------------------------------------------

#ifdef RFLO
      n1      = abs(ppatch%l1end   -ppatch%l1beg   ) + 1    
      n2      = abs(ppatch%l2end   -ppatch%l2beg   ) + 1
      ntiles  = n1*n2
#endif
#ifdef RFLU
      ntiles = ppatch%nBFaces
#endif

      ptileplag => ppatch%tilePlag

      ncv = ptileplag%nCv
      ndv = ptileplag%nDv

      ptileplag%nPclsInjc(:ntiles)   = 0
      
      ptileplag%cv(:ncv,:ntiles)     = 0.0_rfreal
      ptileplag%dv(:ndv,:ntiles)     = 0.0_rfreal
        
      ptileplag%rhs(:ncv,:ntiles)    = 0.0_rfreal
        
      ptileplag%cvOld(:ncv,:ntiles)  = 0.0_rfreal
      ptileplag%rhsSum(:ncv,:ntiles) = 0.0_rfreal
                        
! --- Loop over tile patch ----------------------------------------------------

      DO itile = 1, ntiles

        CALL plag_injcmakeparticle(region, injcdiamdist,         &
                                   ptileplag%dv(dv_tile_diam,itile), &
                                   ptileplag%dv(dv_tile_spload,itile) )
 
        randunif = rand1uniform(region%randData) 

! ---- Avoid error if randUnif is 0 -------------------------------------------
! ---- and set timefactor such that EXP(-50) = 1.9E-22 ------------------------

        IF ( randunif <= 0.0_rfreal) THEN          
          ptileplag%dv(dv_tile_countdown,itile) = 50.0_rfreal 
        ELSE
          ptileplag%dv(dv_tile_countdown,itile) = -log(randunif)
        END IF ! randUnif

! ---- Set initial pool volume

       IF ( ejecmodel == plag_ejec_cre ) THEN
         poolvolumeinit  = 0.0_rfreal
         ratiophidensinv = poolvolumeinit  &
                         *1.0_rfreal/sum(injcmassfluxratio(:)/densplag(:))

         DO icont = 1, ncont
           ptileplag%cv(ptileplag%cvTileMass(icont),itile) = poolvolumeinit    &
                                                           * injcmassfluxratio(icont)
         END DO ! iCont
       ENDIF ! ejecModel       
      END DO ! iTile
                                       
    ENDIF  ! bcType

  ENDDO    ! iPatch
  
! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_injctileinitialize

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_InjcTileInitialize.F90,v $
! Revision 1.4  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:46  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:23  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 20:57:45  fnajjar
! Initial revision after changing case
!
! Revision 1.8  2004/06/30 15:43:27  fnajjar
! Added initialization step for CRE model
!
! Revision 1.7  2004/06/16 23:06:33  fnajjar
! Renamed variabled for CRE kernel
!
! Revision 1.6  2004/03/03 00:30:52  fnajjar
! Incorrect ifdef construct for RFLU pPatch pointer
!
! Revision 1.5  2003/11/26 22:00:28  fnajjar
! Removed improper comment symbol after USE ModRandom
!
! Revision 1.4  2003/11/21 22:35:51  fnajjar
! Update Random Number Generator
!
! Revision 1.3  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.2  2003/01/16 20:15:11  f-najjar
! Removed iRegionGlobal
!
! Revision 1.1  2002/10/25 14:16:31  f-najjar
! Initial Import of Rocpart
!
!******************************************************************************