PLAG_InjcTileCalcRhs.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: computes the RHS for the multiphase injection algorithm.
!
! Description: none.
!
! Input: region    = current region
!
! Output: regions(iReg)%levels%patch%tile%rhs = updated tile rhs values
!                                               of current region.
!
! Notes: Use negative values of rhs for consistent RK Updating step.
!
!******************************************************************************
!
! $Id: PLAG_InjcTileCalcRhs.F90,v 1.4 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_injctilecalcrhs( region )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag_input, t_tile_plag
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global  
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset,   rflo_getnodeoffset
  USE moderror
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ipatch, icont, i, j, k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype, distrib, i2dvals,  ibeg, icoff, idir, iend,     &
             ijcoff, ijnoff, ijkc, ijkd, ijkn, ilev, inode, inoff,   &
             itile, jbeg, jdir, jend, jnode, kbeg, kdir, kend,       &
             knode, lbound, n1, n2, ncont, noff, npatches   
  INTEGER, POINTER, DIMENSION(:) :: pcvtilemass

  REAL(RFREAL)  :: area, heatcapsum, injcvelratio, massfluxsum, mrate, &
                   rhomixtbcond, tburn, tiletemp, tilevelnrm
  REAL(RFREAL), POINTER, DIMENSION(:)   :: injcmassfluxratio, specheat
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: prhs, sface, vals
  
  TYPE(t_patch),     POINTER :: ppatch
  TYPE(t_tile_plag), POINTER :: ptileplag
  TYPE(t_global),    POINTER :: global
  
!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_InjcTileCalcRhs.F90,v $ $Revision: 1.4 $'

  global => region%global
    
  CALL registerfunction( global, 'PLAG_InjcTileCalcRhs',&
  'PLAG_InjcTileCalcRhs.F90' )

! Get dimensions --------------------------------------------------------------

  ilev     = region%currLevel
  npatches = region%nPatches

  ncont        = region%plagInput%nCont
  injcvelratio = region%plagInput%injcVelRatio
  
  injcmassfluxratio => region%plagInput%injcMassFluxRatio
  specheat          => region%plagInput%spht
  
! Loop over patches -----------------------------------------------------------

  DO ipatch=1,npatches

    ppatch  => region%levels(ilev)%patches(ipatch)

    bctype = ppatch%bcType

! - Select injection boundary condition ---------------------------------------

    IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) THEN

! -- Get dimensions and pointers ----------------------------------------------

      lbound = ppatch%lbound

      CALL rflo_getpatchindices( region,ppatch,ilev, &
                                 ibeg,iend,jbeg,jend,kbeg,kend )
      CALL rflo_getpatchdirection( ppatch,idir,jdir,kdir )
      CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
      CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

      noff        = abs(ppatch%l1end-ppatch%l1beg) + 1
      distrib     = ppatch%mixt%distrib
  
      vals => ppatch%mixt%vals
      
! -- Set appropriate extent of cells and shift upper cell by one value --------

      inode = 0
      jnode = 0
      knode = 0
      IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
        inode =  -idir
        jnode =  -jdir
        knode =  -kdir
      ENDIF ! lbound
      
! -- Get the appropriate face vector ------------------------------------------

      IF (lbound==1 .OR. lbound==2) sface => region%levels(ilev)%plag%si
      IF (lbound==3 .OR. lbound==4) sface => region%levels(ilev)%plag%sj
      IF (lbound==5 .OR. lbound==6) sface => region%levels(ilev)%plag%sk

! -- Loop over patch ----------------------------------------------------------

      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkc  = indijk(i,j,k,icoff,ijcoff)
            ijkn  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
            ijkd  = indijk(i-idir,j-jdir,k-kdir,icoff,ijcoff)
            area  = sqrt(sface(xcoord,ijkn)*sface(xcoord,ijkn)+ &
                         sface(ycoord,ijkn)*sface(ycoord,ijkn)+ &
                         sface(zcoord,ijkn)*sface(zcoord,ijkn))

            IF      (lbound==1 .OR. lbound==2) THEN
              n1 = j - jbeg + 1
              n2 = k - kbeg + 1
            ELSE IF (lbound==3 .OR. lbound==4) THEN
              n1 = k - kbeg + 1
              n2 = i - ibeg + 1
            ELSE IF (lbound==5 .OR. lbound==6) THEN
              n1 = i - ibeg + 1
              n2 = j - jbeg + 1
            ENDIF ! lbound
            
            i2dvals = distrib * indij(n1-1,n2-1,noff)
            mrate   = vals(bcdat_inject_mfrate,i2dvals)
            tburn   = vals(bcdat_inject_temp  ,i2dvals)
 
! --- Compute mixture density on boundary -------------------------------------
! --- based on an average of interior & dummy cell ----------------------------

            rhomixtbcond = 0.5_rfreal *                                     &
                          (region%levels(ilev)%mixt%cv(cv_mixt_dens,ijkc) + &
                           region%levels(ilev)%mixt%cv(cv_mixt_dens,ijkd) )

! --- Update tile Rhs datastructure -------------------------------------------
                           
            itile  = indij(n1,n2,noff)
            ptileplag => ppatch%tilePlag
 
            prhs        => ptileplag%rhs
            pcvtilemass => ptileplag%cvTileMass

            massfluxsum = sum( mrate * injcmassfluxratio(:) )
            heatcapsum  = dot_product( specheat, mrate * &
                                       injcmassfluxratio(:) )

            tiletemp    = tburn
            tilevelnrm  = injcvelratio * mrate / rhomixtbcond
  
            DO icont = 1, ncont
              prhs(pcvtilemass(icont),itile) = -area *mrate * &
                                                injcmassfluxratio(icont) 
            END DO ! iCont            
            
            prhs(cv_tile_momnrm,itile) = -area *massfluxsum *tilevelnrm
            
            prhs(cv_tile_ener  ,itile) = -area *                       &
                                  ( 0.5_rfreal*massfluxsum*tilevelnrm**2 &
                                  +            heatcapsum *tiletemp      )
           
          END DO ! i
        END DO ! j
      END DO ! k
                                                        
    ENDIF  ! bcType
 
  ENDDO    ! iPatch

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_injctilecalcrhs

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_InjcTileCalcRhs.F90,v $
! Revision 1.4  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:46  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:40:05  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/12/01 20:57:43  fnajjar
! Initial revision after changing case
!
! Revision 1.5  2003/11/03 21:21:51  fnajjar
! Changed definition of face vectors pointing to PLAG datastructure
!
! Revision 1.4  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.3  2003/05/07 15:12:10  fnajjar
! Bug fix of i2dVals for correct boundary extent
!
! Revision 1.2  2003/01/16 20:15:11  f-najjar
! Removed iRegionGlobal
!
! Revision 1.1  2002/10/25 14:16:31  f-najjar
! Initial Import of Rocpart
!
!
!******************************************************************************